Чтение диска (int 13h ah=02h) - как определить входные параметры?

logical2chs:    ;calculate head, track and sector settings for int 13h
                ;INPUT: logical sector in AX
                ;OUTPUT: registers for int 13h
    push bx
    push ax
 
    ;first calculate which start phisical sector on disk
    ;start phisical sector CL = start logical sector % SectorsPerTrack
 
    mov bx, ax          ;start logical sector for reading in AX
 
    mov dx, 0           ;first the sector
    div word [SectorsPerTrack] ;AX = AX div SectorsPerTrack
    add dl, 01h         ;physical sectors start at 1
    mov cl, dl          ;physical sector in CL for int 13h
 
    ;next calculate which head and track
 
    mov ax, bx  ;AX = start logical sector for reading
 
    mov dx, 0           
    div word [SectorsPerTrack]  ;AX = AX div SectorsPerTrack
    mov dx, 0
    div word [NumHeads]         ;AX = AX div NumHeads
    mov dh, dl                  ;which head/side
    mov ch, al                  ;which track
 
    pop ax
    pop bx
 
    mov dl, byte [bootdev]      ; Set correct device
 
    ret

logical2chs:    ; calculate head, track and sector settings for int 13h
                ; INPUT: logical sector in AX (starting from 0)
                ; OUTPUT: registers for int 13h
 
        xor     dx,dx           ; 'cwd' can be used here to save a byte if AX < 8000h
        div     word [SectorsPerTrack]
        inc     dx
        mov     cl,dl           ; sector
 
        xor     dx,dx           ; 'cwd' can be used here to save a byte if SectorsPerTrack > 1 or input AX < 8000h
        div     word [NumHeads]
        mov     ch,al           ; track
        shr     ax,2            ;*
        and     al,11000000b    ;* bits 8..9 of track number
        or      cl,al           ;* track high bits
        mov     dh,dl           ; head
        mov     dl,[Device]
        ret
; * requires only if track number can be more than 255