А что находится внутри функции MessageBox или как еще можно создать MessageBox?

; masm windows gui #
.686P
.model flat
;include windows.inc
include native.inc
include ntstatus.inc
includelib user32.lib
includelib ntdll.lib
extern _imp__MessageBoxA@16:dword
extern _imp__MessageBoxW@16:dword
extern _imp__MessageBoxExA@20:dword
extern _imp__MessageBoxExW@20:dword
extern _imp__MessageBoxTimeoutA@24:dword
extern _imp__MessageBoxTimeoutW@24:dword
extern _imp__SoftModalMessageBox@4:dword
extern _imp__MessageBoxIndirectA@4:dword
extern _imp__MessageBoxIndirectW@4:dword
extern _imp__NtRaiseHardError@24:dword
;extern _imp__KiFastSystemCall@0:dword
MB_ICONASTERISK     equ 40h 
MB_OK           equ 0
; structures
MSGBOXPARAMSA STRUCT
  cbSize                DWORD      ?
  hwndOwner             DWORD      ?
  hInstance             DWORD      ?
  lpszText              DWORD      ?
  lpszCaption           DWORD      ?
  dwStyle               DWORD      ?
  lpszIcon              DWORD      ?
  dwContextHelpId       DWORD      ?
  lpfnMsgBoxCallback    DWORD      ?
  dwLanguageId          DWORD      ?
MSGBOXPARAMSA ENDS
 
MSGBOXDATA struct       
     params              MSGBOXPARAMSA <>
     pwndOwner           DWORD ?
     wLanguageId         DWORD ?
     pidButton           DWORD ?         ; // Array of button IDs
     ppszButtonText      DWORD ?         ; // Array of button text strings
     cButtons            DWORD ?
     DefButton           DWORD ?
     CancelId            DWORD ?
     Timeout             DWORD ?
MSGBOXDATA ends
; macros
du  macro string
    irpc c,<string>
    db '&c',0
    endm
    dw 0
    endm
.code
start:  xor ebx,ebx
    mov esi,ebx
    push MB_ICONASTERISK or MB_OK
    push offset MsgCaption
    push [Msg+esi*4]
    push ebx
    call _imp__MessageBoxA@16
;---------------------------------------
    inc esi
    push MB_ICONASTERISK or MB_OK
    push offset TitleText
    push [Msg+esi*4]
    push ebx
    call _imp__MessageBoxW@16
;----------------------------------------
    inc esi
    push ebx
    push MB_ICONASTERISK or MB_OK
    push offset MsgCaption
    push [Msg+esi*4]
    push ebx
    call _imp__MessageBoxExA@20
;-----------------------------------------
    inc esi
    push ebx
    push MB_ICONASTERISK or MB_OK
    push offset TitleText
    push [Msg+esi*4]
    push ebx
    call _imp__MessageBoxExW@20
;-----------------------------------------
    inc esi
        push -1
        push ebx
        push MB_ICONASTERISK or MB_OK
        push offset MsgCaption
        push [Msg+esi*4]
        push ebx
        call _imp__MessageBoxTimeoutA@24
;------------------------------------------
    inc esi
        push -1
        push ebx
        push MB_ICONASTERISK or MB_OK
        push offset TitleText
        push [Msg+esi*4]
        push ebx
        call _imp__MessageBoxTimeoutW@24
;------------------------------------------
        sub esp,sizeof(MSGBOXPARAMSA);40
    mov edi,esp
    assume edi:ptr MSGBOXPARAMSA
    mov dword ptr [edi].cbSize,sizeof(MSGBOXPARAMSA)
    mov dword ptr [edi].hwndOwner,ebx
    mov dword ptr [edi].hInstance,400000h
    mov dword ptr [edi].lpszText,offset Msg8
    mov dword ptr [edi].lpszCaption,offset MsgCaption
    mov dword ptr [edi].dwStyle,MB_ICONASTERISK or MB_OK;:= MB_USERICON;
    mov dword ptr [edi].lpszIcon,ebx;:= PCHAR('MYICO');
    mov dword ptr [edi].dwContextHelpId,ebx;:= 0;
    mov dword ptr [edi].lpfnMsgBoxCallback,ebx;:= nil;
    mov dword ptr [edi].dwLanguageId,ebx;:= LANG_NEUTRAL;   
    push edi
        call _imp__MessageBoxIndirectA@4
;--------------------------------------------------------
    mov dword ptr [edi].cbSize,sizeof(MSGBOXPARAMSA)
    mov dword ptr [edi].hwndOwner,ebx
    mov dword ptr [edi].hInstance,400000h
    mov dword ptr [edi].lpszText,offset Msg9
    mov dword ptr [edi].lpszCaption,offset TitleText
    mov dword ptr [edi].dwStyle,MB_ICONASTERISK or MB_OK
    mov dword ptr [edi].lpszIcon,ebx;:= PCHAR('MYICO');
    mov dword ptr [edi].dwContextHelpId,ebx;:= 0;
    mov dword ptr [edi].lpfnMsgBoxCallback,ebx;:= nil;
    mov dword ptr [edi].dwLanguageId,ebx;:= LANG_NEUTRAL;   
    push edi
        call _imp__MessageBoxIndirectW@4
    add esp,sizeof(MSGBOXPARAMSA)
;-------------------------------------------------------------------------
        sub esp,sizeof MSGBOXDATA+8
;  local mbd:MSGBOXDATA
;  local bufid[1]:DWORD
;  local bufstr[1]:DWORD
    lea eax,[esp+4];bufid
    mov dword ptr[eax],1
    mov [esp],offset _OK
        lea edi,[esp+8]
    mov [edi].cbSize,sizeof MSGBOXPARAMSA
    mov [edi].hwndOwner,ebx
    mov [edi].lpszText,offset Msg7
    mov [edi].lpszCaption,offset TitleText
    mov [edi].dwStyle,MB_ICONASTERISK or MB_OK
        assume edi:ptr MSGBOXDATA
    mov [edi].pwndOwner,ebx;0
    mov [edi].wLanguageId,ebx;0
    mov [edi].pidButton,eax
    mov [edi].ppszButtonText,esp;offset bufstr
    mov [edi].cButtons,1
    mov [edi].DefButton,ebx;0
    mov [edi].CancelId,1
    mov [edi].Timeout,-1
    push edi
    call _imp__SoftModalMessageBox@4
    assume edi:nothing
    add esp,sizeof MSGBOXDATA+8
;------------------------------------------------------------------
ShowMessage proc
Local MessageBuffer[38h]:WCHAR;в Num+Num1 в вордах
Local Message[2]:UNICODE_STRING
Local HardErrorPointer[3]:PVOID
;первый параметр
    lea edi,MessageBuffer
    mov Message.Buffer+sizeof(UNICODE_STRING)*0,edi
    mov Message.MaximumLength+sizeof(UNICODE_STRING)*0,Num
    mov Message._Length+sizeof(UNICODE_STRING)*0,Num-2
    lea edx,Message+sizeof(UNICODE_STRING)*0
    mov HardErrorPointer+sizeof(PVOID)*0,edx;pwText
    mov esi,offset MessageText
    mov ecx,Num+Num1
    rep movsb
;второй параметр
    lea edi,MessageBuffer+Num
    mov Message.Buffer+sizeof(UNICODE_STRING)*1,edi
    mov Message.MaximumLength+sizeof(UNICODE_STRING)*1,Num1
    mov Message._Length+sizeof(UNICODE_STRING)*1,Num1-2
    lea edx,Message+sizeof(UNICODE_STRING)*1
    mov HardErrorPointer+sizeof(PVOID)*1,edx;pwCaption
;третий параметр
        mov HardErrorPointer+sizeof(PVOID)*2,MB_ICONASTERISK+MB_OK;uType
        lea edx,HardErrorPointer
    push offset x;куда функция запишет выбранный юзером ответ (если тип, 
;переданный в следующем параметре, предполагает выбор ответа пользователем)
    push ebx;0 варианты ответов
    push edx;указатель на массив параметров
    push 3;общее число параметров
    push 00000011b;маска, еденичные биты которой соответствуют тем 
;параметрам, которые имеют тип PUNICODE_STRING, а нули -- остальным параметрам
    push STATUS_SERVICE_NOTIFICATION;статус ошибки
    call _imp__NtRaiseHardError@24
;--------------------------------------------------
;меняем первый параметр
    lea edi,MessageBuffer
    mov Message.Buffer+sizeof(UNICODE_STRING)*0,edi
    mov Message.MaximumLength+sizeof(UNICODE_STRING)*0,Num3
    mov Message._Length+sizeof(UNICODE_STRING)*0,Num3-2
    lea edx,Message+sizeof(UNICODE_STRING)*0
    mov HardErrorPointer+sizeof(PVOID)*0,edx;pwText
    mov esi,offset MessageText2
    mov ecx,Num3
    rep movsb
        lea edx,HardErrorPointer
    mov eax,0B6h;ID NtRaiseHardError для WinXP
    push offset x
    push ebx
    push edx
    push 3
    push 00000011b
    push STATUS_SERVICE_NOTIFICATION;статус ошибки
    push offset @f
    mov edx,7FFE0300h
    call dword ptr ds:[edx]
@@:
;--------------------------------------------------
;меняем первый параметр
    lea edi,MessageBuffer
    mov Message.Buffer+sizeof(UNICODE_STRING)*0,edi
    mov Message.MaximumLength+sizeof(UNICODE_STRING)*0,Num4
    mov Message._Length+sizeof(UNICODE_STRING)*0,Num4-2
    lea edx,Message+sizeof(UNICODE_STRING)*0
    mov HardErrorPointer+sizeof(PVOID)*0,edx;pwText
    mov esi,offset MessageText3
    mov ecx,Num4
    rep movsb
        lea edx,HardErrorPointer
    mov eax,0B6h;ID NtRaiseHardError для WinXP
    push offset x
    push ebx
    push edx
    push 3
    push 00000011b
    push STATUS_SERVICE_NOTIFICATION;статус ошибки
    push offset @f
    push offset @f
    mov edx,esp
    db 0Fh,34h;sysenter
@@:
;--------------------------------------------------------
    lea edi,MessageBuffer
    mov Message.Buffer+sizeof(UNICODE_STRING)*0,edi
    mov Message.MaximumLength+sizeof(UNICODE_STRING)*0,Num2
    mov Message._Length+sizeof(UNICODE_STRING)*0,Num2-2
    lea edx,Message+sizeof(UNICODE_STRING)*0
    mov HardErrorPointer+sizeof(PVOID)*0,edx;pwText
    mov esi,offset MessageText1
    mov ecx,Num2
    rep movsb
        lea edx,HardErrorPointer
    mov eax,0B6h;ID NtRaiseHardError для WinXP
    push offset x
    push ebx
    push edx
    push 3
    push 00000011b
    push STATUS_SERVICE_NOTIFICATION;статус ошибки
    mov edx,esp
    int 2Eh
    add esp,18h
    leave
    retn
ShowMessage endp
 
MessageText: du <NtRaiseHardError>
Num = $-MessageText
TitleText: du <Iczelion Tutorial #2:MessageBox>
Num1 = $-TitleText
MessageText1: du <int 2Eh>
Num2 equ $-MessageText1
MessageText2: du <KiFastSystemCall>
Num3 equ $-MessageText2
MessageText3: du <sysenter>
Num4 equ $-MessageText3
x dd 0
Msg dd Msg1,Msg2,Msg3,Msg4,Msg5,Msg6,Msg7,Msg8,Msg9
Msg1    db 'MessageBoxA',0
Msg2:   du <MessageBoxW>
Msg3    db 'MessageBoxExA',0
Msg4:   du <MessageBoxExW>
Msg5    db 'MessageBoxTimeoutA',0
Msg6:   du <MessageBoxTimeoutW>
Msg7:   du <SoftModalMessageBox>
Msg8    db 'MessageBoxIndirectA',0
Msg9:   du <MessageBoxIndirectW>
MsgCaption db "Iczelion Tutorial #2:MessageBox",0
_OK:    du <OK>
end start

format PE GUI
include 'win32ax.inc'
; import data in the same section
 
  invoke    MessageBox,eax,"Win32 Assembly with FASM is Great!",\
   "Iczelion Tutorial #2-2:MessageBox",eax
   retn
data import
 
 library user32,'USER32.DLL'
 import user32,\
    MessageBox,'MessageBoxA'
 
end data

; goasm windows gui #
CODE SECTION
;
START:  push eax
    call @1
db 'Iczelion Tutorial 2#:MessageBox',0
@1: call @2
db 'Win32 Assembly with GoAsm is Great!',0
@2: push eax
    call d[MessageBoxA]
    retn

; nasm windows gui #
%define ONLY_NASM 
%include "nagoa+.inc"
%include "defines.inc"
section .text
start:
    invoke MessageBox,0,Message,wTitle,MB_OK+MB_SYSTEMMODAL
    retn
 
  wTitle   db 'Iczelion Tutorial #2:MessageBox',0
  Message db 'Win32 Assembly with NASM is Great!',0
 
LAST_BEGIN
 
__LIBS_   user32,  'user32.DLL'
 
__IMPORT_ user32,\
          MessageBox,'MessageBoxA',0
 
LAST_END

.CPU 686
.BITS 32
.ENTRYPOINT
 
INVOKE MessageBox,BYTE 0,DWORD Text,DWORD Title,BYTE 0
INVOKE ExitProcess,BYTE 0
 
Title: DSTR "Assembler Example\0"
Text: DSTR "Hello World\0"
 
.LIBRARY "kernel32.dll"
IMPORT ExitProcess "ExitProcess"
 
.LIBRARY "user32.dll"
IMPORT MessageBox "MessageBoxA"

; wasm windows gui #
.686P
.model flat
extern __imp__MessageBoxA@16:dword
.code
start:  push eax
    push offset msgBoxCaption
    push offset msgBoxText
    push eax
    call __imp__MessageBoxA@16
    ret
msgBoxText db 'Win32 Assembly with WASM is Great!',0
msgBoxCaption db 'Iczelion Tutorial #2:MessageBox',0
end start

____________________________________________________________________________________________
 
; MsgBox1.asm  RosAsm            [url]http://betov.free.fr/[/url]
; Affichage d'une boîte a message
; Programmé par AsmGges          [url]http://www.chez.com/asmgges/index.htm[/url]
___________________________________________________________________________________________
 
Main:
    ; affichage d'une boîte à message
    ; -------------------------------
    call 'USER32.MessageBoxA' &NULL Message Titre &MB_OK
 
    ; fin du programme
    ; ----------------
    call 'KERNEL32.ExitProcess' &NULL
___________________________________________________________________________________________
 
; Définitions des datas chaînes / variables initialisées ou non / équates / structures
___________________________________________________________________________________________
 
[Titre:    B$ "AsmGges Win32" 0]
[Message:  B$ "Bonjour ! Comment allez-vous ?" 0]
___________________________________________________________________________________________
 
; Macros définies par l'utilisateur
___________________________________________________________________________________________
 
[push | push #1 | #+1]
[call | push #L>2 | call #1]
___________________________________________________________________________________________

; lzasm windows gui #
option ansi;unicode
model flat,stdcall
 
includelib "d:\Ass_new\lib\win32.lib"
procdesc MessageBoxA :dword,:dword,:dword,:dword
 
codeseg
 
    startupcode
    call MessageBoxA,eax,offset msgBoxText,offset msgBoxCaption,eax
    retn;exitcode
msgBoxText  db "Win32 Assembly with LZASM is Great!",0
msgBoxCaption   db "Iczelion Tutorial #2:MessageBox",0

; tasm windows gui #
.386
.model flat
includelib import32.lib
include windows32.inc
extern MessageBoxA:PROC
.code
start:
    push MB_OK + MB_SYSTEMMODAL
    push offset wTitle   
    push offset Message
    push eax
    call MessageBoxA
    ret             ;выход из программы
wTitle  db 'Iczelion Tutorial #2:MessageBox',0
Message db 'Win32 Assembly with tasm is Great!',0
ends
end start

; masm windows gui #
.686P
.model flat
include windows.inc
includelib user32.lib
extern _imp__MessageBoxA@16:dword
.code
start:  push eax;MB_OK
    push offset MsgCaption
    push offset MsgBoxText
    push eax
    call _imp__MessageBoxA@16
    ret;    invoke ExitProcess,NULL
MsgCaption      db "Iczelion Tutorial #2:MessageBox",0
MsgBoxText      db "Win32 Assembly with masm is Great!",0
end start

    org 0x100
start:
    mov si, DLL_NAME
    mov di, INIT_PROC
; comment out for no init proc...
    xor di, di
    push    di
    pop es
    mov bx, DISPATCHER
    db  0xc4, 0xc4, 0x58, 0x0   ; register
    jc  error
    mov [DLL_HANDLE], ax
    mov al, 'L'         ; loaded
    int 0x29
 
    mov ax, [DLL_HANDLE]
    mov cx, message_end - message_start
    mov si, message_start
    db  0xc4, 0xc4, 0x58, 0x2   ; invoke dispatcher
    cmp ax, 0x2005      ; check return value...
    jnz no_ret
    mov al, 'R'
    int 0x29
    jmp skip
no_ret:
    mov al, 'N'
    int 0x29
skip:
;...
;...
    mov ax, [DLL_HANDLE]
    db  0xc4, 0xc4, 0x58, 0x1   ; unregister
    ret
error:
    mov al, '!'
    int 0x29
    ret
 
DLL_HANDLE: dw 0
DLL_NAME: db "3rd_party.dll", 0
INIT_PROC: db "InitProc_", 0
DISPATCHER: db "Dispatch_", 0
message_start:
    db  "Hello from DOS!",0
message_end:

; masm dos com #
.586p
.model tiny
;for WinXP - 298 bytes
include windows.inc
.code
exebase         equ 400000h
main:
;signatures----------------------------
dosHeader       dd IMAGE_DOS_SIGNATURE;'MZ'
ntHeader        dd IMAGE_NT_SIGNATURE;'PE'
;image_header--------------------------
Machine         dw IMAGE_FILE_MACHINE_I386; (Intel386)
Count_of_section    dw 1
TimeStump       dd 0;
Symbol_table_offset dd 0;
Symbol_table_count  dd 0;
Size_of_optional_header dw section_table-optional_header;
Characteristics     dw IMAGE_FILE_32BIT_MACHINE or \
 IMAGE_FILE_RELOCS_STRIPPED or IMAGE_FILE_EXECUTABLE_IMAGE or \
 IMAGE_FILE_LINE_NUMS_STRIPPED or IMAGE_FILE_LOCAL_SYMS_STRIPPED
;-------------------------------------
optional_header:
Magic_optional_header   dw IMAGE_NT_OPTIONAL_HDR32_MAGIC
Linker_version_major_and_minor dw 0 
Size_of_code        dd end_import-start;
Size_of_init_data   dd 0;
Size_of_uninit_data dd 0;
entry_point     dd start;
base_of_code        dd start;
base_of_data        dd 0;
image_base      dd exebase;
e_lfanew        dd ntHeader-dosHeader;section alignment
file_alignment      dd 4;
OS_version_major_minor  dd 4;
image_version_major_minor dd 0;
subsystem_version_major_minor dd 4;
reserved1       dd 0;
size_of_image       dd end_import;
size_of_header      dd start;
checksum        dd 0;
subsystem_and_DLL_flag  dd IMAGE_SUBSYSTEM_WINDOWS_GUI
Stack_allocation    dd 100000h;
Stack_commit        dd 1000h;
Heap_allocation     dd 100000h;
Heap_commit     dd 1000h;
loader_flag     dd 0;
number_of_dirs      dd (section_table-export_RVA)/8;
export_RVA          dd 0
export_size         dd 0
import_RVA          dd import
import_size         dd end_import-import
;------------------------------------------------
section_table       dd 'xet.','t';resource_RVA_and_resource_size
virtual_size        dd 0;exeption_RVA
virtual_address     dd start;exeption_size
Physical_size       dd end_import-start;security_RVA
Physical_offset     dd start;security_size
Relocations         dd 0;fixups_RVA
Linenumbers     dd 0;fixups_size
Relocations_and_Linenumbers_count dd 0;debug_RVA
Attributes              dd 00;0E0000020h;debug_size
;---------------------------------------------------------------------
start:  push eax;MB_OK              
    push offset wTitle+exebase  
    push offset Message+exebase 
    push eax                    
    call MessageBox+exebase     
    retn                        
;----------------------------------------------------------------------
wTitle  db 'Iczelion Tutorial #2',0   
Message db 'Win32 Assembly is Great!'  
;----------------------------------------------------------------------
import  dd 0;значение смещения от начала секции import до начала массива 
;с адресами импортируемых функций ArrayAddressImpFunc (первая копия)
        dd 0
        dd 0
    dd user32_dll;значение смещения от начала секции import 
;до начала ACSIIZ-строки с именем dll-библиотеки
    dd MessageBox;значение смещения от начала секции import до начала
;массива с адресами импортируемых функций ArrayAddressImpFunc (вторая копия)
        dd 0
        dd 0             
MessageBox      dd _MessageBoxA
        dw 0          
_MessageBoxA db 0,0,'MessageBoxA',0 ;          
user32_dll  db 'user32'                      
end_import:
end main

    .386
    .model flat, stdcall  ; 32 bit memory model
    option casemap :none  ; case sensitive
      
     include \MASM32\INCLUDE\windows.inc
     include \MASM32\INCLUDE\user32.inc
     include \MASM32\INCLUDE\kernel32.inc
 
     includelib \MASM32\LIB\user32.lib
    includelib \MASM32\LIB\kernel32.lib
.data
    _user32         db 'user32.dll',0
    _MessageBox     db 'MessageBoxA',0
    beg_            dd 0
    address         dd 0
    memory      dd 0
    MyMessage   dd 0
    
.code
start:
    invoke GetFocus 
    invoke GetModuleHandle, addr _user32
    mov beg_,eax    
    invoke GetProcAddress,eax,addr _MessageBox
    mov address,eax
    
    invoke GlobalAlloc,GMEM_FIXED,67FFEh
    mov memory,eax  
    mov edi,eax
    mov esi,beg_
    mov ecx,67FFEh
    rep movsb
        
    mov eax,address
    sub eax,beg_
    add eax,memory
    mov MyMessage,eax
    
    push 0
    push offset _MessageBox
    push offset _user32
    push 0
    call MyMessage
    
    invoke GlobalFree,memory
    invoke ExitProcess,0
    ret
end start

format PE GUI 4.0 DLL
entry DllEntryPoint
 
include 'win32a.inc'
section '.data' data writeable readable 
 
_ntvdm  db  'NTVDM.EXE',0
hell    db  'Awaken from DOS HELL',0
;hndl   dd      ?
_s  dd  ?
_ptr    dd  ?
_ds dd  ?
_si dd  ?
_di dd  ?
_cx dd  ?
section '.text' code readable executable 
proc DllEntryPoint hinstDLL,fdwReason,lpvReserved
;       invoke  MessageBox,NULL,hell,hell,MB_ICONERROR+MB_OK
    mov eax,TRUE
    ret
endp
 
proc InitProc 
;       mov     eax,TRUE
;       invoke  MessageBox,NULL,hell,hell,MB_ICONERROR+MB_OK
    ret
endp
 
 
proc Dispatch
  local hndl:DWORD
    invoke  MessageBox,NULL,hell,hell,MB_ICONERROR+MB_OK
    invoke  LoadLibrary, _ntvdm
        cmp    eax, -1
        jnz    @F
        ret
@@:     mov    [hndl], eax
        invoke GetProcAddress, [hndl], 87      ; getDS
        call   eax
        mov    [_ds], eax
        invoke GetProcAddress, [hndl], 109     ; getSI
        call   eax
        mov    [_si], eax
        invoke GetProcAddress, [hndl], 82      ; getCX
        call   eax
        mov    [_cx], eax
        invoke GetProcAddress, [hndl], 14      ; MGetVdmPointer
        mov    [_ptr], eax
        push   0                               ; FALSE
        push   [_cx]
    mov     edx, [_ds]                      ; _ds << 16 + _si
    shl     edx, 10h                        ;
    add     edx, [_si]                      ;
    push    edx                             ;
    call    eax                             ; PBYTE MGetVdmPointer( ULONG Address, ULONG Size, UCHAR ProtectedMode);
    mov     [_s], eax                       ; 
    invoke  MessageBox,NULL,_s,hell,MB_ICONERROR+MB_OK
    invoke  FreeLibrary,[hndl]
        invoke GetProcAddress, [hndl], 122     ; setAX
    push    2005H 
        call   eax
    ret
endp
 
data fixups
end data
 
section '.idata' import data readable writeable
 library kernel32,'KERNEL32.DLL',\
    user32,'user32.dll'
 
 import kernel32,\
    LoadLibrary,'LoadLibrary',\
    FreeLibrary,'FreeLibrary',\
    GetProcAddress,'GetProcAddress'
 
 import user32,\
    MessageBox,'MessageBoxA'
 
section '.edata' export data readable
 
  export '3rd_party.dll',\
    InitProc,'InitProc_',\
    Dispatch,'Dispatch_'

format PE GUI 4.0 DLL
include 'win32a.inc'
 
entry $
    mov eax,TRUE
ret 16
 
Dispatch:
    call   [getDS]
    mov    [_ds],ax
    call   [getSI]
    mov    [_si],ax
    call   [getCX]
    movzx  eax,ax
    invoke MGetVdmPointer,dword[_si],eax,0
    invoke MessageBoxA,0,eax,hell,MB_ICONERROR+MB_OK
ret
 
hell  db  'Awaken from DOS HELL',0
_si   dw  ?
_ds   dw  ?
 
align 8
data fixups
end data
 
align 8
data import
 library user32,'user32.dll',\
         ntvdm,'NTVDM.EXE'
 
 import user32,\
        MessageBoxA,'MessageBoxA'
 
 import ntvdm,\
        getDS,'getDS',\
        getSI,'getSI',\
        getCX,'getCX',\
        MGetVdmPointer,'MGetVdmPointer'
end data
 
align 8
data export
export '1.dll',\
       Dispatch,'Dispatch_'
end data

org 100h
    mov  si, DLL_NAME
    xor  di, di
    push di
    pop  es
    mov  bx, DISPATCHER
    db   0xc4, 0xc4, 0x58, 0x0   ; register
    mov  [DLL_HANDLE],ax
 
    mov cx, message_end - message_start
    mov si, message_start
    db  0xc4, 0xc4, 0x58, 0x2   ; invoke dispatcher
 
    mov ax, [DLL_HANDLE]
    db  0xc4, 0xc4, 0x58, 0x1   ; unregister
    ret
 
DLL_HANDLE: dw 0
DLL_NAME:   db "1.dll", 0
DISPATCHER: db "Dispatch_", 0
message_start:
    db  "Hello from DOS!",0
message_end:

macro   RegisterModule { dd 0058C4C4h }
macro   UnRegisterModule { dd 0158C4C4h }
macro   DispatchCall { dd 0258C4C4h }
 
    org 100h
start:
    mov si, DLL_NAME
;   mov di, DLL_INIT
; comment out for no init proc...
    xor di, di
    push    di
    pop es
    mov bx, DISPATCHER
    RegisterModule   
    jc  error
    mov [DLL_HNDL], ax
    mov al, 'L'         ; loaded
    int 0x29
 
    mov ax, [DLL_HNDL]
    mov cx, msg_sz
    mov si, msg
    DispatchCall    
    cmp ax, 0x2005      ; check return value...
    jnz no_ret
    mov al, 'R'
    int 0x29
    jmp skip
no_ret:
    mov al, 'N'
    int 0x29
skip:
;...
;...
    mov ax, [DLL_HNDL]
    UnRegisterModule
    ret
;       Client AX = Error Code
;           AX = 1 - DLL not found
;           AX = 2 - Dispacth routine not found.
;           AX = 3 - Init Routine Not Found
;           AX = 4 - Insufficient Memory
 
error:
    or  al,30h      
    int 0x29
    ret
 
DLL_HNDL:   dw 0
DLL_NAME:   db "3rd_party.dll", 0
DLL_INIT:   db "InitProc_", 0
DISPATCHER: db "Dispatch_", 0
msg:        db  "Hello from DOS!",0
msg_sz      = $ - msg

;------------------------------------------------------
; Sol_Asm assembler core
; Copyright (c) 2004-2007, Bogdan Valentin Ontanu.
; All rights reserved.
;------------------------------------------------------
 
;------------------------------------------------------------------
; This file is used to test Sol_ASM
; win32_pe format generation
;------------------------------------------------------------------
 
import_dll  user32.dll
import_func MessageBox alias MessageBoxA
 
 
section "code"      class_code
section "idata"     class_imports
section "data"      class_data
 
 
.data
 
sz_message  db  "First Win32 PE application",0
sz_title    db  "Sol_ASM",0
 
 
.code
 
    invoke  MessageBox, 0, sz_message, sz_title, 3
 
    ret

; yasm windows gui #
; yasm -f bin hello.asm -o hello.exe
%define exebase     0x400000
%define MB_OK       0
%macro invoke 1-*  ; macro to call Win32 API functions
    %rep %0 - 1     ; repeat for each argument
        %rotate -1  ; rotate right (last becomes %1)
        push %1     ; push argument
    %endrep
    %rotate -1      ; %1 = function name
    call  [%1]      ; call API function via IAT
%endm
[BITS 32]
org exebase
;for WinXP - 335 bytes
dd 'MZ','PE',1014Ch,0,0,0,10F0080h,10Bh,END_SECTION-start,0,0,start-exebase
dd start-exebase,0,exebase,4,4,4,0,4,0,END_SECTION-exebase,start-exebase,0,2
dd 100000h,1000h,100000h,1000h,0,4,0,0,import-exebase,end_import-import,0,0,0
dd 0,'.text',0,start-exebase,END_SECTION-start,start-exebase,0,0,0,0E0000020h
;---------------------------------------------------------------------
start:  invoke MessageBox,eax,Message,wTitle,eax;MB_OK
        retn
;----------------------------------------------------------------------
wTitle  db 'Iczelion Tutorial #2:MessageBox',0
Message db 'Win32 Assembly with Yasm is Great!'
;----------------------------------------------------------------------
import:
dd 0,0,0,user32_dll-exebase
dd user32_table-exebase
dd 0,0
user32_table:
MessageBox      dd _MessageBoxA-exebase
                dw 0
_MessageBoxA    db 0,0,'MessageBoxA',0      
user32_dll  db 'user32'
end_import:
END_SECTION:

; masm windows dll #
.686
.model flat
include windows.inc
include ntvdm.inc
includelib ntvdm.lib
;------------------------------------
NO_BUTTON      equ 0  ; No button
SEB_OK         equ 1  ; Button with "OK".     
SEB_CANCEL     equ 2  ; Button with "Cancel"  
SEB_YES        equ 3  ; Button with "&Yes"     
SEB_NO         equ 4  ; Button with "&No"      
SEB_RETRY      equ 5  ; Button with "&Retry"   
SEB_ABORT      equ 6  ; Button with "&Abort"   
SEB_IGNORE     equ 7  ; Button with "&Ignore"  
SEB_CLOSE      equ 8  ; Button with "&Close"
SEB_DEFBUTTON  equ 8000h  ; Mask to make this button default 
;-------------------------------------
.data
hell  db  'Awaken from DOS HELL',0
message db 'Hello from DOS!',0
 
.code
DllEntry proc hInst:HINSTANCE, reason:DWORD, reserved1:DWORD
    mov eax,TRUE
    ret
DllEntry endp
 
Dispatch_ proc
    invoke WOWSysErrorBox,addr message,addr hell,SEB_OK,NO_BUTTON,NO_BUTTON
    ret
Dispatch_ endp
end DllEntry

LIBRARY 1
EXPORTS 
Dispatch_

; masm dos com #
.286
.model tiny
.code
BOP_3RDPARTY equ 58h
org 100h
start:
comment * -------------------------------------------------------------
 RegisterModule - This Bop call is made from the 16 bit module
        to register a third party DLL with the bop
        manager. This call returns a handle to the
        16bit caller which is to be used later to
        dispatch a call to the DLL.
 
   INPUT:
   Client DS:SI - asciiz string of DLL name.
       Client ES:DI - asciiz string of Init Routine in the DLL. (Optional)
   Client DS:BX - asciiz string to Dispatch routine in the DLL.
 
   OUTPUT:
   SUCCESS:
       Client Carry Clear
       Client AX = Handle (non Zero)
   FAILURE:
       Client Carry Set
       Client AX = Error Code
       AX = 1 - DLL not found
       AX = 2 - Dispacth routine not found.
       AX = 3 - Init Routine Not Found
       AX = 4 - Insufficient Memory
 
   NOTES:
   RegisterModule results in loading the DLL (specified in DS:SI).
       Its Init routine (specified in ES:DI) is called. Its Dispatch
   routine (specified in DS:BX) is stored away and all the calls
       made from DispatchCall are dispacthed to this routine.
       If ES and DI both are null than the caller did'nt supply the init
       routine.
----------------------------------------------------------------- *
 
    mov si,offset DLL_NAME
    xor di,di
    push di
    pop es
    mov bx,offset DISPATCHER
db 0C4h, 0C4h, BOP_3RDPARTY, 0    ; register
    mov DLL_HANDLE,ax
 
comment *  -----------------------------------------------------------
 DispacthCall - This Bop call is made from the 16 bit module
      to pass a request to its DLL.
 
   INPUT:
   Client AX - Handle returned by RegisterModule Call.
 
   OUTPUT:
   None (DLL should set the proper output registers etc.)
   (VDM Is terminated with a debug message if Handle is invalid)
 
   NOTES:
   Use it to pass a request to 32bit DLL. The request index and the
   parameters are passed in different registers. These register settings
   are private to the 16bit module and its associated VDD. Bop manager
   does'nt know anything about these registers. 
------------------------------------------------------------------- *
 
db 0C4h, 0C4h, BOP_3RDPARTY, 2   ; invoke dispatcher
 
comment * ---------------------------------------------------------
 UnRegisterModule - This Bop call is made from the 16 bit module
          to unregister a third party DLL with the bop
          manager.
 
   INPUT:
   Client AX - Handle returned by RegisterModule Call.
 
   OUTPUT:
   None (VDM Is terminated with a debug message if Handle is invalid)
 
   NOTES:
   Use it if initialization of 16bit app fails after registering the
   Bop. 
------------------------------------------------------------------ *
 
    mov ax,DLL_HANDLE
db 0C4h, 0C4h, BOP_3RDPARTY, 1   ; unregister
    retn
 
DLL_HANDLE dw 0
DLL_NAME   db "1.dll", 0
DISPATCHER db "Dispatch_", 0
end start