Как сделать "Панель задач" в две строки через реестр или скриптом bat/cmd?

;--------------------
; Script: tbmv.ahk
; Description: Moving the taskbar
; Author: © Garry Galler 2018  
;--------------------
#NoEnv 
#SingleInstance ignore        ; разрешаем запуск только одной копии скрипта
;----------------
ABE_LEFT := 0
ABE_TOP := 1
ABE_RIGHT := 2
ABE_BOTTOM := 3
 
; определяем положение панели
GetPosTaskBar() {
    ABM_GETTASKBARPOS := 0x00000005
    VarSetCapacity(APPBARDATA, A_PtrSize = 4 ? 36 : 48)
    result := DllCall("Shell32\SHAppBarMessage" ,"UInt", ABM_GETTASKBARPOS,"Ptr", &APPBARDATA, "UInt")
    
    if %result% = 0 
    {
        ToolTip % "Ошибка получения положения панели задач"
        Sleep, 3000
        Exit
    }
    return NumGet(APPBARDATA,A_PtrSize + 4 + 4,"UInt") ;DWORD:HWND:UINT
}
 
zoom:= %0% = 0 ? 2 : %1% ; передача скрипту параметров  не работает (почему - не знаю)
speed_mouse:=10 ; скорость перемещения мыши
HKEY_PATH:="SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced"
 
;RegWrite, REG_DWORD, HKEY_CURRENT_USER, %HKEY_PATH%, TaskbarSizeMove, 0 ; закрепить
RegRead, TaskbarLocked, HKEY_CURRENT_USER, %HKEY_PATH%, TaskbarSizeMove
If TaskbarLocked = 0
    SendMessage 0x111, 424, , , ahk_class Shell_TrayWnd
 
WinActivate ahk_class Shell_TrayWnd
;ControlGetPos  x, y, width, height, MSTaskListWClass1, ahk_class Shell_TrayWnd ; получаем координаты и размер контрола внутри окна
ControlGetPos  x, y, width, height, , ahk_class Shell_TrayWnd ; получаем координаты и размер самого окна
 
TaskbarPosition := GetPosTaskBar() 
CoordMode, Mouse, Screen ; режим определения координат мыши: абсолютный\экранный
; перемещаем курсор в зависимости от положения панели
; снизу
If TaskbarPosition = %ABE_BOTTOM%
{ 
    x:=A_ScreenWidth/2
    y:=A_ScreenHeight - height 
  
    MouseMove x, y
    drag_y:=A_ScreenHeight - (height * zoom) - 5
    MouseClickDrag Left, x, y, x, drag_y, speed_mouse
}
; сверху
Else If TaskbarPosition = %ABE_TOP%
{ 
    x:=A_ScreenWidth/2  
    y:=y + height
    MouseMove x, y
    drag_y:=y * zoom + 5
    MouseClickDrag Left, x, y, x, drag_y, speed_mouse
}
; слева
Else If TaskbarPosition = %ABE_LEFT%
{ 
    x:=x + width
    MouseMove x, y
    drag_x:=x * zoom + 5
    MouseClickDrag Left, x, y, drag_x, y, speed_mouse
}
 
; справа
Else If TaskbarPosition = %ABE_RIGHT%
{ 
    y:=A_ScreenHeight/2
    x:=A_ScreenWidth - width
  
    MouseMove x, y
    drag_x:=A_ScreenWidth - (width * zoom) - 5
    MouseClickDrag Left, x, y, drag_x, y, speed_mouse
}
 
If TaskbarLocked = 0
    SendMessage 0x111, 424, , , ahk_class Shell_TrayWnd