Рисование фрактала

org 100h
use16
        mov ax, 13h
        int 10h
        call    SetVisiblePage0
        call    ClearScreen
 
        fninit
        mov bx, colors
        mov cx, 255
@@:     mov [temp], cx
        fild    [temp]
        fmul    [pi_2_256]
        fld st0
        fadd    [pi_2_3]
        fld st0
        fadd    [pi_2_3]
        fsin
        fld1
        faddp
        fmul    [brightness]
        fistp   [temp]
        mov ax, [temp]
        mov [bx], al
        inc bx
        fsin
        fld1
        faddp
        fmul    [brightness]
        fistp   [temp]
        mov ax, [temp]
        mov [bx], al
        inc bx
        fsin
        fld1
        faddp
        fmul    [brightness]
        fistp   [temp]
        mov ax, [temp]
        mov [bx], al
        inc bx
        dec cx
        jns @b
 
        push    0a000h
        pop es
        mov al, 2
        mov dx, 3c4h
        out dx, al
        mov dx, 3c5h
        mov al, 0fh
        out dx, al
        xor bx, bx
 
        fld [minY]
        fstp    [z0Im]
        xor di, di
forY:       fld [minX]
        fstp    [z0Re]
        xor si, si
forX:       fld [z0Re]
        fld [z0Im]
        mov cx, 255
@@:     fld st1
        fmul    st0, st0
        fld st1
        fmul    st0, st0
        fld st1
        fadd    st0, st1
        fld [inf]
        fcomip  st1
        fstp    st0
        jb  @f
        fsubp
        fadd    [p]
        fxch    st2
        fmulp
        fadd    st0, st0
        fadd    [q]
        dec cx
        jnz @b
@@:     test    cx, cx
        jz  @f
        fcompp
@@:     fcompp
        mov [es:bx], cl
        inc bx
        fld [z0Re]
        fadd    [_dX]
        fstp    [z0Re]
        inc si
        cmp si, gMaxX
        jne forX
        fld [z0Im]
        fadd    [_dY]
        fstp    [z0Im]
        inc di
        cmp di, gMaxY
        jne forY
 
        mov bx, colors
mainLoop:   mov dx, 03c8h
        xor al, al
        out dx, al
        mov dx, 03c9h
        mov si, bx
        mov cx, colorsEnd
        sub cx, bx
        rep outsb
        mov si, colors
        lea cx, [bx - colors]
        test    cx, cx
        jz  @f
        rep outsb
@@:     add bx, 3
        cmp bx, colorsEnd
        jne @f
        mov bx, colors
@@:     mov dx, 50
@@:     xor cx, cx
        loop    $
        dec dx
        jnz @b
        mov ah, 1
        int 16h
        jz  mainLoop
 
        xor ah, ah
        int 16h
        mov ax, 3
        int 10h
        ret
 
z0Re        dd ?
z0Im        dd ?
temp        dw ?
colors      rb 256 * 3
label colorsEnd at $
 
p       dd -0.55
q       dd -0.55
gMaxX       = 320
gMaxY       = 200
minX        dd -0.75
maxX        dd 0.75
minY        dd -0.5
maxy        dd 0.5
_dX     dd 0.00234375
_dY     dd 0.0025
inf     dd 1e7
brightness  dd 31.0
pi_2_256    dd 0.024543692606
pi_2_3      dd 2.094395102393
 
SetVisiblePage0:
        mov dx, 3dah
@@:     in  al, dx
        and al, 8
        jz  @b
        mov dx, 3d4h
        mov ax, 0c00h
        out dx, ax
        mov ax, 0d00h
        out dx, ax
        mov dx, 3dah
@@:     in  al, dx
        and al, 8
        jnz @b
        ret
 
ClearScreen:
        push    es
        push    di
        mov dx, 3c4h
        mov al, 2
        out dx, al
        mov dx, 3c5h
        mov al, 0fh
        out dx, al
        xor ax, ax
        push    0a000h
        pop es
        xor di, di
        mov cx, 320 * 200 / 2
        rep stosw
        pop di
        pop es
        ret
 
PutPixel:
        push    es
        push    bx
        mov bx, dx
        push    di
        mov di, ax
        push    dx
        push    ax
        mov al, 2
        mov dx, 3c4h
        out dx, al
        mov dx, 3c5h
        mov al, 0fh
        out dx, al
        pop ax
        pop dx
        mov ax, 320
        mul cx
        add di, ax
        push    0a000h
        pop es
        mov [es:di], bx
        pop di
        pop bx
        pop es
        ret

.486
cseg segment use16
assume cs:cseg, ds:cseg
org 100h
start:
    mov al, 13h
    int 10h
    push    0A000h
    pop ds
    shr si, 1       ; si=Y=128
Rou:
    mov di, -321    ; di=X=-321
    dec si      ; Y=di=X=-321
    dec si      ; Y=Y-1
Col:
    inc di      ; X=X+1
    je  Rou
    sub bp, bp      ; Re=0
    mov cl, 46      ; Color
Calc:
    lea bp, [bp+di+127] ; Re=Re+X+127
    add ax, si      ; Im=Im+Y
    push    ax      ; push Im
    imul    bp      ; Im=Im*Re
    sar ax, 5       ; Im=Im/32
    inc ax      ; Im=Im+1
    pop dx      ; Old Im
    imul    bp, bp      ; Re=Re*Re
    imul    dx, dx      ; Im=Im*Im
    jb  Paint
    sub bp, dx      ; Re=(Re*Re-Im*Im)
    sar bp, 6       ; Re=Re/64
    loop    Calc
Paint:
    mov [bx], cl
    sub ax, ax      ; Im=0
    inc bx
    jne Col
    int 16h     ; Key (Escape: al=27, ah=1)
    aad 232     ; al = 27+1*232 = 3, ah=0
    int 10h     ; Mode 3
    ret
cseg ends
end start