Тестирование полезных кодов и примеров

Option Explicit
'© Антихакер32 (CyberForum.ru)
Public WithEvents tx1 As TextBox
Public WithEvents tx2 As TextBox
Public WithEvents Cm1 As CommandButton
Public WithEvents Cm2 As CommandButton
Const th = 400, m = 100, String2 = "php?to="
Private Declare Sub InitCommonControls Lib "comctl32.dll" ()
 
Private Sub Form_Initialize(): InitCommonControls: End Sub
 
Private Sub Cm1_Click()
    Clipboard.Clear
    Clipboard.SetText tx2.Text
End Sub
 
Private Sub Cm2_Click() 'Запуск URL
    On Error Resume Next
    With CreateObject("Shell.Application"): .Open (Trim(tx2)): End With
End Sub
 
Private Sub tx1_Change()
    tx2 = CV_HTTP_VK_Link$(tx1)
End Sub
 
Private Sub tx1_Click()
    tx1.SelStart = 0: tx1.SelLength = Len(tx1)
End Sub
 
Private Sub tx2_Click()
    tx2.SelStart = 0: tx2.SelLength = Len(tx2)
End Sub
 
Private Sub Form_Resize()
    Dim v
    On Error Resume Next
    For Each v In Controls
        If TypeName(v) = "CommandButton" Then
            v.Width = (Me.ScaleWidth - m * 2) \ 3
        Else: v.Width = Me.ScaleWidth - m * 2
        End If
        v.Visible = 1
    Next
End Sub
 
Private Sub Form_Load()
    Dim tt&, f&, s$: tt = m
    For f = 1 To 2: s = "tx" & f
        Call CallByName(Me, s, VbSet, Controls.Add("vb.textbox", s))
        With Controls(s): .Move m, tt, 0, th: tt = tt + th + m: End With
    Next
    For f = 1 To 2: s = "cm" & f
        Call CallByName(Me, s, VbSet, Controls.Add("vb.CommandButton", s))
        With Controls(s): .Move m, tt, 0, th: tt = tt + th + m
            .Caption = Choose(f, "Скопировать", "Запустить")
        End With
    Next
    With Me: .Caption = "Конвертор VK-ссылок"
        .Width = 10000: .Height = tt + (.Height - .ScaleHeight)
    End With
    'Если в буфере обмена уже чтото есть то заносим в текстовое поле
    s = Trim(Clipboard.GetText)
    If InStr(1, s, "http", 1) = 1 Then tx1 = s
End Sub
 
Function CV_HTTP_VK_Link$(ByVal Link$, Optional Compare As VbCompareMethod = 1)
    'Получение нормальной ссылки, если сайт VK ее шифрует
    Dim f&, n&, v
    n = InStr(1, Link, String2, Compare)
    n = n + Len(String2) * Sgn(n) + Abs(n = 0)
    Link = Mid$(Link, n): Link = Replace(Link, vbCrLf, "")
    v = Array( _
    Array("%3A", "%2F", "%3F", "%3D"), _
    Array(":", "/", "?", "="))
    
    For f = 0 To UBound(v(0))
        Link = Replace(Link, CStr(v(0)(f)), CStr(v(1)(f)))
    Next
    CV_HTTP_VK_Link = Link
End Function