Перемещение простых геометрических объектов по экрану мышкой

    call cls    ; стереть невидимую память
    call drawtest   ; нарисовать изображение в невидимой памяти
    call sync   ; копировать изображение на экран

shape4  label word ; квадрат
    dw 4
    dw -40,-32
    dw 40,-32
    dw 40,32
    dw -40,32
    dw -40,-32

; Программа отрисовки объектов и их перемещения мышкой
; Использовался Turbo Assembler 4.0
; Компилируется в COM файл
 
    .286
    .model small
    .code
    assume ds:_text
 
; вызов функций мыши
mouse   macro val
    mov ax,val
    int 33h
    endm
 
mouseShow macro
    mouse 1
    endm
 
mouseHide macro
    mouse 2
    endm
 
mousePoll macro
    mouse 3
    endm
 
codesize = 2000h
; начало программы
    org 100h
start:  mov sp,codesize-2
    jmp beg
 
; включается файл проведения линии по алгоритму Брезенхема
; (подпрограммы plot - вывод точки, drawline - вывод линии, invoke - макро вывода линии)
;   include linebrez.inc
 
; linebrez.inc начало **********
 
; аргументы вызова - координаты линии и цвет
; эти переменные заносятся в стек перед вызовом drawline
; см invoke
x1  equ word ptr [bp+12]
y1  equ word ptr [bp+10]
x2  equ word ptr [bp+8]
y2  equ word ptr [bp+6]
col equ byte ptr [bp+4]
 
; внутренние переменные drawline
; эти переменные существуют только в процессе работы drawline
deltaX  equ word ptr [bp-2]
deltaY  equ word ptr [bp-4]
signX   equ word ptr [bp-6]
signY   equ word ptr [bp-8]
er  equ word ptr [bp-10]
er2 equ word ptr [bp-12]
 
; вывод точки
; x=cx, y=dx, color=al
plot:   push di
    push es
    cmp cx,320 ; координаты выходят за границы экрана ?
    jnc pl1
    cmp dx,200
    jnc pl1
    push ax
    mov ax,320 ; di=320*y+x
    mul dx
    add ax,cx
    mov di,ax
; отрисовка в обычной памяти, а не в видео
    mov ax,cs ; 0A000h
    add ax,codesize/16
    mov es,ax
    pop ax
    mov es:[di],al ; выводим точку
pl1:    pop es
    pop di
    ret
 
; вывод линии
; SUB drawLine (x1, y1, x2, y2, col)
; Пример вызова:
; invoke drawline, <10,10,310,10,15>
 
drawline proc
    push bp   ; пролог Сохраняем bp в стеке
    mov bp,sp ; далее мы адресуем переменные с помощью bp
    sub sp,16 ; выделяем место под локальные переменные
    push ax
    push bx
    push cx
    push dx
;deltaX = ABS(x2 - x1)
    mov ax,x2
    sub ax,x1
    jge lin1
    neg ax
lin1:   mov deltaX,ax
;deltaY = ABS(y2 - y1)
    mov ax,y2
    sub ax,y1
    jge lin2
    neg ax
lin2:   mov deltaY,ax
;IF x1 < x2 THEN signX = 1 ELSE signX = -1
    mov bx,1
    mov ax,x1
    cmp ax,x2
    JL  lin3
    neg bx
lin3:   mov signX,bx
;iF y1 < y2 THEN signY = 1 ELSE signY = -1
    mov bx,1
    mov ax,y1
    cmp ax,y2
    JL  lin4
    neg bx
lin4:   mov signY,bx
;er = deltaX - deltaY
    mov ax,deltaX
    sub ax,deltaY
    mov er,ax
;PSET (x2, y2), col
    mov cx,x2
    mov dx,y2
    mov al,col
    call plot
; основной цикл построения линии
;WHILE (x1 <> x2) OR (y1 <> y2)
wil1:   mov ax,x1
    cmp ax,x2
    jnz wil2
    mov ax,y1
    cmp ax,y2
    jnz wil2
    jmp wend
wil2:   
;PSET (x1, y1), col
    mov cx,x1
    mov dx,y1
    mov al,col
    call plot
;er2 = er * 2
    mov ax,er
    add ax,ax
    mov er2,ax
;IF (er2 > -deltaY) THEN er = er - deltaY: x1 = x1 + signX
    mov ax,er2
    add ax,deltaY
    JLE lin5
    mov ax,er
    sub ax,deltaY
    mov er,ax
    mov ax,x1
    add ax,signX
    mov x1,ax
lin5:
;IF (er2 < deltaX) THEN er = er + deltaX: y1 = y1 + signY
    mov ax,er2
    cmp ax,deltaX
    jge lin6
    mov ax,er
    add ax,deltaX
    mov er,ax
    mov ax,y1
    add ax,signY
    mov y1,ax
;WEND
lin6:   jmp wil1
wend:   pop dx
    pop cx
    pop bx
    pop ax
    mov sp,bp ; эпилог, восстанавливаем sp
    pop bp    ; восстанавливаем bp
    ret 10    ; делаем возврат и продвигаем стек на 5*2=10 байт (т к 5 аргументов хранилось в стеке)
drawline endp
 
; макро вызова drawline См lst.lst, какой код генерит это макро
 
invoke macro CallProc,Params
    IRP P,<Params>
        mov ax, P
        push ax
        
    endm
    call CallProc
endm
 
; linebrez.inc конец  **********
 
prnbuf  db "000",0 ; буфер вывода числа
 
; установить позицию курсора
setcur  macro yy
    mov al,yy
    call setcursub
    endm
 
setcursub:pusha
    mov dl,0  ; cursorx=0
    mov dh,al ; cursory=al
    mov bh,0
    mov ah,2
    int 10h
    popa
    ret
 
; очистить видео буфер
cls:    push es
    pusha
    mov ax,cs     ; буфер находится по сегменту cs+codesize/16:0 ...
    add ax,codesize/16
    mov es,ax
    mov di,0
    mov cx,320*200/4 ; ... длина буфера 64000 байт
    db  66h   ; префикс 32разрядного режима
    xor ax,ax ; xor eax,eax т е eax=0
    db  66h   ; префикс 32разрядного режима
    rep stosw ; rep stosd
    popa
    pop es
    ret
 
; переписать буфер в видео память VGA 
sync:   push ds
    push es
    pusha
; этот фрагмент устраняет мерцание курсора мыши
    mov dx,3DAh
syncwt1:in   al,dx ; ожидать начала обратного хода луча видеоразвертки
    test al,8
    jnz   syncwt1
syncwt2:in   al,dx
    test al,8
    jz   syncwt2
; конец фрагмента
    mouseHide ; скрыть курсор мыши
    mov ax,0A000h ; сегмент видео VGA
    mov es,ax
    mov di,0
    mov ax,cs     ; сегмент видеобуфера
    add ax,codesize/16
    mov ds,ax
    mov si,0
    mov cx,320*200/4 ; 16000 dword
    db  66h ; rep movsd prefix
    rep movsw ; выполняется операция rep movsd 386 процессора
    mouseShow ; показать курсор мыши
    popa
    pop es
    pop ds
    ret
 
; напечатать строку ds:si в видео режиме
prnstring:pusha
; поставьте if 1 чтобы скрыть отладочный вывод
if 0
    mov ah,2  ; опрос флагов клавиатуры
    int 16h
    test al,4 ; ctrl button нажата ?
    jz prnlin1 ; если нет, то не выводим строку
endif
prnlin0:lodsb      ; ax=очередной байт текста
    cmp al,0   ; конец строки ?
    jz prnlin1
    mov ah,0Eh
    mov bl,15 ; цвет выводимого символа
    int 10h
    jmp prnlin0
prnlin1:popa
    ret
 
prnword: ; вывод значения AX в текстовый буфер
    pusha
    mov  di,offset prnbuf+2
    mov cx,3 ; вывести AX как 3 десятичные цифры
pw1:    mov dx,0
    mov bx,10
    div bx
    add dl,"0"
    mov ds:[di],dl
    dec di
    loop pw1    
    mov si,offset prnbuf ; вывести текстовый буфер на экран
    call prnstring
    popa
    ret
 
; геометрические фигуры Координаты 0, 0 - центр фигуры
; первое слово - число линий фигуры
; далее идут координаты вершин
shape3 label word ; треугольник
  dw 3
  dw   0 ,-42 
  dw -45 , 21 
  dw  45 , 21
  dw   0 ,-42 
 
shape4  label word ; квадрат
    dw 4
    dw -40,-32
    dw 40,-32
    dw 40,32
    dw -40,32
    dw -40,-32
 
shapestar label word ; звезда
  dw 5
  dw  0 ,-42 
  dw -30 , 33
  dw  48 ,-13 
  dw -48 ,-13 
  dw  30 , 33 
  dw   0 ,-42 
 
shape32 label word ; окружность
  dw 32
  dw  0 ,-33 
  dw -8 ,-33 
  dw -15 ,-31 
  dw -22 ,-28 
  dw -28 ,-24 
  dw -33 ,-19 
  dw -37 ,-13 
  dw -39 ,-7 
  dw -40 , 0 
  dw -39 , 7 
  dw -37 , 13 
  dw -33 , 19 
  dw -28 , 24 
  dw -22 , 28 
  dw -15 , 31 
  dw -8 , 33 
  dw  0 , 33 
  dw  8 , 33 
  dw  15 , 31 
  dw  22 , 28 
  dw  28 , 24 
  dw  33 , 19 
  dw  37 , 13 
  dw  39 , 7 
  dw  40 , 0 
  dw  39 ,-7 
  dw  37 ,-13 
  dw  33 ,-19 
  dw  28 ,-24 
  dw  22 ,-28 
  dw  15 ,-31 
  dw  8 ,-33 
  dw  0 ,-33 
 
; число объектов (мобов) на экране
nmobs = 6
; структуры мобов. x,y соответствуют центру фигуры
; длина структуры - 8 байт
;         x,  y, цвет, адрес фигуры
mob1 dw  80, 50, 15, offset shapestar
mob2 dw 240, 50, 14, offset shapestar
mob3 dw  80,140, 13, offset shape4
mob4 dw 240,140, 12, offset shape4
mob5 dw 160, 80, 11, offset shape3
mob6 dw 160,140, 10, offset shape32
 
; половина размера квадрата захвата моба мышкой 
; (квадрат 64*64)
grabsiz = 32
; номер выбранного моба
select  dw 0
; смещение центра моба относительно координаты курсора мышки
seldx   dw 0
seldy   dw 0
mycol   dw 0
 
; выбрать моб 
selectmobs:pusha
    mov bx,nmobs ; начинаем с последнего (верхнего) моба
    mov si,offset mob1+8*(nmobs-1) ; адрес моба
sm0:    mov ax,[si]  ; найти смещение центра моба относит курсора мышки ; ax=координата x моба
    sub ax,cx    ; seldx=x_моба-x_мыши
    mov seldx,ax
    mov ax,2[si] ; seldy=y_моба-y_мыши
    sub ax,dx
    mov seldy,ax
    call sqin ; мышка попадает в квадрат выбора ?
    jnc sm1   ; да, записать номер моба
    sub si,8  ; перейти к другому мобу
    dec bx    ; bx используется как счётчик цикла, т к cx хранит координату x мыши
    jnz sm0
sm1:    mov select,bx ; если ни один моб не выбран, select=0
    popa
    ret
; попадает ли мышка в квадрат выбора ?
sqin:   cmp seldx,grabsiz
    jg  sqin1
    cmp seldx,-grabsiz
    jL  sqin1
    cmp seldy,grabsiz
    jg  sqin1
    cmp seldy,-grabsiz
    jL  sqin1
    clc ; да, сбросить флаг С
    ret
sqin1:  stc ; нет, установить флаг C
    ret 
; переместить объект, утянутый мышкой
movmobs:cmp select,0 ; нет выбранных мобов - выход
    jz  mov1
    pusha
    mov ax,select
    dec ax
    shl ax,3; ax=ax*8, где 8 - длина mob
    mov si,offset mob1
    add si,ax ; si - адрес выбранного моба
    mov ax,cx
    add ax,seldx
    mov [si],ax ; x=mousex+seldx
    mov ax,dx
    add ax,seldy
    mov [si+2],ax ; y=mousey+seldy
    popa
mov1:   ret
 
 
; нарисовать мобы
drawmobs:pusha
    mov bx,1 ; двигаемся от первого (нижнего) моба к верхнему
    mov si,offset mob1
dm1:    lodsw
    mov cx,ax ; cx=x
    lodsw
    mov dx,ax ; dx=y
    lodsw
    mov mycol,ax ; col=цвет
    lodsw     ; si=адрес фигуры
    push si
    mov si,ax
    call drawshape ; нарисовать фигуру
    pop si
    inc bx
    cmp bx,nmobs ; следующий моб
    jle dm1
    popa
    ret         
 
drawform:
    mov mycol,10 ; зеленый
    mov si,offset shapestar
; рисовать фигуру
; si=адрес фигуры
; cx,dx - координаты центра фигуры
drawshape:
    lodsw
    mov di,ax ; di=число линий фигуры
draw1:  lodsw     ; загрузить координату x фигуры (начало отрезка)
    add ax,cx ; x1=x+cx
    push ax;  =x1 ; поместить x1 в стек
    lodsw     ; загрузить координату y фигуры
    add ax,dx
    push ax;  =y1
    lodsw     ; аналогично загрузить и записать в стек координаты конца отрезка
    add ax,cx
    push ax ; =x2
    lodsw
    add  ax,dx
    push ax;  =y2
    mov  ax,mycol ; ax=цвет фигуры
    push ax; =col 
    call drawline ; провести линию см brez.inc
    sub si,4    ; продвинуть si на 2 переменных назад, чтобы нарисовать ломаную
    dec di
    jnz draw1   ; конец цикла рисования ломаной
    ret
 
; построение картинки в видео буфере
drawtest:
    call movmobs ; двигать мобы
    call drawmobs ; рисовать мобы
; Используйте эту строку в тестовых целях
;   invoke drawline, <10,10,310,10,15> ; провести отрезок из точки 10,10 в точку 310,10 цветом 15 (белым)
    ret
 
oldcx   dw 0
olddx   dw 0
 
ismoved:cmp oldcx,cx
    jnz ism1
    cmp olddx,dx
ism1:   ret
 
; вывод сообщения об ошибке, если драйвер мыши не найден
emess   db "Error: mouse driver not found",13,10,"$"
exiterr:mov ax,3 ; вернуться в текстовый режим
    int 10h
    mov dx,offset emess ; печать сообщения
    mov ah,9
    int 21h
    mov ax,4C01h ; выход в DOS с кодом ошибки 1
    int 21h
 
; начало основной программы
 
beg:    cld
    push cs ;ds=es=cs
    pop  ds
    push cs
    pop  es
    mov ax,13h ; установить граф режим VGA 13h - 320*200 256 цветов
    int 10h
    mouse 0   ; инит мышку
    cmp ax,-1
    jnz  exiterr ; мышка не найдена - выход
    mouseShow      ; показать курсор мыши
; нарисовать сцену на экране
    call cls ; стереть буфер
    call drawtest ; рисовать в буфере сцену
    call sync ; копировать результат на экран
; основной цикл
main:   mov ah,1 ; клавиша нажата - выход
    int 16h
    jnz exit
    mov oldcx,cx
    mov olddx,dx
    mousePoll ; опрос состояния мышки
        ; возвращает cx,dx - координаты, bx - биты кнопок мышки
    shr cx,1  ; 320w screen
; вывод отладочной инф (если нажата клавиша ctrl)
    setcur 0
    mov ax,cx ; mousex
    call prnword
    setcur 1    
    mov ax,dx ; mousey
    call prnword
    setcur 2    
    mov ax,bx ; mouse buttons
    call prnword
    test bx,1 ; нажата левая кнопка мыщки ?
    jz  ma1   ; нет - выбирать объект
    call ismoved ; мышка была сдвинута при нажатой левой кнопке ?
    jz  main     ; нет - ничего не делать
    call cls  ; да - передвинуть выбранный объект и перерисовать сцену
    call drawtest
    call sync
    jmp main  ; конец основного цикла
 
ma1:    call selectmobs ; выбрать объект
    setcur 3
    mov ax,select   ; напечатать номер объекта
    call prnword
    jmp main        ; возврат к началу основного цикла
 
exit:   mov ah,0 ; выход из программы Поглотить код нажатой клавиши
    int 16h
    mouseHide  ; скрыть курсор мыши
    mov ax,3 ; вернуться в текстовый режим
    int 10h
    mov ax,4C00h ; выход в DOS
    int 21h
 
    end start