Подсчитать количество цифр в файле и вывести на экран

;DOS, TASM, COM-файл
;tasm.exe /m filename.asm
;tlink.exe /t /x filename.obj
;
.model tiny
.code
.386
ORG 100h
START:
;
    lea dx,prigl
    mov ah,9
    int 21h
;-------------------
    lea dx,max
    mov di,dx
    mov ah,0ah  ;Ввод имени файла
    int 21h
 
    inc di      ;на число введенных символов
    xor bx,bx
 
    mov bl,[di] ;число введенных символов
    inc di      ;на введенную строку
    mov byte ptr [di+bx],0 ;в конец строки записать
 
;открытие файла----------------------------------
    mov ah, 3Dh
    mov al,0    ;для чтения
    mov dx,di
    int 21h
    jc error
 
;-Чтение из файла
    mov bx,ax   ;handle
    mov si,ax   ;сохранить для закрытия файла
    mov ah, 3fh
    lea dx,cc   ;буфер для чтения
    mov cx,-1   ;максимальный размер
    int 21h
    test ax,ax  ;0 прочитано?
    jz error
    mov cx,ax   ;прочитанных байт
    mov di,dx   ;сохранить адрес буфера
 
;-Закрыть файл
    mov ah, 3eh
    int 21h
 
    lea dx,ind
    mov ah,9
    int 21h
 
;подсчет цифр
    call Schet
 
;преобразование и вывод на экран
    call Bin2ASCII
    jmp short exit
error:
    lea dx,errst
    mov ah,9
    int 21h
exit:
    xor ax,ax   ;ждать нажатой клавиши
    int 16h
    ret ;выход из программы
Bin2ASCII   proc    near
    mov     bx, 10 ; основание сс. 10 для десятеричной и т.п.
oi2:
    xor     dx,dx
    div     bx
; Делим число на основание сс. В остатке получается последняя цифра.
; Сразу выводить её нельзя, поэтому сохраним её в стэке.
    push    dx
    inc     cx
; А с частным повторяем то же самое, отделяя от него очередную
; цифру справа, пока не останется ноль, что значит, что дальше
; слева только нули.
    test    ax, ax
    jnz     oi2
; Теперь приступим к выводу.
    mov     ah, 02h
oi3:
    pop     dx
; Извлекаем очередную цифру, переводим её в символ и выводим.
    add     dl, '0'
    int     21h
; Повторим ровно столько раз, сколько цифр насчитали.
    loop    oi3
    ret
Bin2ASCII   endp
;----------------------------
Schet   proc    near
    xor ax,ax   ;обнулить счетчик
m3:
;проверка, символ является числом или нет
    cmp byte ptr [di],'0'  ; если введен неверный символ <0
    jl short m4
    cmp byte ptr [di],'9'  ; если введен неверный символ >9
    ja short m4
    inc ax  ;счетчик
m4:
    inc di
    loop m3
 
    ret
Schet   endp
;-----Данные-------
prigl db '‚ўҐ¤ЁвҐ Ё¬п д*©«*: $'
errst db 13,10,'ЋиЁЎЄ*!$'
ind   db 13,10,'Љ®«ЁзҐбвў® жЁда ў д*©«Ґ: $'
cc:
max db 80
len db ?
fname:
    end start