Построить график функции

;;; Для рисования графика функции можно использовать сплайн, проходящий через набор точек, определенных функцией.
;; Метод 'vla-AddSpline для создания сплайна.
 
;; 1. Определение алгебраической функции.
 
(defun FuncMath (x)
  ;; здесь будет определение функции
  (* x x)
)
 
;; 2. Создание списка точек для графика, через которые должен пройти сплайн:
 
(defun GeneratePts (xmin xmax step / x y points)
  ; xmin и xmax — начальное и конечное значения по оси X.
  ; step        — шаг вычисления значения [X Y].
 
  (setq x xmin)
  (while (<= x xmax)
    (cond
      ( (vl-catch-all-error-p (setq y (vl-catch-all-apply 'FuncMath (list x))))
        (prompt "\nПроверьте диапазон аргумента функции.")
        (vl-exit-with-error ""))
      (T 
        ;; Добавляем точку в список точек
        (setq points (cons (list x y 0.) points))
        ;; Переходим к следующему значению X
        (setq x (+ x step)))))
  (reverse points))
 
;; 3. Рисование графика сплайном.
 
(defun DrawGraph (points / ms rowPoints startTan endTan fitPoints)
  (vl-load-com)
  (setq ms (vla-get-ModelSpace (vla-get-ActiveDocument (vlax-get-acad-object))))
    (setq rowPoints (apply 'append points))  ; слияние точек в слошной ряд для массива
 
  ;; Создаем сплайн, проходящий через указанные точки
  (setq startTan (vlax-3d-point 0 0 0)
        endTan   (vlax-3d-point 0 0 0))
  (setq fitPoints (vlax-make-safearray vlax-vbDouble (cons 0 (1- (length rowPoints)))))
  (vlax-safearray-fill fitPoints rowPoints)
    
  ;; Глобальная переменная, для дальнейшего взятия производной.
  (setq *splineObj* (vla-AddSpline ms fitPoints startTan endTan))  ; метод создания сплайна
  (vla-put-Color *splineObj* 6)  ; фиолетовый
 
  (prompt "\nГрафик нарисован. ")
)
 
;; 4. Main routine.
 
(defun DrawFunctionGraph (xmin xmax step / points)
  ;; Генерируем точки для функции. В диапазоне от-до с шагом.
  (setq points (GeneratePts xmin xmax step))
  ;; Рисуем сплайн по этим точкам
  (DrawGraph points)
  (princ)
)
 
;; Вызов:
(DrawFunctionGraph -5 5 0.1)

(defun FuncMath (x / e y)
  (setq e (exp 1.0))  ; экспонента
  (+ x (expt e x))  ; пользовательская функция
)
 
(DrawFunctionGraph -10 3 0.1)

;;; Визуализация вектора касательной.
(defun DrawTangentVector (curveObj param / point-on-curve tangent-vector endPnt)
  ;; Вычисляем точку на кривой, соответствующую параметру
  (setq point-on-curve (vlax-curve-getPointAtParam curveObj param))
  ;; Вычисляем вектор касательной
  (setq tangent-vector (vlax-curve-getFirstDeriv curveObj param))
    (setq tangent-vector (mapcar '(lambda (n) (* n 5)) tangent-vector)) ; масштаб визуализации
 
  ;; Определяем конечную точку вектора как сумму начальной точки и вектора смещения
  ;; [сложение координат начальной точки и вектора смещения]
  (setq endPnt (mapcar '+ point-on-curve tangent-vector))
  ;; Создаем линию в пространстве модели для визуализации вектора касательной
  (vla-AddLine
      (vla-get-ModelSpace (vla-get-ActiveDocument (vlax-get-acad-object)))
      (vlax-3d-point point-on-curve)
      (vlax-3d-point endPnt))
  
  (prompt "\nВектор касательной визуализирован как линия.")
)
 
;; Main.
(defun C:VisualizeTangent (/ curveObj point param)
  ;; Выбор кривой
  (setq curveObj (vlax-ename->vla-object (car (entsel "\nВыберите кривую: "))))
  (setq point (getpoint "\nВыберите точку на кривой: ")
        param (vlax-curve-getParamAtPoint curveObj point))
  ;; Визуализация касательной
  (DrawTangentVector curveObj param)
  (princ))
 
;; Вызов:
(C:VisualizeTangent)
 
; => должна появиться линия касательной в выбраной точке.