Алгоритм поиска кратчайшего маршрута

Program Search_Floyd;
Const
  n = 6;
Type
  TGraph = Array[1..n,1..n] of Integer;
Const
  C : TGraph = ((0,    2,    22, 1000, 18,   900),
                (2,    0,    10, 1000, 35,   1000),
                (22,   10,   0,  78,   23,   9),
                (1000, 1000, 78, 0,    1000, 35),
                (18,   35,   23, 1000, 0,    19),
                (900,  1000, 9,  35,   19,   0));
Var
  P : TGraph;
 
Procedure Floyd(n : Integer; C : TGraph; var P : TGraph);
Var
  A : TGraph;
  i,j,k : Integer;
Begin
  for i:=1 to n do
    for j:=1 to n do
      begin
        A[i,j] := C[i,j];
        P[i,j] := 0;
      end;
  for i:=1 to n do A[i,i] := 0;
  for k:=1 to n do
    for i:=1 to n do
      for j:=1 to n do
        if (A[i,k] + A[k,j]) < A[i,j] then
          begin
            A[i,j] := A[i,k] + A[k,j];
            P[i,j] := k;
          end;
End;
 
Procedure PrintPath(i,j : Integer; const P : TGraph);
Var
  k : Integer;
Begin
  k := P[i,j];
  if k = 0 then Exit;
  PrintPath(i,k,P);
  Write(k,'  ');
  PrintPath(k,j,P);
End;
 
BEGIN
  Floyd(n,C,P);
  PrintPath(1,4,P);
  ReadLn;
END.