Как создать свое событие для своего класса?

unit uMyClass;
 
interface
 
uses
  Classes, Dialogs;
 
type
 
  TMyClass = class
  private
    FName : String;
    //...
    //Поле ссылающееся на обработчик события MyEvent.
    //Тип TNotifyEvent описан в модуле Clases так: TNotifyEvent = procedure(Sender: TObject) of object;
    //Фраза  "of object" означает, что в качестве обработчика можно назначить только метод какого-либо
    //класса, а не произвольную процедуру.
    FOnMyEvent : TNotifyEvent;
    //...
  protected
    //...
    //Эта процедура проверяет задан ли обработчик события. И, если задан, запускает его.
    procedure DoMyEvent; dynamic;
  public
    //...
    //Это свойство позволяет назначить обработчик для обработки события MyEvent.
    property OnMyEvent : TNotifyEvent read FOnMyEvent write FOnMyEvent;
    //...
    //Процедура, которая принимает решение - произошло событие MyEvent или нет.
    //Таких процедур может быть несколько - везде где может возникнуть событие MyEvent.
    //Если событие MyEvent произошло, то вызвается процедура DoMyEvent().
    procedure GenericMyEvent;
    //...
    //Имя экземпляра класса.
    property Name : String read FName write FName;
    //...
  published
    //...
  end;
 
implementation
 
{ TMyClass }
 
procedure TMyClass.DoMyEvent;
begin
  //Если обработчик назначен, то запускаем его.
  if Assigned(FOnMyEvent) then FOnMyEvent(Self);
end;
 
procedure TMyClass.GenericMyEvent;
var
  MyEventIsOccurred : Boolean;
  //...
begin
  //...
  MyEventIsOccurred := True;
  //Если верно некоторое условие, которое подтверждает, что событие MyEvent
  //произошло, то делаем попытку запустить связанный обработчик.
  if MyEventIsOccurred then begin
    DoMyEvent;
  end;
  //...
end;
 
end.

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls
 
  ,uMyClass;
 
type
 
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
    
    //Обработчик события MyEvent для объектов, принадлежащих типу TMyClass.
    procedure MyObjectMyEvent(Sender : TObject);
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
 
{ TForm1 }
 
//Обработчик события MyEvent для объектов, принадлежащих типу TMyClass.
procedure TForm1.MyObjectMyEvent(Sender: TObject);
var
  MyObj : TMyClass;
begin
  if not (Sender is TMyClass) then Exit;
 
  MyObj := Sender as TMyClass;
  ShowMessage('Событие MyEvent произошло! Имя объекта, который породил событие: ' + MyObj.Name);
end;
 
procedure TForm1.Button1Click(Sender: TObject);
var
  MyObj1, MyObj2, MyObj3 : TMyClass;
begin
  //Создаём экземпляры класса TMyClass.
  MyObj1 := TMyClass.Create;
  MyObj1.Name := 'MyObj1';
  MyObj2 := TMyClass.Create;
  MyObj2.Name := 'MyObj2';
  MyObj3 := TMyClass.Create;
  MyObj3.Name := 'MyObj3';
 
  //Для MyObj1 и MyObj2 назначаем обработчики события MyEvent.
  MyObj1.OnMyEvent := MyObjectMyEvent;
  MyObj2.OnMyEvent := MyObjectMyEvent;
 
  //Работаем с экземплярами класса. При этом в каждом из экзепляров
  //возникает событие MyEvent.
 
  MyObj1.GenericMyEvent;
  MyObj2.GenericMyEvent;
 
  //При выполнении метода MyObj3.GenericMyEvent, событие MyEvent наступит, но оно
  //не будет обработано процедурой MyObjectMyEvent, т. к., ранее, мы не назначили её в качестве
  //обработичика события MyEvent для экземпляра MyObj3.
  MyObj3.GenericMyEvent;
 
  MyObj1.Free;
  MyObj2.Free;
  MyObj3.Free;
end;
 
end.

type TNotifyEvent = procedure (Sender: TObject) of object;

procedure TForm1.Panel1Click(Sender: TObject);
var
  Panel : TPanel;
begin
  Panel := Sender as TPanel;
  ShowMessage('Обработчик TForm1.Panel1Click() вызвал компонент с именем: ' + Panel.Name);
end;

procedure TForm1.Panel1Click(Sender: TObject);
var
  Cmp : TComponent;
  Panel : TPanel;
begin
  //Если в проекте обработчик мог быть назначенным разным типам компонентов (а не только экземплярам TPanel).
  Cmp := Sender as TComponent;
  ShowMessage('Обработчик TForm1.Panel1Click() вызвал компонент типа ' + Cmp.ClassName
    + ' с именем: ' + Cmp.Name);
 
  //Если экземпляр принадлежит классу TPanel или его потомку, то выполняем какие-то специальные действия:
  if Sender is TPanel then
  begin
    Panel := Sender as TPanel;
    if Panel.Color <> clRed then
      Panel.Color := clRed
    else
      Panel.Color := clGreen;
    ShowMessage('Изменён цвет панели.');
  end;
end;

type TNotifyEvent = procedure (Sender: TObject) of object; // простой обработчик
type TMyShitEvent1 = procedure (Sender: TObject; const Param: <тип_параметра>)  of object; // не совсем простой обработчик
type TMyShitEvent2 = procedure (Sender: TObject; var Param: <тип_параметра>)  of object; // не совсем простой обработчик
type TMyFuncEvent = function (Sender: TObject<; другие параметры>): <тип> of object; // и даже так можно!