Создать архивы по 100 файлов

echo off
chcp 1251
 
SetLocal EnableExtensions EnableDelayedExpansion
 
set arcsize=100
set counter=0
set counter100=0
set files=0
 
for /f %%i in ('dir/a-d/b *.txt') do (set /a files+=1)
 
if %files% equ 0 (
    echo Нет файлов для архивации
    goto end
    )
 
set /p arcnum="Введите последний номер архива: "
    
:while
 
set /a arcnum+=1
set /a counter100-=%counter100%
 
for /f %%i in ('dir/a-d/b *.txt') do (
    if !counter! equ %files% (goto wend)
    if !counter100! equ %arcsize% (goto while)
    ARJ32.EXE m "DEFAULT_NAME_%arcnum%.ARJ" %%i > nul
    set /a counter+=1
    set /a counter100+=1
    )
 
:wend
 
echo Последний номер архива: %arcnum%
 
:end
 
set arcnum=
set counter100=
set counter=
set files=
 
pause

echo off
SetLocal EnableDelayedExpansion
 
for /f "delims=" %%i in ('dir/a-d/b *.txt') do (
set /a files+=1
rem команда упаковки
if "!files!"=="100" set files=
)

@echo off
setlocal enabledelayedexpansion
set "d_out=2"
if not exist "%d_out%" md "%d_out%"
for /f "delims=" %%a in ('dir /a-d /b') do set /a n+=1& set "m=00!n!"& copy "%%a" "%d_out%\!m:~-3!%%~xa"
pause>nul

@echo off&cls
SetLocal EnableExtensions
                :: %src% каталог, где лежат файлы, архивы также упадут в этот каталог
set "src=диск:\путь1\путь2"
if "%src:~-1%" equ "\" call set "src=%%src:~0,-1%%"
 
                :: %mult% мах кол-во файлов в 1-м архиве
set /a "mult=100"
                :: %arj_cnt%-1 мах количество архивов
set /a "arj_cnt=1000"
                :: %arj_name% префикс имени архива
set "arj_name=NAME_ARHIVE"
                :: %arj_cmd% команда для ARJ32
                :: a добавить файлы в архив
                :: m добавить файлы, ежели всё ОК - удалить файлы
set "arj_cmd=a"
 
if exist "%src%\%arj_name%*.arj" (
  echo:в каталоге '%src%' есть архивы по маске '%arj_name%*.arj'
  echo:может получиться непотребное
  echo:здесь можно чё-нить накодить для этого события, а я завершусь с ошибкой
  echo:
  pause
  exit /b 99
)
                                :: приведём %temp% к формату 8.3
 
for %%v in ("%temp%") do set "temp=%%~dpsv"&call set "temp=%%temp:~0,-1%%"
 
                :: %list% очередная порция файлов для упаковки
set "list=%temp%\file_list"
 
                :: на всякий случай переопределим %ARJ_SW%
set "ARJ_SW=-i -w%temp%"
 
>nul 2>nul del %list%
 
SetLocal EnableDelayedExpansion
  for /f "tokens=*" %%v in ('dir /a-d/b "%src%"^|find /i /v ".arj"') do (
    >>%list% (echo %%v)
    set /a cnt+=1
    if !cnt! == %mult% (
      set /a arj_cnt+=1
      call :packer !arj_cnt!||(>con echo:ошибка архивирования & >con pause & exit /b 1)
      set /a cnt=0
      >nul 2>nul del %list%
    )
  )
                :: пакуем остаток 
  if exist %list% (
      set /a arj_cnt+=1
      call :packer !arj_cnt!||(>con echo:ошибка архивирования & >con pause & exit /b 1)
      >nul 2>nul del %list%
  )
exit /b 0
_____________________________________________________________________________
 
:packer
SetLocal DisableDelayedExpansion
  set "t=%1"
  set "t=%t:~-3%"
  pushd %src%
  if exist "%arj_name%_%t%" (
    >con echo:оч.много файлов, кол-во архивов ^> '%arj_cnt%-1'
    >con pause
    exit /b 99
  )
  title '%arj_name%_%t%.arj' пакуем очередную пачку из %mult% файлов
  >con echo:'%arj_name%_%t%.arj' пакуем очередную пачку из %mult% файлов
  >nul arj32 %arj_cmd% -!@ "%arj_name%_%t%.arj" @%list%
  set "rc=%ERRORLEVEL%"
popd
exit /b %rc%