Как записать в файл текст emu8086

@Belena123321 · Регистрация: 10.12.2018

Студворк — интернет-сервис помощи студентам

Подскажите, пожалуйста, как записать текст в файл. Мне нужно что бы я ввела с клавиатуры данные, а они записались в файл.

Assembler
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
#make_COM#
 
; COM file is loaded at CS:0100h
ORG 100h
;- - - - - Adresy Failiw------
Y1 db 'Y1.TXT', 0; адресный файл
start:  mov ax,3
    int 10h
    mov ah,9
    mov dx,offset mes1
    int 21h
    mov ah,0Ah
    mov dx,offset buff
    int 21h
    mov bh,0
    mov bl,buff+1
    mov buff[bx+2],'$'
    mov word ptr buff,' !'
    mov ax,3
    int 10h
    mov ah,9
    mov dx,offset mes2
    int 21h
    mov ah,0Ah
    mov dx,offset buff2
    int 21h
    mov bh,0
    mov bl,buff2+1
    mov buff2[bx+2],'$'
    mov word ptr buff2,' !'
    mes1 db 'Введите Вашу фамилию',0Dh,0Ah,'$'
buff db 255,?,255 dup(?)
mes2 db 0Dh,0Ah,'Введите Ваше имя',0Dh,0Ah,'$'
buff2 db 255,?,255 dup(?)
ret
end start

ФедосеевПавел · 12.04.2020, 13:42

Описание функций прерываний BIOS и DOS
http://www.codenet.ru/progr/dos/
Вам понадобятся сервисы DOS - int 21h

1. Откройте файл на запись ah=3Ch, сохраните описатель файла в переменной
2. У вас есть буфер ввода клавиатуры с текстом и длиной этого текста - вот их и укажите функции записи ah=40h.
3. Закройте файл функцией ah=3Eh

Всё.

@Belena123321 · 12.04.2020, 15:17 **[ТС]**

Что-то я всерано делаю не то((( В файл то что я ввожу с клавиатуры не записыватся, он остаётся пустым... Можете, пожалуйста, подсказать, что не так

Assembler
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
#make_COM#
 
ORG 100h
 
start:  mov ax,3
    int 10h
    mov ah,9
    mov dx,offset mes1
    int 21h
    mov ah,0Ah
    mov dx,offset buff
    int 21h
    mov bh,0
    mov bl,buff+1
    mov buff[bx+2],'$'
    mov word ptr buff,' !'
    mov ax,3
    int 10h
    mov ah,9
    mov dx,offset mes2
    int 21h
    mov ah,0Ah
    mov dx,offset buff2
    int 21h
    mov bh,0
    mov bl,buff2+1
    mov buff2[bx+2],'$'
    mov word ptr buff2,' !'
    mes1 db 'Введите Вашу Фамилию',0Dh,0Ah,'$'
buff db 255,?,255 dup(?)
mes2 db 0Dh,0Ah,'
buff2 db 255,?,255 dup(?)
 
    MOV   AH,  3Ch      
    MOV   CX,  0        
    MOV   DX,  offset path  
    INT   21h            
    PUSH  AX        
    MOV   AX,  3D02h    
    MOV   DX,  offset path  
    INT   21h       
    MOV   AH,  40h      
    POP   BX    
    MOV   DX,  offset path  
    MOV   CX,  29       
    INT   21h       
    MOV   AH,  3Eh      
    INT   21h
 
    RET
 
path    DB    'Y1.txt$', 0
buf DB    ?         
    
        END   start

ФедосеевПавел · 12.04.2020, 15:46

У вас смешался код и данные. Т.к. данные это такие же байты, как и инструкции, то вместо осмысленного кода процессор выполняет какие-то инструкции, которые соответствуют байтам строк (данных).

Имя файла в формате 8.3, т.е. не может быть расширения txt$ - в схематичном коде я поправил.

У вас должно быть (схематично):

Assembler
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
#make_COM#
 
ORG 100h
 
;ввод строки при помощи int 21h ah=0Ah
............
;открытие файла при помощи int 21h ah=3Ch
............
;запись буфера ввода клавиатуры в файл int 21h ah=40h
............
;закрытие файла int 21h ah=3Eh
............
;завершение программы
int 20h ;или, как у вас в коде - RET
 
;данные
    mes1 db 'Введите Вашу фамилию',0Dh,0Ah,'$'
buff db 255,?,255 dup(?)
mes2 db 0Dh,0Ah,'Введите Ваше имя',0Dh,0Ah,'$'
buff2 db 255,?,255 dup(?)
path    DB    'Y1.txt', 0
        END   start

Попробуйте записать только один буфер - только фамилию - для отладки.

Добавлено через 1 минуту

Не по теме:

Попробуйте не пропадать и сделать прямо сейчас - я пока побуду на форуме.

Добавлено через 12 минут
Ещё. После успешного открытия файла в регистре ax операционная система вернёт описатель (хэндл) файла - его нужно сохранить в переменной

Assembler
1
hFile dw ?

и позже использовать для записи и закрытия файла - его требуется загружать в регистр bx.

@Belena123321 · 12.04.2020, 15:53 **[ТС]**

Вы уже всё расписала, но у меня всё равно не работает ((( Я ни чего уже не понимаю

Assembler
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
#make_COM#
ORG 100h
start:  mov ax,3
    int 10h
    mov ah,9
    mov dx,offset mes1
    int 21h
    mov ah,0Ah
    mov dx,offset buff
    int 21h
    mov bh,0
    mov bl,buff+1
    mov buff[bx+2],'$'
    mov word ptr buff,' !'
    MOV   AH,  3Ch      
    MOV   CX,  0        
    MOV   DX,  offset path  
    INT   21h                
    PUSH  AX        
    MOV   AX,  3D02h    
    MOV   DX,  offset path  
    INT   21h       
    MOV   AH,  40h      
    POP   BX    
    MOV   DX,  offset path  
    MOV   CX,  29       
    INT   21h       
    
    MOV   AH,  3Eh      
    INT   21h
 
    RET
mes1 db 'Введите фамилию',0Dh,0Ah,'$'
buff db 255,?,255 dup(?)
 
path    DB    'Y1.txt', 0
        END   start

ФедосеевПавел · 12.04.2020, 16:28

Belena123321, используйте кнопки с названием языка программирования для обрамления текста исходника тегами - это добавляет подсветку синтаксиса и нумерацию строк, отступы.
Для ассемблера:
- выделяете текст исходника
- нажимаете кнопку ASM на панели инструментов редактора сообщений и видите примерно такую картину

[ASM]#make_COM#
ORG 100h
start: mov ax,3
int 10h
mov ah,9[/ASM]

После отправки сообщения этот текст будет выглядеть

Assembler
1
2
3
4
5
#make_COM#
ORG 100h
start:  mov ax,3
    int 10h
    mov ah,9

Добавлено через 23 минуты
Вот пример ввода строки и записи её в файл.
Строки с диагностическими сообщениями скопировал из какого-то примера - лишние уберите самостоятельно.
У меня нет emu8086, но есть FASM - поправьте если что-то в синтаксисе будет неправильно

Assembler
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
use16
org 100h
        ;приглашение к вводу строки
        mov     ah,     09h
        lea     dx,     [asGetString]
        int     21h
        ;ввод строки
        mov     ah,     0Ah
        lea     dx,     [kbdBuf]
        int     21h
        ;открытие файла
        mov     ah,     3Ch             ;создать файл
        mov     cx,     0               ;атрибут
        lea     dx,     [aszFileName]   ;имя
        int     21h
        jnc     @@FileCreateOk
                mov     ah,     09h
                lea     dx,     [errFileOpenWr]
                int     21h
                jmp     @@Exit
        @@FileCreateOk:
        mov     [hFile],        ax
        ;запись в файл
        mov     ah,     40h
        mov     bx,     [hFile]
        mov     cl,     [kbdBuf+1]
        mov     ch,     0
        lea     dx,     [kbdBuf+2]
        int     21h
        jnc     @@FileWriteOk
                mov     ah,     09h
                lea     dx,     [errFileWrite]
                int     21h
                jmp     @@FileClose
        @@FileWriteOk:
 
@@FileClose:
        mov     ah,     3Eh
        mov     bx,     [hFile]
        int     21h
        jnc     @@FileCloseOk
                mov     ah,     09h
                lea     dx,     [errFileClose]
                int     21h
                jmp     @@Exit
        @@FileCloseOk:
 
@@Exit:
        ;ожидание нажатия любой клавиши
        mov     ah,     09h
        lea     dx,     [msgPressAnyKey]
        int     21h
        mov     ah,     0
        int     16h
        ;завершение программы
        int     20h
;-------------------------------------------------------
errFileOpenRd   db      0Dh, 0Ah, 'File open (for read) error', '$'
errFileOpenWr   db      0Dh, 0Ah, 'File open (for write) error', '$'
errFileRead     db      0Dh, 0Ah, 'File read error', '$'
errFileWrite    db      0Dh, 0Ah, 'File write error', '$'
errFileClose    db      0Dh, 0Ah, 'File close error', '$'
CrLf            db      0Dh, 0Ah, '$'
asGetString     db      'Enter a string:', 0Dh, 0Ah, '$'
msgPressAnyKey  db      0Dh, 0Ah, 'Press any key to exit...', '$'
 
aszFileName     db      'data.txt', 0
hFile           dw      ?
 
BufSize         equ     80
kbdBuf          db      BufSize, ?, (BufSize+1) dup(?)

Проверил пример - работает. Думаю, должно быть понятно.
По возможности сохраняйте отступы - это помогает читать, хотя многие привыкли видеть ассемблерные листинги сплошной неформатированной массой.

Добавлено через 5 минут
Перечитал ваш пример - ошибка в том, что вы открываете на запись 3Ch, о потом зачем-то ещё раз открываете 3D02h. Второй раз не нужно. К тому же, разница между этими открытиями на запись в том, что для 3D02h файл должен существовать, иначе будет ошибка открытия - но т.к. вы не обрабатываете ошибки, то ничего о них и не знаете.

@Belena123321 · 12.04.2020, 16:35 **[ТС]**

Спасибо Вам большое!!!

ФедосеевПавел · 12.04.2020, 16:37

Разобрались?

@Belena123321 · 12.04.2020, 16:46 **[ТС]**

Ну в тексте программы я кажется разабролась, но у меня всеравно почему-то файл остаётся пустым, но у Вас же работает, значит и у меня дожно. Программа и файл data находятся в одной папке, ошибки не выходит ни какой, однако файл пустой(((

ФедосеевПавел · 12.04.2020, 17:04

Моя программа оставляет пустой файл?

Добавлено через 14 минут
Обычно, файл создаётся, но остаётся пустым после записи - в случае, когда записывается меньше сектора (512 байт) и файл не закрывается программой (не сбрасываются буферы внутри операционки или внутри винчестера).

@Belena123321 · 13.04.2020, 10:05 **[ТС]**

Файл пустой.
Тогда как выполнить это задание: написать простейшею форму регистрации:программа должна спросить имя пол возрасти записать полученные результаты в файл, если должно быть не менее 512 байт?

ФедосеевПавел · 13.04.2020, 10:13

Саму программу тоже приводите в виде текста.

@Belena123321 · 13.04.2020, 10:23 **[ТС]**

Вот текст программы

Assembler
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
#make_COM#
org 100h
     
        mov     ah,     09h
        lea     dx,     Name 
        int     21h
   
        mov     ah,     0Ah
        lea     dx,     Buff
        int     21h
        mov     ah,     09h
        lea     dx,     Gender
        int     21h
 
        mov     ah,     0Ah
        lea     dx,     Buff2
        int     21h
         mov     ah,     09h
        lea     dx,     Age
        int     21h
 
        mov     ah,     0Ah
        lea     dx,     Buff3
        int     21h
 
        mov     ah,     3Ch            
        mov     cx,     0               
        lea     dx,     FileName  ;
        int     21h
        jnc     @@FileCreateOk
                mov     ah,     09h
                lea     dx,     errFileOpenWr
                int     21h
                jmp     @@Exit
        @@FileCreateOk:
        mov     [hFile],        ax
 
        mov     ah,     40h
        mov     bx,     hFile
        mov     cl,     Buff+1
        mov     ch,     0
        lea     dx,     Buff+2
        mov     cl,     Buff2+1
        mov     ch,     0
        mov     cl,     Buff2+2
        mov     cl,     Buff3+1
        mov     ch,     0
        lea     dx,     Buff3+2
        int     21h
        jnc     @@FileWriteOk
                mov     ah,     09h
                lea     dx,     [errFileWrite]
                int     21h
                jmp     @@FileClose
        @@FileWriteOk:
 
@@FileClose:
        mov     ah,     3Eh
        mov     bx,     [hFile]
        int     21h
        jnc     @@FileCloseOk
                mov     ah,     09h
                lea     dx,     [errFileClose]
                int     21h
                jmp     @@Exit
        @@FileCloseOk:
 
@@Exit:
      
        mov     ah,     09h
        lea     dx,     [msgPressAnyKey]
        int     21h
        mov     ah,     0
        int     16h
 
       ; int     20h
       ret
;-------------------------------------------------------
errFileOpenRd   db      0Dh, 0Ah, 'File open (for read) error', '$'
errFileOpenWr   db      0Dh, 0Ah, 'File open (for write) error', '$'
errFileRead     db      0Dh, 0Ah, 'File read error', '$'
errFileWrite    db      0Dh, 0Ah, 'File write error', '$'
errFileClose    db      0Dh, 0Ah, 'File close error', '$'
CrLf            db      0Dh, 0Ah, '$'
Name    db       0Dh, 0Ah,'Enter your name:', 0Dh, 0Ah, '$'
Gender db       0Dh, 0Ah,'Enter your gender (w/m):', 0Dh, 0Ah, '$'
Age db       0Dh, 0Ah,'Enter your age:', 0Dh, 0Ah, '$'
msgPressAnyKey  db      0Dh, 0Ah, 'Press any key to exit...', '$'
 
FileName     db      'data.txt', 0
 
hFile           dw      ?
 
BufSize         equ     80
BufSize2         equ     2
Buff          db      BufSize, ?, (BufSize+1) dup(?)
Buff2          db      BufSize2, ?, (BufSize2+1) dup(?)
Buff3          db      BufSize, ?, (BufSize+1) dup(?)

ФедосеевПавел · 13.04.2020, 10:37

У меня нет emu8086, поэтому никак не могу прокомментировать его работу.
Если программа правильная, то она отработает в другом эмуляторе DOS, например в msdosplayer, только нужно получить исполнимый файл при помощи компилятора из пакета fasm - его синтаксис в данном случае очень похож.

1. скачал msdosplayer
2. распаковал и скопировал один из msdos.exe (второй почему-то не работает - выяснял экспериментом)
3. установил fasm
4. скомпилировал свою программу (в которой первая строка use16 - это важная строка), получил main.com
5. из командной строки запустил

Windows Batch file
1
msdos.exe main.com

Протокол работы эмулятора (выделил содержимое консоли через меню, вызываемое правой кнопкой мыши и скопировал Ctrl-C)

Code
1
2
3
Enter a string:
code by Assemler
Press any key to exit...

В результате появился файл data.txt идентичным содержимым "code by Assemler".

http://takeda-toshiya.my.cooca... index.html - msdosplayer
https://flatassembler.net/ fasm

Добавлено через 4 минуты
При попытке записи - вы заполняете регистры, но не вызываете сам обработчик через int 21h. Поэтому записи и нет - вы просто что-то записываете в регистры и тут же заменяете на новые значения.
Кроме того - при копировании - идёт постоянная путаница буферов Buf2 чередуется с Buf3.

Добавлено через 3 минуты
Кроме того, после вызова int 21h ah=40h, содержимое ax равно числу записанных байт или код ошибки записи. Т.е. не экономьте и полностью заполняйте все регистры.
И для удобства - если обращаетесь к ячейке памяти с адресом hFile (условно), берите адрес в квадратные скобки

Assembler
1
mov bx, [hFile]

для некоторых ассемблеров это обязательно, да и читать проще.

Добавлено через 1 минуту
Т.е. это ошибки в коде, а не эмулятора.

@Belena123321 · 13.04.2020, 10:37 **[ТС]**

Спасибо

ФедосеевПавел · 14.04.2020, 19:27

Пример ввода трёх строк в цикле и запись их в файл

Кликните здесь для просмотра всего текста

Assembler
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
use16
org 100h
 
        ;открытие файла
        mov     ah,     3Ch             ;создать файл
        mov     cx,     0               ;атрибут
        lea     dx,     [aszFileName]   ;имя
        int     21h
        jnc     @@FileCreateOk
                mov     ah,     09h
                lea     dx,     [errFileOpenWr]
                int     21h
                jmp     @@Exit
        @@FileCreateOk:
        mov     [hFile],        ax
 
        ;цикл по числу вводимых строк
        mov     cx,     3
        lea     si,     [ptrStrings]
@@for:
        push    cx
        push    si
 
 
        ;приглашение к вводу строки
        mov     ah,     09h
        ;lea     dx,     [asGetString]
        mov     dx,     [si]
        int     21h
        ;ввод строки
        mov     ah,     0Ah
        lea     dx,     [kbdBuf]
        int     21h
        ;добавим в конец строки символы перевода строки:
        lea     bx,     [kbdBuf+2]
        add     bl,     [kbdBuf+1]
        adc     bh,     0
        mov     word[bx],       0A0Dh
        add     byte[kbdBuf+1], 2
        ;запись в файл
        mov     ah,     40h
        mov     bx,     [hFile]
        mov     cl,     [kbdBuf+1]
        mov     ch,     0
        lea     dx,     [kbdBuf+2]
        int     21h
        jnc     @@FileWriteOk
                mov     ah,     09h
                lea     dx,     [errFileWrite]
                int     21h
                jmp     @@FileClose
        @@FileWriteOk:
 
        pop     si
        pop     cx
        add     si,     2
loop    @@for
 
 
@@FileClose:
        mov     ah,     3Eh
        mov     bx,     [hFile]
        int     21h
        jnc     @@FileCloseOk
                mov     ah,     09h
                lea     dx,     [errFileClose]
                int     21h
                jmp     @@Exit
        @@FileCloseOk:
 
@@Exit:
        ;ожидание нажатия любой клавиши
        mov     ah,     09h
        lea     dx,     [msgPressAnyKey]
        int     21h
        mov     ah,     0
        int     16h
        ;завершение программы
        int     20h
;-------------------------------------------------------
errFileOpenRd   db      0Dh, 0Ah, 'File open (for read) error', '$'
errFileOpenWr   db      0Dh, 0Ah, 'File open (for write) error', '$'
errFileRead     db      0Dh, 0Ah, 'File read error', '$'
errFileWrite    db      0Dh, 0Ah, 'File write error', '$'
errFileClose    db      0Dh, 0Ah, 'File close error', '$'
CrLf            db      0Dh, 0Ah, '$'
asGetString1    db      0Dh, 0Ah, 'Enter a 1st string:', 0Dh, 0Ah, '$'
asGetString2    db      0Dh, 0Ah, 'Enter a 2nd string:', 0Dh, 0Ah, '$'
asGetString3    db      0Dh, 0Ah, 'Enter a 3rd string:', 0Dh, 0Ah, '$'
msgPressAnyKey  db      0Dh, 0Ah, 'Press any key to exit...', '$'
 
ptrStrings      dw      asGetString1, asGetString2, asGetString3
 
aszFileName     db      'data.txt', 0
hFile           dw      ?
 
BufSize         equ     80
kbdBuf          db      BufSize, ?, (BufSize+1) dup(?)

Новые блоги и статьи Все статьи Все блоги /
Реалии Hrethgir 01.03.2026 Нет, я не закончил до сих пор симулятор. Эта задача сложнее. Не получилось уйти в плавсостав, но оно и к лучшему, возможно. Точнее получалось - но сварщиком в палубную команду, а это значит, в моём. . .	Ритм жизни kumehtar 27.02.2026 Иногда приходится жить в ритме, где дел становится всё больше, а вовлечения в происходящее — всё меньше. Плотный график не даёт вниманию закрепиться ни на одном событии. Утро начинается с быстрых,. . .	SDL3 для Web (WebAssembly): Сборка библиотек: SDL3, Box2D, FreeType, SDL3_ttf, SDL3_mixer и SDL3_image из исходников с помощью CMake и Emscripten 8Observer8 27.02.2026 Недавно вышла версия 3. 4. 2 библиотеки SDL3. На странице официальной релиза доступны исходники, готовые DLL (для x86, x64, arm64), а также библиотеки для разработки под Android, MinGW и Visual Studio. . . .	SDL3 для Web (WebAssembly): Реализация движения на Box2D v3 - трение и коллизии с повёрнутыми стенами 8Observer8 20.02.2026 Содержание блога Box2D позволяет легко создать главного героя, который не проходит сквозь стены и перемещается с заданным трением о препятствия, которые можно располагать под углом, как верхнее. . .
Конвертировать закладки radiotray-ng в m3u-плейлист damix 19.02.2026 Это можно сделать скриптом для PowerShell. Использование . \СonvertRadiotrayToM3U. ps1 <path_to_bookmarks. json> Рядом с файлом bookmarks. json появится файл bookmarks. m3u с результатом. # Check if. . .	Семь CDC на одном интерфейсе: 5 U[S]ARTов, 1 CAN и 1 SSI Eddy_Em 18.02.2026 Постепенно допиливаю свою "многоинтерфейсную плату". Выглядит вот так: https:/ / www. cyberforum. ru/ blog_attachment. php?attachmentid=11617&stc=1&d=1771445347 Основана на STM32F303RBT6. На борту пять. . .	Камера Toupcam IUA500KMA Eddy_Em 12.02.2026 Т. к. у всяких "хикроботов" слишком уж мелкий пиксель, для подсмотра в ESPriF они вообще плохо годятся: уже 14 величину можно рассмотреть еле-еле лишь на экспозициях под 3 секунды (а то и больше),. . .	И ясному Солнцу zbw 12.02.2026 И ясному Солнцу, и светлой Луне. В мире покоя нет и люди не могут жить в тишине. А жить им немного лет.

ФедосеевПавел Модератор 8659 / 4494 / 1669 Регистрация: 01.02.2015 Сообщений: 13,907 Записей в блоге: 12
	12.04.2020, 13:42
	Описание функций прерываний BIOS и DOS http://www.codenet.ru/progr/dos/ Вам понадобятся сервисы DOS - int 21h 1. Откройте файл на запись ah=3Ch, сохраните описатель файла в переменной 2. У вас есть буфер ввода клавиатуры с текстом и длиной этого текста - вот их и укажите функции записи ah=40h. 3. Закройте файл функцией ah=3Eh Всё. 1

@Belena123321 17 / 1 / 0 Регистрация: 10.12.2018 Сообщений: 85
	12.04.2020, 16:35 [ТС]
	Спасибо Вам большое!!! 0

ФедосеевПавел Модератор 8659 / 4494 / 1669 Регистрация: 01.02.2015 Сообщений: 13,907 Записей в блоге: 12
	12.04.2020, 16:37
	Разобрались? 0

@Belena123321 17 / 1 / 0 Регистрация: 10.12.2018 Сообщений: 85
	12.04.2020, 16:46 [ТС]
	Ну в тексте программы я кажется разабролась, но у меня всеравно почему-то файл остаётся пустым, но у Вас же работает, значит и у меня дожно. Программа и файл data находятся в одной папке, ошибки не выходит ни какой, однако файл пустой((( 0

ФедосеевПавел Модератор 8659 / 4494 / 1669 Регистрация: 01.02.2015 Сообщений: 13,907 Записей в блоге: 12
	12.04.2020, 17:04
	Моя программа оставляет пустой файл? Добавлено через 14 минут Обычно, файл создаётся, но остаётся пустым после записи - в случае, когда записывается меньше сектора (512 байт) и файл не закрывается программой (не сбрасываются буферы внутри операционки или внутри винчестера). 0

@Belena123321 17 / 1 / 0 Регистрация: 10.12.2018 Сообщений: 85
	13.04.2020, 10:05 [ТС]
	Файл пустой. Тогда как выполнить это задание: написать простейшею форму регистрации:программа должна спросить имя пол возрасти записать полученные результаты в файл, если должно быть не менее 512 байт? Миниатюры 0

ФедосеевПавел Модератор 8659 / 4494 / 1669 Регистрация: 01.02.2015 Сообщений: 13,907 Записей в блоге: 12
	13.04.2020, 10:13
	Саму программу тоже приводите в виде текста. 0

@Belena123321 17 / 1 / 0 Регистрация: 10.12.2018 Сообщений: 85
	13.04.2020, 10:37 [ТС]
	Спасибо 0