Сменить цвет в окнах Static

%TITLE "Start.asm"
 
; Минимальное приложение Win32
 
    IDEAL
 
    P386
    LOCALS  @@
    MODEL   flat, STDCALL
 
    MASM    ; Вставка объявлений Windows (требуется режим MASM)
 
PathInc macro x
include C:\tools\tasm\include\x
endm
 
PathInc iConst.inc
PathInc Win32.inc
 
    IDEAL
 
include "Winapp.ri"     ; -------- Вставка идентификаторов ресурсов
 
WINDOW_WIDTH        = 640           ; Ширина окна
WINDOW_HEIGHT       = 400           ; Высота окна
MIN_WINDOW_WIDTH    = WINDOW_WIDTH-10   ; Минимальная ширина окна
MIN_WINDOW_HEIGHT   = WINDOW_HEIGHT-10  ; Минимальная высота окна
 
 
    DATASEG     ; -------- Инициализированные переменные
 
include "iData.inc"     ; -------- Определение переменных
 
_g_szWndname    db 'wnd_winapp', 0
_g_szAppname    db 'Winapp Simple win32', 0
szQuest         db 'Do you want to close the program?', 0
 
szWelcome   db 'You smell really bad. Shave, lose weight, and get a real job.', 0
 
szErr1      db 'Cannot register class', 0
szErr2      db 'Cannot create window', 0
 
 
    UDATASEG    ; -------- Неинициализированные переменные
 
Hinstance       dd ?
_g_hWnd     dd ?
 
 
    CODESEG 
 
include "iProc.inc"     ; -------- Определение внешних функций, импортируемых из Windows
 
;
; Entry point
;
Start:
    push    0
    call    GetModuleHandleA
    mov [Hinstance], eax
 
    push    0
    push    offset _g_szWndname
    call    FindWindowA
    or  eax, eax
    jnz Exit
 
    call    WinMain
    jmp Exit
 
ERROR_REGISTER:
    push    ICON_WARNING
    push    offset _g_szAppname
    push    offset szErr1
    jmp MSGBOX
 
ERROR_CREATE:
    push    ICON_WARNING
    push    offset _g_szAppname
    push    offset szErr2
 
MSGBOX:
    push    0
    call    MessageBoxA
Exit:
    push    0
    call    ExitProcess
; -------------------------------------------------------
;
; WinMain
;
proc    WinMain
 
    call    AppInit
    call    AppRun
    ret
 
endp    WinMain
 
;
; AppInit
;
proc    AppInit
 
    call    RegisterWin
 
    push    0           ; Pointer to window-creation data
    push    [Hinstance]     ; Handle to application instance
    push    0           ; Handle to menu, or child-window identifier
    push    0           ; Handle to parent or owner window
    push    CW_USEDEFAULT       ; Window height
    push    CW_USEDEFAULT       ; Window width
    push    CW_USEDEFAULT       ; Y vertical position of window
    push    CW_USEDEFAULT       ; X horizontal position of window
 
    ; Window style
    ;push   WS_SYSMENU or WS_CAPTION or WS_MINIMIZEBOX
    push    WS_OVERLAPPEDWINDOW
 
    push    offset _g_szAppname ; Pointer to registered window name
    push    offset _g_szWndname ; Pointer to registered class name
 
    push    WS_EX_APPWINDOW ; Extended window style
    ;push   WS_EX_WINDOWEDGE
 
    call    CreateWindowExA
    cmp eax, 0
    je  ERROR_CREATE
    mov [_g_hWnd], eax
 
    push    SW_SHOWNORMAL
    push    [_g_hWnd]
    call    ShowWindow
 
    push    [_g_hWnd]
    call    UpdateWindow
    ret
endp    AppInit
 
;
; AppRun
;
proc    AppRun
 
    LOCAL   @@msg:MSGSTRUCT
@@10:
    push    0
    push    0
    push    0
    lea eax, [@@msg]
    push    eax
    call    GetMessageA
    or  ax, ax
    je  @@99
    lea eax, [@@msg]
    push    eax
    call    TranslateMessage
    lea eax, [@@msg]
    push    eax
    call    DispatchMessageA
    jmp @@10
@@99:
    ret
endp    AppRun
 
;
; RegisterWin
;
proc    RegisterWin
 
    LOCAL   @@wcex:WNDCLASSEXA
 
    mov [@@wcex.cbSize], WNDCLASSEXA_LEN        ; sizeof WNDCLASSEXA
    mov [@@wcex.style], CS_HREDRAW or CS_VREDRAW
    mov [@@wcex.lpfnWndProc], offset WndProc
    mov [@@wcex.cbClsExtra], 0
    mov [@@wcex.cbWndExtra], 0
    mov eax, [Hinstance]
    mov [@@wcex.hInstance], eax
    push    IDI_APPICON
    push    0
    call    LoadIconA
    mov [@@wcex.hIcon], eax
    mov [@@wcex.hIconSm], eax
    push    IDC_ARROW
    push    0
    call    LoadCursorA
    mov [@@wcex.hCursor], eax
    mov [@@wcex.hbrBackground], COLOR_WINDOW
    mov [@@wcex.lpszMenuName], IDR_MAINFRAME
    mov [@@wcex.lpszClassName], offset _g_szWndname
    lea eax, [@@wcex]
    push    eax
    call    RegisterClassExA
    cmp eax, 0
    je  ERROR_REGISTER
    ret
endp    RegisterWin
 
;
; WndProc
;
proc    WndProc
 
    USES    ebx, edi, esi
 
    ARG hWnd:dword, uMsg:dword, wParam:dword, lParam:dword
    LOCAL   @@pDC:dword, @@ps:PAINTSTRUCT, @@rect:RECT
 
    mov edi, [hWnd]
    mov esi, [uMsg]
 
    cmp esi, WM_CREATE
    je  @@WMCREATE
 
    cmp esi, WM_PAINT
    je  @@WMPAINT
 
    cmp esi, WM_COMMAND     ; Command
    je  @@WMCOMMAND
 
    cmp esi, WM_GETMINMAXINFO       ; Disable size window
    je  @@WMGETMINMAXINFO
 
    cmp esi, WM_CLOSE
    je  @@WMCLOSE
 
    cmp esi, WM_DESTROY
    je  @@WMDESTROY
 
    jmp @@DEFWINDOWPROC
 
@@WMCREATE:
    jmp @@RETURNZERO
 
@@WMPAINT:
    lea eax, [@@ps]
    push    eax
    push    edi         ; hWnd
    call    BeginPaint
    mov [@@pDC], eax
    push    TRANSPARENT
    push    eax
    call    SetBkMode
;   jmp SKIP
 
    push    offset szWelcome        ; Length of string
    call    lstrlenA
    push    eax
    push    offset szWelcome        ; String
    push    100         ; y
    push    100         ; x
    push    [@@pDC]     ; the DC
    call    TextOutA
    jmp SKIP2
SKIP:
    push    DT_EXTERNALLEADING or DT_NOPREFIX or DT_WORDBREAK
    mov [@@rect.rcLeft], 10
    mov [@@rect.rcTop], 10
    mov [@@rect.rcRight], 600
    mov [@@rect.rcBottom], 100
    lea eax, [@@rect]
    push    eax
    push    -1
    push    offset szWelcome        ; String
    push    [@@pDC]
    call    DrawTextA
SKIP2:
    lea eax, [@@ps]
    push    eax
    push    edi         ; hWnd
    call    EndPaint
    jmp @@RETURNZERO
 
@@WMCOMMAND:
    push    [lParam]
    push    [wParam]
    push    edi         ; hWnd
    call    OnCommand
    jmp @@RETURNZERO
 
@@WMGETMINMAXINFO:
    mov ebx, [lParam]       ; Minmaxinfo structure
    mov [(MINMAXINFO ebx).mintrackposition_x], MIN_WINDOW_WIDTH
    mov [(MINMAXINFO ebx).mintrackposition_y], MIN_WINDOW_HEIGHT
    jmp @@RETURNZERO
 
@@WMCLOSE:
    push    MB_YESNO or MB_ICONQUESTION
    push    offset _g_szAppname
    push    offset szQuest
    push    edi         ; hWnd
    call    MessageBoxA
    cmp eax, IDYES
    jne @@RETURNZERO
    push    edi         ; hWnd
    call    DestroyWindow
    jmp @@RETURNZERO
 
@@WMDESTROY:
    push    0
    call    PostQuitMessage
    jmp @@RETURNZERO
 
@@DEFWINDOWPROC:
    push    [lParam]
    push    [wParam]
    push    esi         ; uMsg
    push    edi         ; hWnd
    call    DefWindowProcA
    jmp @@99
 
@@RETURNZERO:
    mov eax, 0
@@99:
    ret
endp    WndProc
 
;
; DlgProc
;
proc    DlgProc
 
    USES    edi, esi
    ARG hWnd:dword, uMsg:dword, wParam:dword, lParam:dword
 
    mov edi, [hWnd]
    mov esi, [uMsg]
    cmp esi, WM_INITDIALOG
    je  @@WMINITDIALOG
 
    cmp esi, WM_COMMAND
    je  @@WMCOMMAND
    jmp @@RETURNFALSE
 
@@WMINITDIALOG:
    jmp @@RETURNTRUE
 
@@WMCOMMAND:
    mov esi, [wParam]
    cmp esi, IDOK
    je  @@IDOK
    jmp @@RETURNFALSE
 
@@IDOK:
    push    0
    push    edi     ; hWnd
    call    EndDialog
    jmp @@RETURNTRUE
    
@@RETURNTRUE:
    mov eax, 1
    jmp @@99
 
@@RETURNFALSE:
    mov eax, 0
@@99:
    ret
endp    DlgProc
 
;
; HelpAbout
;
proc    HelpAbout
 
    ARG hWnd:dword
 
    push    0
    push    offset DlgProc
    push    [hWnd]
    push    IDD_ABOUTBOX
    push    [Hinstance]
    call    DialogBoxParamA
    ret
endp    HelpAbout
 
;
; OnCommand
;
proc    OnCommand
 
    USES    edi, esi
    ARG hWnd:dword, wId:dword, lParam:dword
 
    mov edi, [hWnd]
    mov esi, [wId]
 
    cmp esi, IDM_EXIT
    je  @@IDMEXIT
    cmp esi, IDM_ABOUT
    je  @@IDMABOUT
    jmp @@99
 
@@IDMEXIT:
    push    0
    push    0
    push    WM_DESTROY
    push    edi
    call    SendMessageA
    jmp @@99
 
@@IDMABOUT:
    push    edi
    call    HelpAbout
    jmp @@99
@@99:
    ret
endp    OnCommand
 
    END Start
 
; -------------------------------------------------------
; <<eof>> Start.asm
; -------------------------------------------------------