Заменить в исходном файле буквы слов-палиндромов на прописные

LOCALS  @@
 
.model small
 
.stack 100h
 
.data
        ;символы разделители слов
        DelimChars              db      '.,!?;:"() ', "'", 0Ah, 0Dh
        LenDelimChars           dw      $-DelimChars
 
        CrLf            db      0Dh, 0Ah, '$'
        msgPressAnyKey  db      'Press any key to exit...', '$'
 
        ;переменные для файлового обмена
        InFileName      db      'InFile.txt', 0
        InFileHandler   dw      ?
        OutFileName     db      'OutFile.txt', 0
        OutFileHandler  dw      ?
 
        errFileOpen     db      'File open error', '$'
        errFileRead     db      'File read error', '$'
        errFileClose    db      'File close error', '$'
 
        String          db      512 dup(?)
        StrLen          dw      $-String
 
.code
 
;Определяет, принадлежит ли символ в al разделителям слов
;на входе
; al - символ
;на выходе
; ah -  0 (не разделитель), 1 (разделитель)
IsDelimChar     proc
        mov     ah,     0
        pushf
        push    si
        push    di
        push    cx
        push    es
 
        push    ds
        pop     es
        lea     di,     DelimChars
        mov     cx,     LenDelimChars
        cld
        repne   scasb
        jcxz    @@Skip
        jnz     @@Skip
        mov     ah,     1
@@Skip:
        pop     es
        pop     cx
        pop     di
        pop     si
        popf
        ret
IsDelimChar     endp
 
;Проверка слова на симметричность
;на входе:
; si - адрес начала слова
; cx - длина строки
;на выходе:
; al=0 - слово не палиндром
;   =1 - слово - палиндром
IsPalindrome    proc
        push    bx
        push    cx
        push    dx
        push    si
        push    di
 
        mov     di,     si
        add     di,     cx
        dec     di
        shr     cx,     1       ;проверять половину строки
 
@@For:
        mov     al,     [si]
        inc     si
        dec     di
        cmp     al,     [di+1]
        loopz   @@For
        mov     al,     1
        jz      @@Exit
        mov     al,     0
@@Exit:
        pop     di
        pop     si
        pop     dx
        pop     cx
        pop     bx
        ret
IsPalindrome    endp
 
;Замена строчных букв на прописные
;на входе:
; si - адрес начала слова
; cx - длина строки
;на выходе:
; преобразованная строка
UpCase  proc
        push    cx
        push    si
 
        @@For:
                mov     al,     [si]
                cmp     al,     'a'
                jb      @@Next
                cmp     al,     'z'
                ja      @@Next
 
                sub     al,     'a'-'A'
                mov     [si],   al
        @@Next:
                inc     si
        loop    @@For
 
@@Exit:
        pop     si
        pop     cx
        ret
UpCase  endp
 
main    proc
        mov     ax,     @data
        mov     ds,     ax
 
        ;ввод исходной строки из файла
        ; - открытие файлов
        mov     ah,     3Dh
        mov     al,     00h     ;открыть для чтения
        lea     dx,     [InFileName]
        int     21h
        jnc     @@InFileOpenOk
        mov     ah,     09h
        lea     dx,     [errFileOpen]
        int     21h
        jmp     @@Exit
@@InFileOpenOk:
        mov     [InFileHandler],        ax
        ; - читать из файла
        mov     ah,     3Fh
        mov     bx,     [InFileHandler]
        lea     dx,     [String]
        mov     cx,     512
        int     21h
        jnc     @@InFileReadOk
        mov     ah,     09h
        lea     dx,     [errFileRead]
        int     21h
        jmp     @@Exit
@@InFileReadOk:
        mov     [StrLen],       ax
        ; - закрытие файла
        mov     ah,     3Eh
        mov     bx,     [InFileHandler]
        int     21h
        jnc     @@InFileCloseOk
        mov     ah,     09h
        lea     dx,     [errFileClose]
        int     21h
@@InFileCloseOk:
        ;вывод исходной строки на экран
        mov     ah,     40h
        mov     bx,     1
        mov     cx,     [StrLen]
        lea     dx,     [String]
        int     21h
        mov     ah,     09h
        lea     dx,     [CrLf]
        int     21h
 
        lea     si,     [String]
        mov     cx,     [StrLen]
        ;пропускаем все разделители
@@WhileDelimiter:
        mov     al,     [si]
        call    IsDelimChar
        cmp     ah,     0
        je      @@NewWord
        inc     si
        loop    @@WhileDelimiter
 
        jcxz    @@Finish        ;если строка закончилась - выйти
        ;найдено новое слово
@@NewWord:
        mov     dx,     0       ;длина очередного слова пока равна 0
        push    si              ;сохраняем в стеке адрес начала слова
        ;пропускаем все буквы слова до разделителя
@@WhileWord:
        mov     al,     [si]
        call    IsDelimChar
        or      ah,     ah
        jne     @@Break
@@NextChar:
        inc     dx              ;увеличиваем длину слова
        inc     si              ;переходим к следующему символу
        loop    @@WhileWord
@@Break:
        pop     di              ;извлекаем из стека адрес начала слова
        push    si
        push    cx
        mov     si,     di
        mov     cx,     dx
        call    IsPalindrome    ;проверка слова на принадлежность к палиндромам
        pop     cx
        pop     si
        cmp     al,     0
        je      @@Next
        ;если выделенное слово - палиндром, то сделать его буквы прописными
        push    si
        push    cx
        mov     cx,     dx
        mov     si,     di
        call    UpCase
        pop     cx
        pop     si
 
@@Next:
        jcxz    @@Finish
        jmp     @@WhileDelimiter
 
@@Finish:
 
        ;вывод результатов
        ; - на экран
        mov     ah,     40h
        mov     bx,     1
        mov     cx,     [StrLen]
        lea     dx,     [String]
        int     21h
        mov     ah,     09h
        lea     dx,     [CrLf]
        int     21h
        ; - в файл
        ; - открытие файла
        mov     ah,     3Ch
        lea     dx,     [OutFileName]
        mov     cx,     0
        int     21h
        jnc     @@OutFileOpenOk
        mov     ah,     09h
        lea     dx,     [errFileOpen]
        int     21h
        jmp     @@Exit
@@OutFileOpenOk:
        mov     [OutFileHandler],       ax
        ; - записать в файл
        mov     ah,     40h
        mov     bx,     [OutFileHandler]
        lea     dx,     [String]
        mov     cx,     [StrLen]
        int     21h
        jnc     @@OutFileReadOk
        mov     ah,     09h
        lea     dx,     [errFileRead]
        int     21h
        jmp     @@Exit
@@OutFileReadOk:
        mov     [StrLen],       ax
        ; - закрытие файла
        mov     ah,     3Eh
        mov     bx,     [OutFileHandler]
        int     21h
        jnc     @@OutFileCloseOk
        mov     ah,     09h
        lea     dx,     [errFileClose]
        int     21h
@@OutFileCloseOk:
 
@@Exit:
        mov     ax,     4C00h
        int     21h
main    endp
 
end     main