Version 1909 x64 (KB4549951) откатывается после рестарта

@echo off
rem Установка обновлений в формате .CAB
rem DISM /Online /Add-Package /PackagePath:X:\путь_к_файлу\имя_файла.cab
rem Где X: - имя диска.
 
rem Естественно, запускать надо с админскими правами!
rem @echo on
 
rem --------------------------
if exist %1 goto setup
 
@echo ======================= Инструкция ==========================
@echo   Не надо запускать этот файл, тупо тыкая в него.
@echo   Создай ярлык на этот файл и присвой ему админские 
@echo права через "Свойства".
@echo   Для установки CAB-обновления перетащи мышью 
@echo и брось этот CAB-файл на ярлык.
@echo   Установка идёт в фоновом режиме и может длиться до 
@echo полутора часов. Сверни окно консоли и работай.
@echo   Когда установка будет закончена, в консоли появится 
@echo запрос на перезагрузку "Перезагрузить [Y/N]?:".
@echo Однократная перезагрузка длится от 5 до 15 минут.
goto anykey
 
:setup
@echo =========== Установка обновления Windows 10x64 ==============
set logfile="%~dp0_results.log"
@echo  %time% - [Установка начата]
call :TimeCountBegin
@echo  !!! Дождись запроса на перезагрузку !!!
DISM /Online /Add-Package /PackagePath:%1
::ping -n 5 localhost
@echo  %time% - [Установка окончена]
call :TimeCountEnd
 
:anykey
@echo ===================== Нажми эникей ==========================
pause > nul
exit
 
:: ----------------------------
:TimeCountBegin
@echo  %time% - [Установка начата] > %logfile%
set begin_HH=%time:~0,2%
set /a begin_HH=%begin_HH%+0
::set /a begin_HH=%begin_HH%-100
set begin_MM=1%time:~3,2%
set /a begin_MM=%begin_MM%-100
set begin_SS=1%time:~6,2%
set /a begin_SS=%begin_SS%-100
goto :EOF
 
:TimeCountEnd
@echo  %time% - [Установка окончена] >> %logfile%
set end_HH=%time:~0,2%
set /a end_HH=%end_HH%+0
::set /a end_HH=%end_HH%-100
set end_MM=1%time:~3,2%
set /a end_MM=%end_MM%-100
set end_SS=1%time:~6,2%
set /a end_SS=%end_SS%-100
set /a begin=(%begin_HH%*3600)+(%begin_MM%*60)+%begin_SS%
set /a end=(%end_HH%*3600)+(%end_MM%*60)+%end_SS%
set /a worktime=%end%-%begin%
set /a worktime_MM=%worktime%/60
set /a worktime_SS=%worktime%-%worktime_MM%*60
echo Время обработки %worktime_MM% мин %worktime_SS% сек.
echo Время обработки %worktime_MM% мин %worktime_SS% сек. >> %logfile%
goto :EOF

cab-setup.cmd Windows10.0-KB4550945-x64_PSFX.cab