перенести создание файла в основную нерезидентную часть

.286
cseg segment
assume cs:cseg, ds:cseg, ss:cseg, es:cseg      
org 100h        ;Префикс программного сегмента(служ. инф., параметры ком.строки)
 
begin:
       jmp init     ;на метку инициализации (начало программы)
 
; === процедура обработки 09h прерывания (клавиатура) ===
int_09h_proc proc
 
       cmp ax, 0FFAAh   ;Проверка на то, что загружаем в первый раз
       jne continue ;Если не проверка, то продолжаем далее
       xchg ah,al   ;Меняем местами FF и AA - это флаг признак,что резидент загружен
       iret             ;выход из прерыв.-возврат в программу, восстанавливая из стека значения регистров IP, CS и FLAGS.
 
continue:
       push ax
       push es
 
       xor ax,ax 
       mov es,ax
       mov al,es:0417h  ; берем байт статуса клавиатуры - нажата ли клавиша (BIOS data area)
       test al,00000100b  ; проверяем не нажат ли Ctrl
       jz not_ctrl_s ; выходим, если нет
 
               in al,60h ; принимаем скан-код с клавиатуры
               cmp al, 2dh  ;  сравниваем со скан кодом X
               je unload    ;Выгружаем, если совпало
               cmp al,1fh ; сравниваем со скан кодом S
               jne not_ctrl_s ; выходим если это не он. Иначе продолжаем
 
       pusha     ;(push All registers) помещает в стек регистры ax, cx, dx, bx, sp, bp, si, di.
       pushf     ;помещает в стек регистр флагов (нуля, переноса...)
 
       cli      ;запрещаем прерывания, чтобы не было конфликтов
       push es      ;и сегментные регистры
       push ds
 
       push 0b800h      ;ds должен быть равен сегменту видеобуфера 0-ой страницы
       pop ds           ;0b800h - сегмент этой страницы теперь в ds
 
       push 0b900h  ;es - 1-ой страницы
       pop es       ;0b900h - сегмент этой страницы теперь в es
 
 
       xor di,di    ;аннулируем di и si
       xor si,si
 
       mov cx,25    ;на экране 25 строк...
next_line:
       push cx
       mov cx,80    ;...80 символов в каждой строке
next_symbol:
       lodsw        ;берем первый символ и атрибут в ax по адресу ds:si (lodsw)
       stosb        ;заносим символ без атрибута из al в 1-ую
            ;видеостраницу (stosb) - из [es:di]
       loop next_symbol ;следующий символ... (пока cx не станет 0)
 
       mov ax,0a0dh ;добавляем в конце каждой строки возврат каретки
       stosw        ;перевод строки
       pop cx
       loop next_line   ;следующая строка... (пока cx не станет 0)
 
       push cs      ;ds должен быть равен сегменту, в котором мы сейчас
       pop ds       ;находимся (а cs всегда на этот сегмент и указывает)
files:
       mov ax,3d02h ;функция открытия файла 3d - открыть, 02h - для чтения/записи
       mov dx,offset screen_file_name   ;ds:dx указывают на путь и имя файла
       int 21h      ;создаем файл в текущем каталоге
       jnc file_opened  ;Если файл открыт (он существует), то пропускаем этап создания
       mov ax,3c02h     ;Функция создания файла 3сh, 02h - для чтения и записи
       xor cx,cx        
       int 21h
 
file_opened:
       xor cx,cx
       xor dx,dx
 
       mov bx,ax        ;Тут устанавливаем указ. в файле 42h-устанавливаем указатель в файл,
       mov ax,4202h ;02h - с послед. места
       int 21h
 
       push 0b900h  ;ds должен указывать на 1-ую видеостраницу
       pop ds
 
       mov ah,40h   ;функция записи в файл
       xor dx,dx    ;ds:dx должны указывать на буфер, где находятся данные
       mov cx,2050  ;кол-во записываемых байт (80*25 + 2*25 = 2050)
       int 21h      ;записываем в созданный файл содержимое экрана...
 
       mov ah,3eh   ;функция закрытия файла
       int 21h
 
       pop ds       ;восстановим сохраненные регистры
       pop es
 
       sti      ;разрешим прерывания
 
       popf             ;Восстанавливаем флаги
       popa     ;И регистры
 
not_ctrl_s:
 
       pop es            ; восстанавливаем регистры
       pop ax
 
       jmp dword ptr cs:[int_09h_vect]  ;передаем управление оригинальному обработчику 09h...
    
 
unload:                            ;Выгружаем наш обработчик прерывания 09h из оперативной памяти
 
       mov ax,2509h                 ;Для этого функцией 25h  
                                    ;загружаем указатель на оригинальный обработчик               
       lds dx,[cs:int_09h_vect]     ;lds (load ds) - загружает в ds = cs:int_09h_vect
                                       в dx = cs:int_09h_vect+2
       int 21h
 
       mov es, [cs:2ch]
       mov ah,49h
       int 21h ; освободить память
       push cs
       pop es
       mov ah, 49h
       int 21h
 
       pop es             ; восстанавливаем регистры
       pop ax
 
       jmp dword ptr cs:[int_09h_vect]
 
int_09h_vect dd ?       ;переменная для хранения адреса 09h прерывания (оригинального)
screen_file_name db 'c:\screen.txt',0   ;имя файла, куда занесем содержимое экрана
 
int_09h_proc endp
 
; ===============================================================
; инициализация (подготовка и настройка резидента)
init:
 
       mov ax, 0FFAAh ;Три строки - проверка, не загружен ли уже резидент
       int 9h          ;Для этого помещаем в ax нигде не встречающееся число
       cmp ax, 0AAFFh  ;И если загружаем, то меняем дробную/целую часть
      
       je already_running    ;Если 
       push es
       mov ax,3509h
       int 21h      ;получим и сохраним адрес (вектор) 09h прерывания
       mov word ptr int_09h_vect,bx ;вначале младшее слово (смещение)...
       mov word ptr int_09h_vect+2,es   ;затем старшее (сегмент)
 
       mov ax,2509h   ;25h устанавливает для al (у нас 09h) значение элемента таблицы векторов=ds:dx
       mov dx,offset int_09h_proc       ;А вот и dx - сюда адрес нового обработчика прерывания 09h
       int 21h      ;Все. "повесим" нашу процедуру на 09h прерывание (при помощи функции 25h)
 
       mov ah,9                    ;Тут просто сообщение, говорящее о том, что программа запустилась
       mov dx,offset mess_hello    ;И загрузилась
       int 21h
 
       mov dx,offset init     ;В dx - адрес метки инициализации
       pop es
       int 27h      ;оставим программу резидентной в памяти, выходим в DOS
 
already_running:
       mov ah, 9
       mov dx, offset in_memory  ;Выводим сообщение о том, что уже запущено
       int 21h
       mov ax, 4c00h      ;Выход (из родительского процесса - init)
       int 21h
 
in_memory db 'Already running...',0ah,0dh,'$'     ;наше сообщение
;А ниже - сообщение, которое грузится при первоначальном запуске программы
mess_hello db 'Press Ctrl+s to write the screen to file C:\SCREEN.TXT',0ah,0dh,'$'
 
cseg ends
end begin

New09Obrab  proc        ; новый обработчик прерывания int09h
 
    pushf           ; заносим флаги в стек, поскольку iret в конце оригинального обработчика заберет один экземпляр флагов из стека
    call    dword   ptr CS:[Old09]  ; вызов оригинального обработчика
    cli         ; запретить прерывания
    pushf           ; сохранить флаги
    pusha           ; сохранить регистры общего назначения
    mov cs:work,0   ; сбрасываем признак активации
    in  al,60h      ; читаем из порта клавиатуры скан-код нажатойй клавиши
    cmp     al,3bh      ; это f1?
    jz  fx_pressed
    cmp     al,3ch      ; это f2?
    jz  fx_pressed
    cmp     al,3dh      ; это f3?
    jz  fx_pressed
    cmp     al,3eh      ; это f4?
    jz  fx_pressed
    jmp skipwork    ; иначе просто пропускаем
fx_pressed:
    mov cs:work,1   ; устанавливаем признак активации
    sub al,3bh      ; по нажатой клавище получаем номер страницы: f1-0,f2-1,f3-2,f4-3
    mov ah,0
    shl ax,12       ; расчитываем смещение страницы
    push    es      ; сохраняем сегментные регистры, поскольку они не сохраняются командой pusha
    push    ds              ;
    push    cs      ; установка es:di в начало буфера программы и ds:si в начало страницы
    pop es
    push    0b800h
    pop ds
    mov si,ax       ; адрес начала страницы
    mov di, offset scrbuff; адрес начала буфера в памяти
    cld                     ; устанавливаем прямой режим увеличения адресов при работе со строковыми командами
    mov cx,0        ; обход страницы
    mov bl,80       ; делитель
scr:
    lodsw           ; команда загрузки из последовательности(цепочки) в аккумулятор AX
    stosb           ; сохраняем в цепочке только код символа
    inc cx      ; увеличиваем счетчик
    mov ax,cx
    div bl      
    test    ah,ah       ;достигнут ли конец строки экрана?
    jnz ncrlf
    mov ax,0a0dh    ;если да, то добавляем в буфер символы конца строки
    stosw
ncrlf:  cmp cx,2048     ;обходим пока не закончится видеостраница
    jnz scr
 
    pop ds      ; восстанавливаем сегментные регистры
    pop es
skipwork:
    popa            ; восстанавливаем регистры общего назначения
    popf            ; восстанавливаем флаги
    sti         ; разрешить прерывания
    iret            ; выход из прерывания
endp
 
New28Obrab  proc        ; новый обработчик прерывания int28h
 
    pushf           ; заносим флаги в стек, поскольку iret в конце оригинального обработчика заберет один экземпляр флагов из стека
    call    dword   ptr CS:[Old28]  ; вызов оригинального обработчика
    pushf           ; сохранить флаги
    pusha           ; сохранить регистры общего назначения
    cmp cs:work,1   ; проверяем фдаг активации
    jnz skip28      ; выход из обработчика, если флаг сброшен
    push    es      ; сохраняем сегментные регистры, поскольку они не сохраняются командой pusha
    push    ds              ;
    push    cs      ; установка es и ds равным cs
    pop es
    push    es
    pop ds
    mov ah,41h      ;удаляем файл page.txt(если он есть), чтобы не мешать созданию нового
    mov dx,offset fname
    int 21h
    mov ah,3ch      ;создаем файл page.txt
    mov cx,0
    mov dx,offset fname
    int 21h
    jc  stop28      ;если ошибка, то пропускаем дальнейшие файловые операции
    mov handle,ax   ;сохраняем хэндл
    mov bx,ax
    mov ah,40h      ;записываем на диск сожержимое буфера
    mov cx,800h + 26*2
    mov dx,offset scrbuff
    int 21h
    jc  stop28
    mov bx,handle   ;и закрываем файл
    mov ah,3eh
    int 21h
 
 
 
stop28: mov cs:work,0   ;сбрасываем флаг активации
    pop ds      ; восстанавливаем сегментные регистры
    pop es
skip28:
    popa            ; восстанавливаем регистры общего назначения
    popf            ; восстанавливаем флаги
    iret            ; выход из прерывания
endp