Резидент обработки прерывания int 31h - формирование звукового сигнала заданной длительности и частоты

prog    segment
    assume cs:prog,ds:prog
 
    org 100h
start:  jmp init
 
;*************************
 
port_b  equ 61h             ;адрес порта b
cmd_reg equ 43h             ;адрес командного регистра
chnl_2  equ 42h             ;адрес канала 2
 
old31h  dd ?                ;адрес предыдущего обработчика прерывания 31h
old09h  dd ?                ;адрес предыдущего обработчика прерывания 09h
 
txtpos  equ 0c1eh           ;координаты для вывода сообщения txt
txt db 'Programma vigrujena!'   ;'Программа выгружена!'
txtl    equ $-txt           ;длина сообщения txt1  
 
loaded  dw 12345            ;признак загрузки программы в память
;--------------------------------------------------------
 
NEW_INT proc far            ;обработчик прерывания INT31h
 
    push bx             ;сохраняем регистры в стеке
    push cx
    push dx
    push si
    push di
    push bp
    push ds
    push es
 
    push cs             ;загружаем регистр DS значением CS через стек
    pop ds
 
 
    mov dx,high(1190000)        ;вычисляем параметр задания частоты звука
    mov ax,low(1190000)
    div bx
    mov bx,ax
 
    mov ax,18           ;вычисляем параметр задания длительности звука
    mul bp
    mov bp,ax
 
    in al,port_b            ;разрешение канала 2 порта b микросхемы 8255
    or al,3
    out port_b,al
 
    mov al,10110110b        ;установка регистров ввода/вывода
    out cmd_reg,al
 
    mov ax,bx           ;засылка счетчика в задвижку
    out chnl_2,al
    mov al,ah
    out chnl_2,al
 
    mov ah,0            ;формируем длительность звука (задержкой)
    int 1ah
    add dx,bp
    mov bx,dx
delay:  int 1ah
    cmp dx,bx
    jne delay
 
    in al,port_b            ;выключаем звук
    and al,11111100b
    out port_b,al
 
exit:   pop es              ;восстанавливаем значения регистров из стека
    pop ds
    pop bp
    pop di
    pop si
    pop dx
    pop cx
    pop bx
 
    iret                ;выходим из обработчика прерывания INT 31h
NEW_INT endp
;--------------------------------------------------------
 
 
;********************************************************
new09h  proc far            ;обработчик прерывания INT09h
 
    pushf               ;сохраняем регистры в стеке
    push ax
    push bx
    push cx
    push dx
    push si
    push di
    push bp
    push ds
    push es
 
    push cs             ;загружаем регистры DS и ES значением CS через стек
    push cs
    pop ds
    pop es
 
    mov ah,2            ;если не нажат <Left Shift>, то переходим к выходу из обработчика
    int 16h
    and al,00000010b
    jz exit09
 
    mov bl,20h          ;выводим сообщение о выгрузке программы из памяти
    mov cx,txtl
    mov dx,txtpos
    mov bp,offset txt
    mov ah,0fh
    int 10h
    mov ah,13h
    mov al,0
    int 10h
 
    call unload         ;вызываем подпрограмму выгрузки программы из памяти
 
exit09: pop es              ;восстанавливаем значения регистров из стека
    pop ds
 
    pop bp
    pop di
    pop si
    pop dx
    pop cx
    pop bx
    pop ax
    popf
 
    jmp cs:old09h           ;переходим к предыдущему обработчику прерывания INT 09h
 
new09h  endp
;********************************************************
 
 
;=======ПОДПРОГАММЫ============      ;РАЗДЕЛ ПОДПРОГРАММ
 
;-------UNLOAD-----------------     ;ПОДПРОГРАММА ВЫГРУЗКИ ПРОГРАММЫ ИЗ ПАМЯТИ
unload  proc near
    mov ax,3531h            ;получаем вектор прерывания 31h
    int 21h
 
    push ds             ;устанавливаем вектор прерывания 31h
    mov ax,2531h
    mov dx,word ptr es:[offset old31h]
    mov ds,word ptr es:[offset old31h+2]
    int 21h
    pop ds
 
    push ds             ;устанавливаем вектор прерывания 09h
    mov ax,2509h
    mov dx,word ptr es:[offset old09h]
    mov ds,word ptr es:[offset old09h+2]
    int 21h
    pop ds
 
    mov ah,49h          ;освобождаем блок памяти
    int 21h
 
    ret
unload  endp
;------------------------------
 
psize   equ ($-prog)/16+1       ;длина резидентной части программы
 
;-------INIT-------------------     ;ПОДПРОГРАММА ИНИЦИАЛИЗАЦИИ
init    proc near
    mov ah,9            ;выводим заголовок программы
    mov dx,offset msg1
    int 21h
 
    mov ax,3531h            ;получаем вектор прерывания 31h
    int 21h
    mov word ptr old31h,bx
    mov word ptr old31h+2,es
 
    mov ax,2531h            ;устанавливаем вектор прерывания 31h
    mov dx,offset NEW_INT
    int 21h
    ;--------------
 
    mov ax,3509h            ;получаем вектор прерывания 09h
    int 21h
    mov word ptr old09h,bx
    mov word ptr old09h+2,es
 
    mov ax,2509h            ;устанавливаем вектор прерывания 09h
    mov dx,offset new09h
    int 21h
    ;--------------
 
    mov ax,3100h            ;вызываем функцию DOS: завершить и оставить резидентной
    mov dx,psize
    int 21h
 
init    endp
;------------------------------
 
                    ;'ЗВУК INT 31h.'
                    ;'Резидентная программа загружена в память!'
msg1    db 13,10,13,10,'ZVUK - INT 31h.'
    db 13,10,'TSR programma zagrujena v pamyat!',13,10,'$'
 
prog    ends
    end start

dosseg
.model small
.stack 1000h
.data
;*************************      ;РАЗДЕЛ КОНСТАНТ И ПЕРЕМЕННЫХ
 
                    ;'Программа INT 31h не загружена!'
txt1    db 13,10,10,'Programma INT 31h ne zagrujena!$'
 
                    ;'Введите частоту звука (100..30000Гц)'
txt2    db 13,10,10,'Vvedite chastotu zvuka (100..30000Hz): $'
 
                    ;'Введите длительность звука (1..99сек)'
txt3    db 13,10,10,'Vvedite dlitelnost zvuka (1..99sec): $'
 
                    ;'Неверное число!'
err1    db 13,10,10,'Nevernoe chislo!$'  
 
inpbuf  db 5+1              ;буфер для ввода числа
inpbuf2 db ?
inpbuf3 db 5+1 dup (?)
 
freq    dw ?                ;частота звука
durat   dw ?                ;длительность звука
;--------------------------------------------------------
 
.code
    mov ax,@data            ;загружаем адрес сегмента данных
    mov ds,ax
 
    mov ax,3531h            ;получаем вектор прерывания 31h
    int 21h
 
    mov ax,es:[bx-2]        ;проверяем наличие программы в памяти по признаку
    cmp ax,12345
    je m1               ;если программа загружена, то переходим далее
 
    mov dx,offset txt1      ;иначе - выходим из программы
    call tprint
    jmp exit
    ;-------------
 
m1: mov di,offset txt2      ;выдаем запрос на ввод частоты звука
    call input
    cmp bx,100          ;если введено недопустимое значение, то
    jb m2               ;переходим к повтору ввода
    cmp bx,30000            ;иначе - переходим далее
    jbe m3
 
m2: mov dx,offset err1
    call tprint
    jmp m1
 
m3: mov freq,bx         ;сохраняем частоту звука
 
    mov inpbuf,2+1          ;корректируем количество символов для ввода длительности звука
m4: mov di,offset txt3      ;выдаем запрос на ввод длительности звука
    call input          ;если введено недопустимое значение, то
    cmp bx,1            ;переходим к повтору ввода
    jae m5              ;иначе - переходим далее
 
    mov dx,offset err1
    call tprint
    jmp m4
 
m5: mov durat,bx            ;сохраняем длительность звука
 
    mov bx,freq         ;загружаем частоту звука
    mov bp,durat            ;загружаем длительность звука
    int 31h             ;вызов функции через INT 31h
 
exit:   mov ah,4ch          ;завершаем программу
    int 21h
;--------------------------------------------------------
 
;=======ПОДПРОГАММЫ===========
 
;-------INPUT-----------------      ;ПОДПРОГРАММА ВВОДА ЧИСЛА
                    ;при выходе:
                    ;BX - введенное число
 
input   proc near
inp4:   mov dx,di           ;выводим приглашение
    call tprint
 
    mov ah,0ah          ;ожидаем ввод строки в буфер
    mov dx,offset inpbuf
    int 21h
    cmp byte ptr inpbuf2,0      ;если ввели не пустую строку, то переходим далее
    jne inp1
 
inp2:   mov dx,offset err1      ;иначе, выводим сообщение об ошибке
    call tprint         ;и переходим к повтору ввода числа
    jmp inp4
 
inp1:   mov bx,0            ;обнуляем результат перевода строки символов в число
    mov ch,0            ;загружаем длину введенной строки
    mov cl,inpbuf2
 
    mov si,offset inpbuf3       ;загружаем адрес буфера введенных символов
 
inp3:   mov ax,10           ;умножаем текущее значение результата на 10
    mul bx
    mov bx,ax
 
    mov al,[si]         ;загружаем очередной символ из буфера
    sub al,'0'          ;если введен некорректный символ, то переходим к выводу сообщения об ошибке
    cmp al,9
    ja inp2
 
    mov ah,0            ;прибавляем полученное число к содержимому результата
    add bx,ax
 
    inc si              ;переходим к следующему символу в буфере
    loop inp3           ;повторяем цикл для всех введенных символов
 
    ret
input   endp
;-----------------------------  
 
 
;-------TPRINT----------------      ;ПОДПРОГРАММА ПЕЧАТИ ТЕКСТОВОЙ СТРОКИ
                    ;при входе:
                    ;DX - начальный адрес текста
tprint  proc near
    mov ah,9h           ;выводим строку
    int 21h
 
    ret
tprint  endp
;-----------------------------
 
end