Поиск подстроки в строке

.8086
.MODEL TINY
;
CR    EQU   0Dh
LF    EQU   0Ah
;
.CODE
      ORG   100h
START:
      LEA   DX, sdInfo
      CALL  showSd
STR_LOOP:
; Input string
      LEA   BX, kbBufStr
      LEA   DX, sdString
      CALL  inpSd
      JZ    EXIT
      MOV   lwString, AX
; Input substring
      LEA   BX, kbBufSub
      LEA   DX, sdSubStr
      CALL  inpSd
      JZ    STR_LOOP
      MOV   lwSubstr, AX
;
      LEA   BX, chBufStr
      MOV   DX, lwString
SUB_LOOP:
      CMP   DX, lwSubstr
      JNC   DO_CMP
      LEA   DX, sdNotFound
      CALL  showSd
      JMP   STR_LOOP
DO_CMP:
      MOV   DI, BX
      LEA   SI, chBufSub
      MOV   CX, lwSubstr
      REPE CMPSB
      JE    SUB_FOUND
      DEC   DX
      INC   BX
      JMP   SUB_LOOP
SUB_FOUND:
; Substring found
      LEA   DX, sdOffset
      CALL  showSd
; Display Result
      MOV   AX, DI
      SUB   AX, Offset chBufStr
      SUB   AX, lwSubstr
      AAM
      MOV   CX, AX
      TEST  CH, CH
      JZ    LOW_DIGIT
      MOV   DL, CH
      CALL  showDigit
LOW_DIGIT:
      MOV   DL, CL
      CALL  showDigit
      LEA   DX, sdCrLf
      CALL  showSd
      JMP   STR_LOOP
EXIT:
      RET
;
showSd:
; Input: DX = Message Address
      MOV   AH, 9
      INT   21h
      RET
;
showDigit:
; Input: DL = Digit in range 0-9
      ADD   DL, "0"
      MOV   AH, 2
      INT   21h
      RET
;
inpSd:
; Input:  DX = Message Address
;         BX = Buffer Address
; Output: AX = String Length
      CALL  showSd
      MOV   [BX], Byte Ptr BufLen
      MOV   DX, BX
      MOV   AH, 0Ah
      INT   21h
      LEA   DX, sdCrLf
      CALL  showSd
      XOR   AH, AH
      MOV   AL, [BX+1]  ; String length
      TEST  AX, AX
      RET
;
.DATA
lwString    DW    ?
lwSubstr    DW    ?
sdInfo      DB    "Searches substring in string; enter empty string to exit"
sdCrLf      DB    CR, LF, "$"
sdString    DB    " string: $"
sdSubStr    DB    " substr: $"
sdNotFound  DB    " not found", CR, LF, "$"
sdOffset    DB    " offset: $"
PromptLen   EQU   9
BufLen      EQU   80 - PromptLen
kbBufStr LABEL Byte
chBufStr    EQU   kbBufStr + 2
kbBufSub    EQU   chBufStr + BufLen
chBufSub    EQU   kbBufSub + 2
;
      END   START

; masm windows gui #
.386
.model flat, stdcall
option casemap:none
include \masm32\include\windows.inc
include \masm32\include\kernel32.inc
include \masm32\include\user32.inc
includelib \masm32\lib\user32.lib
includelib \masm32\lib\kernel32.lib
.data
MsgCaption      db "вхождения символов из подстроки str2 в строку str1",0
str2     db    "rats",0
str1     db    "six little rats, big fat rat and three old rats",0
num = $ - str1 + 1
str3    db num dup (0)
count dd 0
 
.code
start:  call strfind2
    invoke MessageBox, NULL,eax, addr MsgCaption, MB_OK
    invoke ExitProcess,NULL
strfind2 proc
    push ebx
    push esi
    push edi
    invoke lstrlen, addr str2
    dec eax
    mov ebx,eax
    invoke lstrlen, addr str1
    mov count,eax
    mov str1[eax],0Dh
    mov edx,offset str3
    sub edx,offset str1
a2: mov ecx,count
    mov edi,offset str1
    mov al,str2[bx]
a1: repne scasb
    jecxz exit
    mov [edx+edi-1],al
    jmp a1
exit:   dec bx
    jns a2
    mov ecx,num-1
    mov edi,offset str3
    mov esi,edi
a3: lodsb
    or al,al
    jz a4
    stosb
a4: loop a3
    mov byte ptr [edi],0
    mov eax,offset str1
    pop edi
    pop esi
    pop ebx
    ret
strfind2 endp
end start

.686P
.MODEL Flat,StdCall
OPTION CASEMAP:NONE
 
INCLUDE         \MASM32\INCLUDE\WINDOWS.INC
INCLUDE         \MASM32\INCLUDE\KERNEL32.INC
INCLUDE         \MASM32\INCLUDE\USER32.INC
INCLUDE         \MASM32\INCLUDE\MSVCRT.INC
INCLUDE         \MASM32\INCLUDE\MASM32.INC
 
INCLUDELIB      \MASM32\LIB\KERNEL32.LIB
INCLUDELIB      \MASM32\LIB\USER32.LIB
INCLUDELIB      \MASM32\LIB\MSVCRT.LIB
INCLUDELIB      \MASM32\LIB\MASM32.LIB
 
.DATA
 
Source          DB      'Hello my dear friend!',0
Find            DB      'dear',0
Fmt             DB      '%d',0
 
.CODE
 
Start:
 
                invoke  InString, 1, ADDR Source, ADDR Find
 
                invoke  crt_printf, ADDR Fmt, eax
 
                invoke  ExitProcess, NULL
 
END             Start