Вычислить определенный интеграл методом трапеций

@LuciferM · Регистрация: 12.10.2017

Студворк — интернет-сервис помощи студентам

Calculate, using FPU, the following definite integral with the help of the trapezoidal
method:
$https://www.cyberforum.ru/cgi-bin/latex.cgi?\int_{1}^{2}\(exp(2x)+\sqrt{x})dx$

ФедосеевПавел · 01.12.2017, 22:35

Assembler
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
.486
.model flat, stdcall
option casemap :none
 
        include \masm32\include\windows.inc
 
        include \masm32\include\user32.inc
        include \masm32\include\kernel32.inc
        include \masm32\include\masm32.inc
 
        includelib \masm32\lib\user32.lib
        includelib \masm32\lib\kernel32.lib
        includelib \masm32\lib\masm32.lib
.data
        Xstart          dq      1.0     ;начальное значение аргумента
        Xfinish         dq      2.0     ;конечное значение аргумента
        N               dd      1000    ;количество интервалов интегрирования
 
        aszMsgResult    db      'Result: ', 0
        aszPressLeftAlt db      0Dh, 0Ah, 0Dh, 0Ah, "Press Left Alt to exit", 0
        dwColorRed      dd      FOREGROUND_RED
        dwColorWhite    dd      FOREGROUND_RED + FOREGROUND_GREEN + FOREGROUND_BLUE
        dwCursorPosition        COORD   <20, 10>
.data?
        hConsoleOutput  HANDLE  ?
        hConsoleInput   HANDLE  ?
        X               dq      ?       ;текущее значение аргумента
        DeltaX          dq      ?       ;шаг приращения аргумента
        Result          dq      ?       ;результат - значение интеграла
        FpuSw           dw      ?       ;слово состояния FPU (для команд сравнения)
        Buffer          db      1024 dup(?)
        BufLen          dd      ?
 
.code
 
start   proc
 
        ; получение описателей ввода и вывода консоли
        invoke  GetStdHandle,   STD_INPUT_HANDLE
        mov     hConsoleInput,  eax
        invoke  GetStdHandle,   STD_OUTPUT_HANDLE
        mov     hConsoleOutput, eax
        ;очистка экрана
        invoke  ClearScreen
        ;ввод количества интервалов интегрирования
 
        finit
        ;получим Xstart
        fld     [Xstart]
        ;вычислим Xfinish
        fld     [Xfinish]
        ;вычисление приращения аргумента DeltaX
        fld     [Xfinish]
        fsub    st(0),  st(2)
        fild    [N]
        fdivp   st(1),  st(0)
        fst     [DeltaX]
        ;
        fxch    st(2)
        fldz
        fxch    st(1)
 
        ;st(0)  - X
        ;st(1)  - интеграл
        ;st(2)  - Xfinish
        ;st(3)  - DeltaX
        mov     ecx,    [N]
        @@for:
                fld     st(0)           ;f(a)
                call    F
                fld     st(1)           ;f(b)
                fadd    st(0),  st(5)
                fst     st(2)           ;X=X+DeltaX
                call    F
                faddp   st(1),  st(0)   ;st(0)=(f(a)+f(b))/2
                fld1
                fld1
                faddp   st(1),  st(0)
                fdivp   st(1),  st(0)
                faddp   st(2),  st(0)   ;I=st(1)=I+(f(a)+f(b))/2
 
        loop    @@for
        fxch    st(1)
        fmul    st(0),  st(3)
        fst     [Result]
 
        ;вывод результата
        ; - смена цвета
        invoke  SetConsoleTextAttribute, hConsoleOutput, [dwColorRed]
        ; - установка позиции
        invoke  SetConsoleCursorPosition, hConsoleOutput, dword ptr [dwCursorPosition]
        ; - вывод
        invoke  WriteConsole, hConsoleOutput, ADDR aszMsgResult,\
                LENGTHOF aszMsgResult - 1, ADDR BufLen, NULL
        invoke  FloatToStr2, [Result], ADDR Buffer
        invoke  StrLen, ADDR Buffer
        mov     [BufLen],       eax
        invoke  WriteConsole, hConsoleOutput, ADDR Buffer,\
                BufLen, ADDR BufLen, NULL
 
        ;ожидание нажатия Left Alt
        invoke  SetConsoleTextAttribute, hConsoleOutput, [dwColorWhite]
        invoke  WriteConsole, hConsoleOutput, ADDR aszPressLeftAlt,\
                LENGTHOF aszPressLeftAlt - 1, ADDR BufLen, NULL
        @@WaitForLAlt:
                invoke  GetAsyncKeyState, VK_LMENU
                and     eax,    8000h
        jz      @@WaitForLAlt
        ;завершение программы
        invoke  ExitProcess, 0
start   endp
 
;Значение подынтегральной функции
F       proc
        LOCAL   @StateFPU[108]:byte     ;108 use32, 94 use16
        LOCAL   @X:QWord
        LOCAL   @Result:QWord
        ;перед очисткой стека FPU сохраним:
        fstp    [@X]            ; вершину стека (аргумент функции)
        fsave   [@StateFPU]     ; состояние FPU
        ;перед началом работы очищаем стек FPU
        finit
        ;в вершину стека помещаем аргумент функции
        fld     [@X]
 
        fld     st(0)           ;exp(2x)
        fadd    st(0),  st(0)
 
        fldl2e                  ;  st(0)=1/ln(2)=log2(e)
        fmul                    ;  st(0)=x/ln(2)=x*log2(e)
        fld     st
        frndint
        fsub    st(1), st
        fxch    st(1)
        f2xm1
        fld1
        fadd
        fscale
        fstp    st(1)
 
        fxch    st(1)           ;sqrt(x)
 
        fsqrt
 
        faddp   st(1),  st(0)   ;exp(2x)+sqrt(x)
        ;перед восстановлением состояния FPU сохраним результат функции
        fst     [@Result]
        ;восстановление состояния FPU
        frstor  [@StateFPU]
        ;результат вычислений на вершину стека
        fld     [@Result]
 
        ret
F       endp
 
end start

ФедосеевПавел · 31.05.2019, 01:49

Строки 121-122 лишние, т.к. fsave кроме сохранения контекста выполняет и очистку стека FPU.

Новые блоги и статьи Все статьи Все блоги /
SDL3 для Web (WebAssembly): Идентификация объектов на Box2D v3 - использование userData и событий коллизий 8Observer8 02.03.2026 Содержание блога Финальная демка в браузере. Итоговый код: finish-collision-events-sdl3-c. zip https:/ / www. cyberforum. ru/ blog_attachment. php?attachmentid=11680&d=1772460536 Одним из. . .	Реалии Hrethgir 01.03.2026 Нет, я не закончил до сих пор симулятор. Эта задача сложнее. Не получилось уйти в плавсостав, но оно и к лучшему, возможно. Точнее получалось - но сварщиком в палубную команду, а это значит, в моём. . .	Ритм жизни kumehtar 27.02.2026 Иногда приходится жить в ритме, где дел становится всё больше, а вовлечения в происходящее — всё меньше. Плотный график не даёт вниманию закрепиться ни на одном событии. Утро начинается с быстрых,. . .	SDL3 для Web (WebAssembly): Сборка библиотек: SDL3, Box2D, FreeType, SDL3_ttf, SDL3_mixer и SDL3_image из исходников с помощью CMake и Emscripten 8Observer8 27.02.2026 Недавно вышла версия 3. 4. 2 библиотеки SDL3. На странице официальной релиза доступны исходники, готовые DLL (для x86, x64, arm64), а также библиотеки для разработки под Android, MinGW и Visual Studio. . . .
SDL3 для Web (WebAssembly): Реализация движения на Box2D v3 - трение и коллизии с повёрнутыми стенами 8Observer8 20.02.2026 Содержание блога Box2D позволяет легко создать главного героя, который не проходит сквозь стены и перемещается с заданным трением о препятствия, которые можно располагать под углом, как верхнее. . .	Конвертировать закладки radiotray-ng в m3u-плейлист damix 19.02.2026 Это можно сделать скриптом для PowerShell. Использование . \СonvertRadiotrayToM3U. ps1 <path_to_bookmarks. json> Рядом с файлом bookmarks. json появится файл bookmarks. m3u с результатом. # Check if. . .	Семь CDC на одном интерфейсе: 5 U[S]ARTов, 1 CAN и 1 SSI Eddy_Em 18.02.2026 Постепенно допиливаю свою "многоинтерфейсную плату". Выглядит вот так: https:/ / www. cyberforum. ru/ blog_attachment. php?attachmentid=11617&stc=1&d=1771445347 Основана на STM32F303RBT6. На борту пять. . .	Камера Toupcam IUA500KMA Eddy_Em 12.02.2026 Т. к. у всяких "хикроботов" слишком уж мелкий пиксель, для подсмотра в ESPriF они вообще плохо годятся: уже 14 величину можно рассмотреть еле-еле лишь на экспозициях под 3 секунды (а то и больше),. . .

@LuciferM 0 / 0 / 0 Регистрация: 12.10.2017 Сообщений: 4

	Вычислить определенный интеграл методом трапеций 01.12.2017, 15:31. Показов 2360. Ответов 2 Метки нет (Все метки) Calculate, using FPU, the following definite integral with the help of the trapezoidal method: $https://www.cyberforum.ru/cgi-bin/latex.cgi?\int_{1}^{2}\(exp(2x)+\sqrt{x})dx$ 0

ФедосеевПавел Модератор 8659 / 4494 / 1669 Регистрация: 01.02.2015 Сообщений: 13,907 Записей в блоге: 12
	31.05.2019, 01:49
	Строки 121-122 лишние, т.к. fsave кроме сохранения контекста выполняет и очистку стека FPU. 0