Вывод результата вычислений на экран - запутался совсем

ssg segment para stack 'stack'  
dw 32 dup(?)                        
ssg ends           
                    
 
datasg segment para 'data'          
Strg1 db 'Введите первое число:','$'
Strg2 db 'Введите второе число:','$'
menu db '1: операция +',13,10
     db '2: операция -',13,10
     db '3: операция *',13,10
     db '4: операция /',13,10,'$'
Tmp1 dw ?
Tmp2 dw ?
Tmp3 dw ? 
Out1 dw 20 dup (' ')
Out2 dw 20 dup (' ')
Pl db ' + '
R db ' = '
res dw 20 dup (' ')
ends                                
 
 
codesg segment para 'code'          
begin proc far                      
;-------------------------------------------------------------------------
assume cs:codesg,ds:datasg,ss:ssg
push ds                               
sub ax,ax                           
push ax                              
mov ax,datasg                     
mov ds,ax                           
;-------------------------------------------------------------------------
;clr scr
mov ax,0600h
mov bh,70h
mov cx,0000
mov dx,184fh
int 10h
;clr scr  2
mov ax,0600h
mov bh,2eh
mov cx,094fh
mov dx,0000
int 10h 
 
;loc white
mov ah,02
mov bh,00
mov dh,07
mov dl,00
int 10h
;white
mov ah,09
mov al,'w'
mov bh,00
mov bl,77h
mov cx,80
int 10h
;loc blue
mov ah,02
mov bh,00
mov dh,08
mov dl,00
int 10h
;blue
mov ah,09
mov al,'b'
mov bh,00
mov bl,11h
mov cx,340
int 10h
;loc blue - 2
mov ah,02
mov bh,00
mov dh,12
mov dl,60
int 10h
;blue - 2
mov ah,09
mov al,'b'
mov bh,00
mov bl,11h
mov cx,267
int 10h 
;loc red
mov ah,02
mov bh,00
mov dh,16
mov dl,00
int 10h
;red
mov ah,09
mov al,'r'
mov bh,00
mov bl,44h
mov cx,640
int 10h
;figure loc
mov ah,02
mov bh,00
mov dh,10
mov dl,20
int 10h
;figure
mov ah,09
mov al,'f'
mov bh,00
mov bl,22h
mov cx,40
int 10h
;figure loc - 2
mov ah,02
mov bh,00
mov dh,11
mov dl,20
int 10h
;figure - 2
mov ah,09
mov al,'f'
mov bh,00
mov bl,22h
mov cx,40
int 10h
;figure loc - 3
mov ah,02
mov bh,00
mov dh,12
mov dl,20
int 10h
;figure - 3
mov ah,09
mov al,'f'
mov bh,00
mov bl,22h
mov cx,1
int 10h
;figure loc - 3-2
mov ah,02
mov bh,00
mov dh,12
mov dl,59
int 10h
;figure - 3-2
mov ah,09
mov al,'f'
mov bh,00
mov bl,22h
mov cx,01
int 10h
;figure loc - 4
mov ah,02
mov bh,00
mov dh,13
mov dl,20
int 10h
;figure - 4
mov ah,09
mov al,'f'
mov bh,00
mov bl,22h
mov cx,40
int 10h
 
;1 operand
 
;loc strg1
Mov ah,02
Mov bh,00
Mov dh,00
Mov dl,00
Int 10h
;message
Mov ah,09
Lea dx,strg1
Int 21h
;vvod
Mov ah,3fh
Mov bx,00
Mov cx,20
Lea dx,out1
Int 21h
Mov tmp1,ax
                   ;loc string
                   ;mov ah,02
                   ;mov bh,00
                   ;mov dh,12
                   ;mov dl,al
                   ;int 10h
                 ;string
                 ;Mov ah,40h
                 ;Mov bx,00
                 ;Mov cx,38
                 ;Lea dx,outstr
                 ;Int 21h
 
 
;2 operand
 
;loc strg2
Mov ah,02
Mov bh,00
Mov dh,01
Mov dl,00
Int 10h
;message
Mov ah,09
Lea dx,strg2
Int 21h
;vvod
Mov ah,3fh
Mov bx,00
Mov cx,20
Lea dx,out2
Int 21h
Mov tmp2,ax
 
;operator
 
;loc strg3
Mov ah,02
Mov bh,00
Mov dh,02
Mov dl,00
Int 10h
;message
Mov ah,09
Lea dx,menu
Int 21h
;vvod
mov ah,00
int 16h
 
;uslovniy perehod
 
Cmp al,'1'
Je plus
Cmp al,'2'
Je minus
Cmp al,'3'
Je X
Cmp al,'4'
Je del
 
Plus:
;slojenie
Mov dx,out1
add dx,out2
Mov res,dx
;v al koordinata stolba
Mov ax,40
Mov dx,tmp1
Add dx,tmp2
Sub ax,dx
 
;loc string
mov ah,02
mov bh,00
mov dh,12
mov dl,al
int 10h
 
Lea dx,out1
call out_strg
Lea dx,pl
call out_strg
Lea dx,out2
call out_strg
lea dx,r
call out_strg
lea dx,res
call out_strg
int 20h
 
out_strg proc
    Mov ah,09h
    Mov bx,00
    Mov cx,20 
    Int 21h
   ret
out_strg endp
 
Minus:
Del:
X:
 
 
 
;-------------------------------------------------------------------------
ret             
begin endp      
codesg ends     
end begin

use16
org 100h
main:
    mov ax,03h
    int 10h
 
    mov ah,9
    mov dx,msg2
    int 21h
 
    ;ввод первого числа
    call InputInt
    mov [number1],ax
    ;ввод второго числа
    call InputInt
    mov [number2],ax
    ;ввод операции
    @@:
    mov ah,0ah
    xor di,di
    mov dx,main.buff
    int 21h
    ;проверка ввода
    mov al,[main.buff+2]
 
    cmp al,'-'
    je OpSub
 
    cmp al,'+'
    je OpAdd
 
    cmp al,'*'
    je OpMul
 
    cmp al,'/'
    je OpDiv
 
    jmp @b
    ;Вычисление результата
    OpSub:
    mov ax,[number1]
    sub ax,[number2]
    jmp Output
    OpAdd:
    mov ax,[number1]
    add ax,[number2]
    jmp Output
    OpMul:
    mov ax,[number1]
    imul ax,[number2]
    jmp Output
    OpDiv:
    mov ax,[number1]
    mov dx,0
    test ax,8000h
    jz @f
       mov dx,0FFFFh
    @@:
    idiv [number2]
    ;Вывод выражения
    Output:
    push ax
    mov ax,[number1]
    call OutInt
 
    mov ah,02h
    mov dl,' '
    int 21h
    mov dl,[main.buff+2]
    int 21h
    mov dl,' '
    int 21h
 
    mov ax,[number2]
    call OutInt
 
    mov ah,02h
    mov dl,' '
    int 21h
    mov dl,'='
    int 21h
    mov dl,' '
    int 21h
 
    pop ax
    call OutInt
 
    mov ah,9
    mov dx,msg1
    int 21h
 
    mov ah,0ah
    xor di,di
    mov dx,main.buff
    int 21h
 
    cmp [main.buff+2],'y'
    je main
 
    int 20h
 
number1 dw 0
number2 dw 0
main.buff db 2,0,0,0
msg1 db 13,10,"Again?(y/n)$"
msg2 db "Enter 1st operand, 2nd operand and operation(+,-,*,/)",13,10,'$'
 
OutInt:
   pusha
; Проверяем число на знак.
   test    ax, ax
   jns     oi1
 
; Если оно отрицательное, выведем минус и оставим его модуль.
   mov  cx, ax
   mov     ah, 02h
   mov     dl, '-'
   int     21h
   mov  ax, cx
   neg     ax
; Количество цифр будем держать в CX.
oi1:
    xor     cx, cx
    mov     bx, 10 ; основание сс. 10 для десятеричной и т.п.
oi2:
    xor     dx,dx
    div     bx
; Делим число на основание сс. В остатке получается последняя цифра.
; Сразу выводить её нельзя, поэтому сохраним её в стэке.
    push    dx
    inc     cx
; А с частным повторяем то же самое, отделяя от него очередную
; цифру справа, пока не останется ноль, что значит, что дальше
; слева только нули.
    test    ax, ax
    jnz     oi2
; Теперь приступим к выводу.
    mov     ah, 02h
oi3:
    pop     dx
; Извлекаем очередную цифру, переводим её в символ и выводим.
;; раскоментировать если основание сс > 10, т.е. для вывода требуются буквы
;   cmp     dl,9
;   jbe     oi4
;   add     dl,7
;oi4:
    add     dl, '0'
    int     21h
; Повторим ровно столько раз, сколько цифр насчитали.
    loop    oi3
 
    popa
    ret
 
 
InputInt:
    push di
    push dx
    push si
    push cx
 
    mov ah,0ah
    xor di,di
    mov dx,buff ; аддрес буфера
    int 21h ; принимаем строку
    mov dl,0ah
    mov ah,02
    int 21h ; выводим перевода строки
    
; обрабатываем содержимое буфера
    mov si,buff+2 ; берем аддрес начала строки
    cmp byte [si],"-" ; если первый символ минус
    jnz ii1
    mov di,1  ; устанавливаем флаг
    inc si    ; и пропускаем его
ii1:
    xor ax,ax
    mov bx,10  ; основание сc
ii2:
    mov cl,[si] ; берем символ из буфера
    cmp cl,0dh  ; проверяем не последний ли он
    jz endin
    
; если символ не последний, то проверяем его на правильность
    cmp cl,'0'  ; если введен неверный символ <0
    jl er
    cmp cl,'9'  ; если введен неверный символ >9
    ja er
 
    sub cl,'0' ; делаем из символа число 
    mul bx     ; умножаем на 10
    add ax,cx  ; прибавляем к остальным
    inc si     ; указатель на следующий символ
    jmp ii2 ; повторяем
 
er:   ; если была ошибка, то выводим сообщение об этом и выходим
    mov dx,error
    mov ah,09
    int 21h
    int 20h
 
; все символы из буфера обработаны число находится в ax
endin:
    cmp di,1 ; если установлен флаг, то
    jnz ii3
    neg ax   ; делаем число отрицательным
ii3:
 
    pop cx
    pop si
    pop dx
    pop di
    ret
 
error db "incorrect number$"
buff    db 6,7 Dup(?)