Проблема с переменной %path%

@Malysh-ok · Регистрация: 17.10.2013

Студворк — интернет-сервис помощи студентам

Батник Проверка.bat не работает у некоторых пользователей. Причем версия системы идентичная: Win7x64.
Рядом с батником папка bin, а в ней - файлы cecho_x86.exe и cecho_x64.exe.

Опытным путем установлено, что проблема в строке (т.е. если реализовать алгоритм без использования переопределения %PATH% - все работает):

Windows Batch file
1
SET PATH=%PATH%;"%~dp0\bin"

ВОПРОС: почему так происходит и как это побороть?

Текст батника:

Windows Batch file
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
@echo off
Setlocal EnableExtensions EnableDelayedExpansion
set clr=3f
color %clr%
chcp 866 > nul
mode con:cols=82 lines=41
 
cd "%~dp0"
IF EXIST "bin\" (
    SET PATH=%PATH%;"%~dp0\bin"
) else (
    echo.
    echo     Отсутствует папка 'bin' с необходимыми файлами^!
    echo.
    cecho     Закройте это окно или нажмите любую клавишу... 
    pause >nul
    exit 
)
attrib +h "bin" >nul
 
echo Содержимое ВРЕМЕННОЙ переменной Path:
cecho {3b}%PATH%{%clr%}{\n}{\n}
 
:: Получаем файл cecho.exe в зависимости от разрядности системы:
Set xOS=x64
If "%PROCESSOR_ARCHITECTURE%"=="x86" If Not Defined PROCESSOR_ARCHITEW6432 Set xOS=x86
rem echo %xOS% -- '%PATH%'
 
if "%xOS%"=="x86" (
    copy /y bin\cecho_x86.exe bin\cecho.exe >nul
) else (
    copy /y bin\cecho_x64.exe bin\cecho.exe >nul
)
 
echo Версия установленного ADB:
cecho {3b}{\n}
adb version
cecho {%clr%}{\n}
pause

@vavun · 04.06.2019, 20:59

Так, может, выбросить к чертям cecho и другие не необходимые бинарники ? Может даже вместе с bin ?

Сообщение от Malysh-ok

Windows Batch file
1
2
IF EXIST "bin\" (
    SET PATH=%PATH%;"%~dp0\bin"

Не совсем корректно.

Windows Batch file
if exist "bin\" (set "PATH=%PATH%;%~dp0bin")

Сообщение от Malysh-ok

:: Получаем файл cecho.exe в зависимости от разрядности системы: Set xOS=x64 If "%PROCESSOR_ARCHITECTURE%"=="x86" If Not Defined PROCESSOR_ARCHITEW6432 Set xOS=x86

А что получим, если запустим на windows x64 командную строку из syswow64, а не system32 ?
(Например при работе с x86 тотал командером запустится именно она)

А получим следующее

Code
1
2
C:\Windows\SysWOW64>echo %PROCESSOR_ARCHITECTURE%
x86

Вместо всех проверок (при условии выброшенного cecho) просто дабавить это

Windows Batch file
1
2
3
4
if exist %WINDIR%\sysnative\cmd.exe (
    %WINDIR%\sysnative\cmd.exe /c "%~dpnx0"
    exit /b
)

@Malysh-ok · 05.06.2019, 08:44 **[ТС]**

Сообщение от vavun

Так, может, выбросить к чертям cecho и другие не необходимые бинарники ? Может даже вместе с bin ?

В bin будут лежать другие необходимые проги.

Сообщение от vavun

А что получим, если запустим на windows x64 командную строку из syswow64, а не system32 ?
(Например при работе с x86 тотал командером запустится именно она)

Работает корректно (верно определяет версию СИСТЕМЫ) вне зависимости от версии cmd.

По существу, с применением %path% идей нет?

@vavun · 05.06.2019, 12:13

Сообщение от Malysh-ok

По существу, с применением %path% идей нет?

В самом начале моего сообщения.

Сообщение от Malysh-ok

Работает корректно (верно определяет версию СИСТЕМЫ) вне зависимости от версии cmd.

И еще кое-что:

Сообщение от Malysh-ok

Windows Batch file
cd "%~dp0"

Добавьте /d, иначе это будет срабатывать только в пределах диска C.

@Malysh-ok · 06.06.2019, 09:56 **[ТС]**

Про разрядность.
- Запускаем C:\Windows\SysWOW64\cmd.exe
- Убеждаемся в вашей правоте, касаемо %PROCESSOR_ARCHITECTURE% (но это еще не определение разрядности системы!)
- Запускаем Проверка.bat, убеждаемся, что разрядность определяется верно:

Слегка измененный код:

Windows Batch file
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
@echo off
Setlocal EnableExtensions EnableDelayedExpansion
set clr=3f
color %clr%
chcp 866 > nul
mode con:cols=82 lines=41
 
cd /d "%~dp0"
IF EXIST "bin\" (
    SET PATH=%PATH%;"%~dp0\bin"
) else (
    echo.
    echo     Отсутствует папка 'bin' с необходимыми файлами^!
    echo.
    cecho     Закройте это окно или нажмите любую клавишу... 
    pause >nul
    exit 
)
attrib +h "bin" >nul
 
:: Получаем файл cecho.exe в зависимости от разрядности системы:
Set xOS=x64
If "%PROCESSOR_ARCHITECTURE%"=="x86" If Not Defined PROCESSOR_ARCHITEW6432 Set xOS=x86
rem echo %xOS% -- '%PATH%'
 
if "%xOS%"=="x86" (
    copy /y bin\cecho_x86.exe bin\cecho.exe >nul
) else (
    copy /y bin\cecho_x64.exe bin\cecho.exe >nul
)
 
cecho Разрядность системы: {3b}%xOS%{%clr%}{\n}{\n}
 
echo Содержимое ВРЕМЕННОЙ переменной Path:
cecho {3b}%PATH%{%clr%}{\n}{\n}
 
echo Версия установленного ADB:
cecho {3b}{\n}
adb version
cecho {%clr%}{\n}
pause

Сообщение от vavun

Добавьте /d, иначе это будет срабатывать только в пределах диска C.

Это да, забыл...

П.С. Может Dragokas разъяснит проблему?..

@Malysh-ok · 11.06.2019, 08:38 **[ТС]**

Нашел ошибку сам, на удивление глупая: переменную внутри скобочной конструкции раскрывать не так: %PATH%, а так: !PATH!
В конечном итоге батник будет выглядеть так:

Windows Batch file
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
@echo off
Setlocal EnableExtensions EnableDelayedExpansion
set clr=3f
color %clr%
chcp 866 > nul
mode con:cols=82 lines=41
 
cd /d "%~dp0" 1>nul 2>nul
if not %errorlevel%==0 (
    color 0c
    echo.
    echo     Неизвестная ошибка; возможно вы пытаетесь работать с сетевой папкой.
    echo.
    echo     Закройте это окно или нажмите любую клавишу...
    pause >nul
    exit 
)
 
IF EXIST "bin\" (
    set "PATH=!PATH!;"%~dp0bin""
) else (
    echo.
    echo     Отсутствует папка 'bin' с необходимыми файлами^!
    echo.
    echo     Закройте это окно или нажмите любую клавишу... 
    pause >nul
    exit 
)
attrib +h "bin" 1>nul 2>nul
 
:: Получаем файл cecho.exe в зависимости от разрядности системы:
Set xOS=x64
If "%PROCESSOR_ARCHITECTURE%"=="x86" If Not Defined PROCESSOR_ARCHITEW6432 Set xOS=x86
rem echo %xOS% -- '%PATH%'
 
if "%xOS%"=="x86" (
    copy /y bin\cecho_x86.exe bin\cecho.exe >nul
) else (
    copy /y bin\cecho_x64.exe bin\cecho.exe >nul
)
if not %errorlevel%==0 (
    color 0c
    echo.
    echo     Похоже, что у вас недостаточно прав.
    echo     Запустите файл с правами администратора.
    echo.
    echo     Закройте это окно или нажмите любую клавишу... 
    pause >nul
    exit 
)
 
cecho Разрядность системы: {3b}%xOS%{%clr%}{\n}{\n}
 
echo Содержимое ВРЕМЕННОЙ переменной Path:
cecho {3b}%PATH%{%clr%}{\n}{\n}
 
echo Версия установленного ADB:
cecho {3b}{\n}
adb version
cecho {%clr%}{\n}
pause

Новые блоги и статьи Все статьи Все блоги /
SDL3 для Web (WebAssembly): Обработчик клика мыши в браузере ПК и касания экрана в браузере на мобильном устройстве 8Observer8 02.02.2026 Содержание блога Для начала пошагово создадим рабочий пример для подготовки к экспериментам в браузере ПК и в браузере мобильного устройства. Потом напишем обработчик клика мыши и обработчик. . .	Философия технологии iceja 01.02.2026 На мой взгляд у человека в технических проектах остается роль генерального директора. Все остальное нейронки делают уже лучше человека. Они не могут нести предпринимательские риски, не могут. . .	SDL3 для Web (WebAssembly): Вывод текста со шрифтом TTF с помощью SDL3_ttf 8Observer8 01.02.2026 Содержание блога В этой пошаговой инструкции создадим с нуля веб-приложение, которое выводит текст в окне браузера. Запустим на Android на локальном сервере. Загрузим Release на бесплатный. . .	SDL3 для Web (WebAssembly): Сборка C/C++ проекта из консоли 8Observer8 30.01.2026 Содержание блога Если вы откроете примеры для начинающих на официальном репозитории SDL3 в папке: examples, то вы увидите, что все примеры используют следующие четыре обязательные функции, а. . .
SDL3 для Web (WebAssembly): Установка Emscripten SDK (emsdk) и CMake для сборки C и C++ приложений в Wasm 8Observer8 30.01.2026 Содержание блога Для того чтобы скачать Emscripten SDK (emsdk) необходимо сначало скачать и уставить Git: Install for Windows. Следуйте стандартной процедуре установки Git через установщик. . . .	SDL3 для Android: Подключение Box2D v3, физика и отрисовка коллайдеров 8Observer8 29.01.2026 Содержание блога Box2D - это библиотека для 2D физики для анимаций и игр. С её помощью можно определять были ли коллизии между конкретными объектами. Версия v3 была полностью переписана на Си, в. . .	Инструменты COM: Сохранение данный из VARIANT в файл и загрузка из файла в VARIANT bedvit 28.01.2026 Сохранение базовых типов COM и массивов (одномерных или двухмерных) любой вложенности (деревья) в файл, с возможностью выбора алгоритмов сжатия и шифрования. Часть библиотеки BedvitCOM Использованы. . .	SDL3 для Android: Загрузка PNG с альфа-каналом с помощью SDL_LoadPNG (без SDL3_image) 8Observer8 28.01.2026 Содержание блога SDL3 имеет собственные средства для загрузки и отображения PNG-файлов с альфа-каналом и базовой работы с ними. В этой инструкции используется функция SDL_LoadPNG(), которая. . .