Подстановка значения реквизита справочника в табличную часть документа

// Норма времени для выбранного значения
&НаСервереБезКонтекста
Функция ПолучитьНормуВремени(Ссылка)   
    Если Ссылка.ПометкаУдаления Тогда
        Возврат Неопределено;
    КонецЕсли;     
    Возврат Ссылка.НормаВремени;   
КонецФункции
 
// Получаем норму времени в реквизите табличной части
&НаКлиенте
Процедура ВыполненныеРаботыНаименованиеРаботыПриИзменении(Элемент)   
    ТД = Элементы.ВыполненныеРаботы.ТекущиеДанные; 
    ТД.НормаВремени = ПолучитьНормуВремени(ТД.НаименованиеРаботы);    
КонецПроцедуры

&НаСервере
Процедура СотрудникиСотрудникПриИзмененииНаСервере()   
    ТекДата = ТекущаяДатаСеанса();
    // Создаем массив сотрудников
    МассивСотрудников = Новый Массив;
    Для Каждого Строка Из Объект.Сотрудники Цикл
        Если ЗначениеЗаполнено(Строка.Сотрудник) Тогда
            МассивСотрудников.Добавить(Строка.Сотрудник);
        КонецЕсли;
    КонецЦикла;    
    Если МассивСотрудников.Количество() > 0 Тогда
        // Получаем необходимые данные из запроса
        Запрос = Новый Запрос;
        Запрос.Текст = 
            "ВЫБРАТЬ
            |   РесурсыЛокаций.Сотрудник КАК Сотрудник,
            |   РесурсыЛокаций.Должность КАК Должность,
            |   РесурсыЛокаций.Подразделение КАК Подразделение,
            |   РесурсыЛокаций.ГрафикРаботы КАК ГрафикРаботы
            |ИЗ
            |   РегистрСведений.РесурсыЛокаций.СрезПоследних(&ДатаСреза, ) КАК РесурсыЛокаций
            |ГДЕ
            |   РесурсыЛокаций.Сотрудник В(&Сотрудники)";       
        Запрос.УстановитьПараметр("ДатаСреза", ТекДата);
        Запрос.УстановитьПараметр("Сотрудники", МассивСотрудников); 
        Выборка = Запрос.Выполнить().Выбрать();
        ТаблицаДанных = Новый Соответствие;     
        Пока Выборка.Следующий() Цикл
            // Записываем данные в структуру
            ДанныеСтроки = Новый Структура("ГрафикРаботы, Должность, Подразделение", Выборка.ГрафикРаботы, Выборка.Должность, Выборка.Подразделение);
            ТаблицаДанных.Вставить(Выборка.Сотрудники, ДанныеСтроки);
        КонецЦикла;  
        // Подставляем значения в ТЧ документа
        Для Каждого ТекСтрока Из Объект.Сотрудники Цикл
            Если ЗначениеЗаполнено(ТекСтрока.Сотрудник) Тогда
                ТекДанные = ТаблицаДанных.Получить(ТекСтрока.Сотрудник);
                Если ТекДанные <> Неопределено Тогда
                    ТекСтрока.Должность = ТекДанные.Должность;
                    ТекСтрока.Подразделение = ТекДанные.Подразделение;
                    ТекСтрока.ГрафикРаботы = ТекДанные.ГрафикРаботы;
                КонецЕсли;            
            КонецЕсли;
        КонецЦикла;    
    КонецЕсли; 
КонецПроцедуры
 
// Вызываем процедуру на клиенте
&НаКлиенте
Процедура СотрудникиСотрудникПриИзменении(Элемент)   
    СотрудникиСотрудникПриИзмененииНаСервере();     
КонецПроцедуры