типа WHICH .)

@ft4l · Регистрация: 08.02.2013

Студворк — интернет-сервис помощи студентам

есть такой WHICH.BAT

Windows Batch file
1
@ECHO.%~$PATH:1

...

<-- d:\XP\USR -->

  \-\WHICH SVN.EXE

d:\XP\USR\SVN\bin\svn.exe



<-- d:\XP\USR -->

  \-\WHICH SVN

d:\XP\USR\SVN



<-- d:\XP\USR -->

  \-\WHICH MORE





<-- d:\XP\USR -->

  \-\WHICH MORE.COM

C:\WINDOWS\system32\more.com

Посоветуйте как более менее грамотно прикрутить у этому

  FOR %I IN (%PATHEXT%) DO @ECHO %I

.COM

.EXE

.BAT

.CMD

.VBS

.VBE

.JS

.JSE

.WSF

.WSH

.PSC1

Добавлено через 1 час 20 минут
насколько понял, поиск исполняемого файла примерно так происходит

Windows Batch file
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
 
SET "X="
FOR %%Z IN (.;%PATH%) DO (
    FOR %%Y IN (%PATHEXT%) DO (
        SET "X=%%Z\%~1%%Y"
        IF EXIST "!X!" GOTO ENDLOOP
    )
    SET "X="
)
:ENDLOOP
ECHO.%X%
 
ENDLOCAL

... если вложенность циклов не наоборот .))
но с %~$PATH:1 уже + то что хотя-бы регистр символов "как есть" ))

Добавлено через 40 минут
Вроде получилось так )

Windows Batch file
1
2
3
4
5
6
7
8
9
10
@echo off
SETLOCAL
ECHO.
SET "X="
    FOR %%X IN (%PATHEXT%) DO (
        FOR %%Z IN ("%~1%%X") DO IF NOT "%%~$PATH:Z"=="" ECHO.%%~$PATH:Z && GOTO ENDLOOP
    )
:ENDLOOP
IF EXIST "%~$PATH:1\" ECHO.%~$PATH:1\
ENDLOCAL

  \-\WHICH MORE



C:\WINDOWS\system32\more.com

\

Добавлено через 24 минуты
НЕБОЛЬШОЙ БАГ

WHICH.BAT :

Windows Batch file
1
2
3
4
5
6
7
@echo off
ECHO.
    FOR %%X IN (%PATHEXT%) DO (
        FOR %%Z IN ("%~1%%X") DO IF NOT "%%~$PATH:Z"=="" ECHO.%%~$PATH:Z && GOTO ENDLOOP
    )
:ENDLOOP
IF EXIST "%~$PATH:1" ECHO.%~f$PATH:1

в текущем каталоге

d:\XP\USR\SVN\

d:\XP\USR\e.bat

d:\XP\USR\e.bat.bat

Показывает оба файла

<-- d:\XP\USR -->

  \-\WHICH e.bat



d:\XP\USR\e.bat.bat

d:\XP\USR\e.bat

Выполняется файл с одинарным расширением
... похоже за файлом с двойным расширением может быть скрыт исполняемый

@ft4l · 26.12.2024, 11:51 **[ТС]**

Остановился пока,) на таком варианте:

Windows Batch file
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
@echo off
SETLOCAL
 
IF "%~1"=="" GOTO HELP
ECHO.%~1| find /I "?"
IF NOT "%ERRORLEVEL%"=="1" GOTO HELP
 
IF /I "%~1" EQU "DLL" (
    SET "PATHEXT=.DLL"
    SHIFT
)
:: SET PATHEXT
ECHO.
 
FOR %%D IN ("%CD%" "%PATH:;=" "%") DO (
    SET "PATH=%%~D"
    FOR %%Z IN ("%~1") DO IF NOT "%%~f$PATH:Z"=="" ECHO. %%~f$PATH:Z
    FOR %%X IN (%PATHEXT%) DO (
        FOR %%Z IN ("%~1%%X") DO IF NOT "%%~f$PATH:Z"=="" ECHO. %%~f$PATH:Z
    )
)
ENDLOCAL
EXIT /B
 
:HELP
ECHO. %~nx0 searches any executable in the workdir and PATH-dirs (optionally dll)
ECHO. Usage:
ECHO.   %~n0 [DLL] FILENAME - search for
ECHO.   %~n0 [?]        - this help
ECHO.
ENDLOCAL
EXIT /B

... был баг с пробелами и скобками в PATH

D:\>\-\which /?

/?

 WHICH.BAT searches any executable in the workdir and PATH-dirs (optionally searches dll)

 Usage:

        WHICH [DLL] FILENAME    - search for

        WHICH [?]               - this help



D:\>\-\which cvtres



 C:\MsVS10\VC\bin\cvtres.exe

 C:\WINDOWS\Microsoft.NET\Framework\v4.0.30319\cvtres.exe



D:\>\-\which dll sqlite3



 D:\XP\USR\SVN\bin\sqlite3.dll

 d:\XP\site\bin\sqlite3.dll



D:\>\-\which svn



 D:\XP\USR\SVN\bin\svn.exe

Но ещё троит с каталогами

D:\>\-\which system32



 C:\WINDOWS\system32

 C:\WINDOWS\system32



D:\>\-\which bin

@siberian-man · 27.12.2024, 16:55

which хорошая тулза, но она (в юниксах по умолчанию) смотрит только в PATH. У ней есть несколько опций, чтобы посмотреть в настройки шелла (типа alias | /usr/bin/which --read-alias).

В винде (не помню, начиная с какой версии) уже есть команда where, которая выполняет почти тоже самое. Но мы все любим иксы и пишем свои велосипеды, потому что команда where реализована как-то по своему. Велосипеды примерно такие:

Windows Batch file
1
2
3
4
5
6
for %%x in ( "%PATHEXT:;=" "%" "" ) do ^
for %%p in ( "." "%PATH:;=" "%" ) do ^
if exist "%%~fp\%~1%%~x" (
    echo:%%~p\%~1%%~x
    if not defined which_find_all goto :which_arg_continue
)

Здесь идет перебор по всем расширениям (включая пустое, например, если бы мы указали имя с рисширением), по всем путям в PATH (при чем начинаем искать с текущего каталога, то есть ".", также как это делает cmd.exe). Переменная which_find_all определяется где-то в начале с помощью опции -a и управляет поиском, типа искать ли все возможные варианты или остановиться на первом найденном.

Добавлено через 11 минут
Забыл сказать. В cmd.exe последовательность поиска и (соответственно) выполнения команд следующая:

1. макросы doskey (можно узнать по команде doskey /macros)
2. встроенные команды (можно узнать только перебором предопределенного списка)
3. внешние команды (бинарники, скрипты - последовательность определяется переменными PATH и PATHEXT)

Добавлено через 22 минуты
Вот, кстати, есть одна странность (скорее всего баг). Если создать файл (например, echo.bat), то в следующем примере cmd.exe выполнит именно его:

Windows Batch file
1
2
3
4
5
6
7
8
C:\>type \Windows\System32\echo.bat
@echo ha-ha-ha
 
C:\>echo
Режим вывода команд на экран (ECHO) включен.
 
C:\>call echo
ha-ha-ha

@ft4l · 27.12.2024, 18:03 **[ТС]**

Сообщение от siberian-man

System32\echo.bat

В рабочем каталоге бывало батники типа perl.bat поподались
... и долго не мог понять... почему однострочники ничего не выводят ))
вроде у кого-то видел файл.exe текстовой ... типа awk.exe в котором одпа строчка с какими-то <!> и gawk.exe ))
... последнее что подтолкнуло это

d:\C\10-vc\SDKv7.0A\bin\MC.Exe

d:\P\UTIL\MC\mc.exe

"Windows Message Compiler" и "GNU Midnight Commander" )

легче впечатывать which и копипастить второе
... пачками в PATH добавлять во всевозможных вариантах у меня давно отработано ))

Добавлено через 20 минут

>  \-\which mc



 D:\C\32_DDK\bin\x86\mc.exe

 D:\C\32xPSDK_2003r2\Bin\MC.Exe

 D:\P\UTIL\MC\mc.exe

Добавлено через 13 минут

Сообщение от siberian-man

doskey /macros

тож неслабо )

Code
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
:: D:\-
>  doskey /macros:all
[cmd.exe]
    SRC=cd %BASEDIR%\src\$1
    INC=cd %BASEDIR%\inc
    HELP=cd %BASEDIR%\help
    DDKLIB=cd %DDK_LIB_DEST%
    DDK=cd %BASEDIR%\$1
    BIN=cd %BASEDIR%\bin
    WIN1394=cd %BASEDIR%\src\wdm\1394\ui\win1394
    WATERMARK=cd %BASEDIR%\src\print\oemdll\watermark\wmarkps
    USBVIEW=cd %BASEDIR%\src\wdm\usb\usbview
    USBINTEL=cd %BASEDIR%\src\wdm\videocap\usbintel\sys
    USBFILTER=cd %BASEDIR%\src\wdm\usb\filter
    USBCAMD=echo Sample no longer in the DDK.
    UART=echo Sample no longer in the DDK.
    TESTCAP=cd %BASEDIR%\src\wdm\videocap\testcap
    TAPE=cd %BASEDIR%\src\storage\class\tape
    STDUNK=cd %BASEDIR%\src\wdm\audio\stdunk
    SONYMC=cd %BASEDIR%\src\storage\changers\drivers\sonymc
    SERIAL=cd %BASEDIR%\src\kernel\serial
    SERENUM=cd %BASEDIR%\src\kernel\serenum
    SCSCSCAN=echo Sample no longer in the DDK.
    SB16=cd %BASEDIR%\src\wdm\audio\sb16
    SAMPUSD=echo Sample no longer in the DDK.
    SAMPCPL=echo Sample no longer in the DDK.
    S3VIRGE=echo Sample no longer in the DDK.
    S3=echo Sample no longer in the DDK.
    QUICK=cd %BASEDIR%\src\ime\cht\QUICK
    QIC157=cd %BASEDIR%\src\storage\tape\qic157
    PSCR=cd %BASEDIR%\src\smartcrd\pscr
    PP=cd %BASEDIR%\src\print\pp
    PNPPOWER=echo Sample no longer in the DDK.
    PJLMON=cd %BASEDIR%\src\print\monitors\pjlmon
    PHON=cd %BASEDIR%\src\ime\cht\PHON
    PASTHRU=cd %BASEDIR%\src\network\ndis\passthru
    PARPORT=cd %BASEDIR%\src\kernel\parport
    PARCLASS=echo Sample no longer in the DDK.
    OEMUNI=cd %BASEDIR%\src\print\oemdll\oemuni
    OEMUI=cd %BASEDIR%\src\print\oemdll\oemui
    OEMPS=cd %BASEDIR%\src\print\oemdll\oemps
    NSMMC=cd %BASEDIR%\src\storage\changers\drivers\nsmmc
    NSCIRDA=cd %BASEDIR%\src\network\irda\miniport\nscirda
    NETFILTER=echo Sample no longer in the DDK.
    NETCFG=cd %BASEDIR%\src\network\config\netcfg
    NE3200=echo Sample no longer in the DDK.
    NE2000=echo Sample no longer in the DDK.
    N9I3D=echo Sample no longer in the DDK.
    MPU401=cd %BASEDIR%\src\wdm\audio\mpu401
    MODE3FLPY=echo Sample no longer in the DDK.
    MODE3FDC2=echo Sample no longer in the DDK.
    MODE3FD=echo Sample no longer in the DDK.
    MINIQIC=cd %BASEDIR%\src\storage\tape\miniqic
    MINIPORTS3=echo Sample no longer in the DDK.
    LUXTS=echo Sample no longer in the DDK.
    LOCALUI=cd %BASEDIR%\src\print\monitors\localui
    LOCALMON=cd %BASEDIR%\src\print\monitors\localmon
    LANCE=echo Sample no longer in the DDK.
    KRNLDRVR=cd %BASEDIR%\src\vdd\dosioctl\krnldrvr
    JPNU=cd %BASEDIR%\src\ime\jpn\u
    JPNM=cd %BASEDIR%\src\ime\jpn\m
    JPNA=cd %BASEDIR%\src\ime\jpn\a
    ISOUSB=cd %BASEDIR%\src\wdm\usb\isousb
    IRCLASS=cd %BASEDIR%\src\network\irda\dll\irclass
    IOCTLVDD=cd %BASEDIR%\src\vdd\dosioctl\ioctlvdd
    INITIO=cd %BASEDIR%\src\storage\miniport\initio
    IBMTOK2I=echo Sample no longer in the DDK.
    HPSJUSD=echo Sample no longer in the DDK.
    HPMC=cd %BASEDIR%\src\storage\changers\drivers\hpmc
    HIDGAME=cd %BASEDIR%\src\wdm\hid\hidgame
    HCLIENT=cd %BASEDIR%\src\wdm\hid\hclient
    GENPRINT=cd %BASEDIR%\src\print\genprint
    FRAMEBUF=cd %BASEDIR%\src\video\displays\framebuf
    FMSYNTH=cd %BASEDIR%\src\wdm\audio\fmsynth
    FLPYDISK=cd %BASEDIR%\src\storage\fdc\flpydisk
    FDC=cd %BASEDIR%\src\storage\fdc\fdc
    EXABYTE2=cd %BASEDIR%\src\storage\tape\exabyte2
    EXABYTE1=cd %BASEDIR%\src\storage\tape\exabyte1
    EXABYTE=cd %BASEDIR%\src\storage\changers\drivers\exabyte
    EUDC=cd %BASEDIR%\src\ime\cht\EUDC
    euELMSMC=cd %BASEDIR%\src\storage\changers\drivers\elmsmc
    E100BEX=cd %BASEDIR%\src\network\ndis\e100bex
    DVDTS=echo Sample no longer in the DDK.
    DUMMYDMA=echo Sample no longer in the DDK.
    DOSDV=echo Sample no longer in the DDK.
    DLTTAPE=cd %BASEDIR%\src\storage\tape\dlttape
    DISKPERF=cd %BASEDIR%\src\storage\filters\diskperf
    DISK=cd %BASEDIR%\src\storage\class\disk
    DDMSC=cd %BASEDIR%\src\storage\changers\drivers\ddsmc
    COMVDD=cd %BASEDIR%\src\vdd\com_vdd
    CLASSPNP=cd %BASEDIR%\src\storage\class\classpnp
    CLASS=cd %BASEDIR%\src\storage\changers\class
    CHS=cd %BASEDIR%\src\ime\chs
    CHAJEI=cd %BASEDIR%\src\ime\cht\CHAJEI
    CDROM=cd %BASEDIR%\src\storage\class\cdrom
    CDAUDIO=cd %BASEDIR%\src\storage\filters\cdaudio
    BULLTLP3=cd %BASEDIR%\src\smartcrd\bulltlp3
    BULKUSB=cd %BASEDIR%\src\wdm\usb\bulkusb
    BLASTER=cd %BASEDIR%\src\network\irda\exe\blaster
    APP=echo Sample no longer in the DDK.
    AIC5900=echo Sample no longer in the DDK.
    AGA154X=cd %BASEDIR%\src\storage\miniport\aha154x
    ADICSC=cd %BASEDIR%\src\storage\changers\drivers\adicsc
    4MMDAT=cd %BASEDIR%\src\storage\tape\4mmdat
    1394DIAG=cd %BASEDIR%\src\wdm\1394\driver\1394diag
    1394DCAM=cd %BASEDIR%\src\wdm\videocap\1394dcam
    1394API=cd %BASEDIR%\src\wdm\1394\dll\1394api
    up=if "$1"=="" (cd ..) else (for /L %i in (1,1,$1) do cd ..)
    MK=nmake /c $*
    MAKE=nmake /c $*
    COFF=link $*
    LINK32=link $*
    WINDIR=cd %windir% $T %homedrive%
    VIEW=net view \\$*
    QF=format a: /q /u /v:""
    NUSE=net use $* /d
    USE=net use $*
    BCZ=build -cZMg $*
    BZ=build -ZPg $*
    BZZ=build -ZPg $*
    BLD=build -cfeg $*
    ....=cd ..\..\..\$*
    ...=cd ..\..\$*
    ..=cd ..\$*
 
 
:: D:\-
>  bcz /?
BUILD: Adding /Y to COPYCMD so xcopy ops won't hang.
BUILD: Using 2 child processes

volodin661 · 27.12.2024, 18:44

Сообщение от siberian-man

Вот, кстати, есть одна странность (скорее всего баг). Если создать файл (например, echo.bat), то в следующем примере cmd.exe выполнит именно его

это не баг, а фича; сначала идёт поиск в текущей директории и только потом в PATH

@nekit270 · 27.12.2024, 18:46

Сообщение от volodin661

это не баг, а фича; сначала идёт поиск в текущей директории и только потом в PATH

вот только echo - не бинарник где-нибудь в System32, а встроенная команда.

volodin661 · 27.12.2024, 19:58

встроенные команды интерпретатора ничем не отличаются от исполняемых файлов, если речь идёт о порядке исполнения.

есть какие-то исторические предпочтения по порядку исполнения, базирующиеся на именах расширений
( завсегда сначала .COM, потом .EXE) вне зависимости от их расположения в PATHEXT.

но это не точно. память может и подводит. эксперимент проводить не буду.

Добавлено через 56 минут
---

@siberian-man · 30.12.2024, 10:58

Сообщение от volodin661

это не баг, а фича; сначала идёт поиск в текущей директории и только потом в PATH

смею оспорить ваше мнение )))

В начале идет поиск по внутренним командам, потом - поиск в текущем каталоге, потом в PATH.

volodin661 · 30.12.2024, 16:34

siberian-man, да ?
может и так, проверить не смогу, виндуса под руками нет.
и мотивации нет.
эх.

@ft4l · 31.12.2024, 06:58 **[ТС]**

Сообщение от volodin661

не баг, а фича

Так-то заманчиво тоже ,) иметь возможность переопределить ECHO ,например. Но мб черевато...
... Не как то, что типа проект такой . А так, чисто для вариантов ,) такой ещё which

Windows Batch file
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
@echo off
SETLOCAL
 
IF "%~1"=="" GOTO HELP
ECHO.%~1| (find /I "?") && GOTO HELP
::IF NOT "%ERRORLEVEL%"=="1"
 
:: macros if exists
FOR /F "TOKENS=1,* DELIMS==" %%N IN ('doskey /macros') DO IF /I "%%N" EQU "%~1" ECHO. macros: %%N = %%O
 
IF /I "%~1" EQU "DLL" (
    SET "PATHEXT=.DLL"
    SHIFT
)
:: SET PATHEXT
ECHO.
ECHO.%~1| (find.EXE /I "*") && (
    CALL :ASTERIX "%~1"
    GOTO ENDBAT
)
 
FOR %%D IN ("%CD%" "%PATH:;=" "%") DO (
    SET "PATH=%%~D"
    @rem FOR %%Z IN ("%~1") DO IF NOT "%%~f$PATH:Z"=="" ECHO. %%~f$PATH:Z
    FOR %%X IN (%PATHEXT%) DO (
        FOR %%Z IN ("%~1%%X") DO IF NOT "%%~f$PATH:Z"=="" ECHO. %%~f$PATH:Z
    )
)
ENDLOCAL
:ENDBAT
EXIT /B
 
:ASTERIX
FOR %%D IN ("%CD%" "%PATH:;=" "%") DO (
    FOR %%X IN (%PATHEXT%) DO (
        FOR %%F IN (%%D\%~1%%X) DO ECHO. %%~fF
  )
)
ECHO.
EXIT /B
 
:HELP
ECHO. %~nx0 searches any executable in the workdir and PATH-dirs (optionally searches dll)
ECHO. Usage:
ECHO.   %~n0 [DLL] FILENAME - search for
ECHO.   %~n0 [?]        - this help
ECHO.
ECHO.... optionally can use FILENAME with '*' (ASTERIX) 
ECHO.
ENDLOCAL
EXIT /B

Кликните здесь для просмотра всего текста

\-\m.bat

Windows Batch file
1
2
3
4
5
6
7
8
@ECHO OFF
set "__X="
IF NOT "%~1"=="" set "__X=/exename=%~1"
SET "_D__=%~d0" 
SET "PROMPT=%%   $P$_%% $S"
doskey /insert %__X% /macrofile=%~dpn0.mac
doskey /macros:all
set "__X="

\-\m.mac

Windows Batch file
1
2
3
4
5
6
7
8
9
10
11
12
13
14
..    = cd ..
...   = cd ..\..
....  = cd ..\..\..
.mc   = %_D__%\P\UTIL\MC\mc.exe $*
.mced = %_D__%\P\UTIL\MC\mcedit.exe $*
ee    = %_D__%\-\e.bat $*
np    = %_D__%\P\EDIT\npp78\notepad++.exe $*
pl    = %_D__%\-\e.bat   vc plx $*
pl.   = %_D__%\-\e.bat 1 vc plx $*
q     = exit
vim   = %_D__%\P\EDIT\vim\vim.exe $*
w     = %_D__%\-\WHICH.BAT $*
which = %_D__%\-\WHICH.BAT $*
wsm   = %_D__%\XP\WSM.exe  $*

Bash
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
Path=C:\WINDOWS\system32;C:\WINDOWS;C:\WINDOWS\System32\Wbem;C:\WINDOWS\system32\WindowsPo
werShell\v1.0
PATHEXT=.COM;.EXE;.BAT;.CMD;.VBS;.VBE;.JS;.JSE;.WSF;.WSH;.PSC1
 
D:\XP\site\ssl>/-/m
[cmd.exe]
    wsm=%_D__%\XP\WSM.exe  $*
    which=%_D__%\-\WHICH.BAT $*
    w=%_D__%\-\WHICH.BAT $*
    vim=%_D__%\P\EDIT\vim\vim.exe $*
    q=exit
    pl.=%_D__%\-\e.bat 1 vc plx $*
    pl=%_D__%\-\e.bat   vc plx $*
    np=%_D__%\P\EDIT\npp78\notepad++.exe $*
    ee=%_D__%\-\e.bat $*
    .mced=%_D__%\P\UTIL\MC\mcedit.exe $*
    .mc=%_D__%\P\UTIL\MC\mc.exe $*
    ....=cd ..\..\..
    ...=cd ..\..
    ..=cd ..
 
 
%   D:\XP\site\ssl
%  pl
Setting environment for using Microsoft Visual Studio 2010 x86 tools.
 [MsVS10]:      sets added.
 [pl]:  sets added.
 
%   D:\XP\site\ssl
%  which ..
 macros: .. = cd ..
 
 
%   D:\XP\site\ssl
%  which dll *lib*
 
*lib*
 D:\XP\site\bin\libapr-1.dll
 D:\XP\site\bin\libaprutil-1.dll
 ...
 D:\XP\site\bin\zlib1.dll
 C:\WINDOWS\Microsoft.NET\Framework\v4.0.30319\InstallUtilLib.dll
 C:\WINDOWS\Microsoft.NET\Framework\v4.0.30319\mscorlib.dll
 ...
 C:\WINDOWS\system32\vccorlib140.dll
 
 
%   D:\XP\site\ssl
%  which lib*
 
lib*
 D:\XP\bin\libnetcfg.bat
 C:\MsVS10\VC\bin\lib.exe
 
%   D:\XP\site\ssl
%  which *perl
 
*perl
 D:\XP\bin\perl.exe
 D:\XP\bin\wperl.exe
 D:\XP\bin\cpanp-run-perl.bat
 D:\XP\bin\runperl.bat
 
 
%   D:\XP\site\ssl
%  which perl
 
 D:\XP\bin\perl.exe

Новые блоги и статьи Все статьи Все блоги /
SDL3 для Web (WebAssembly): Реализация движения на Box2D v3 - трение и коллизии с повёрнутыми стенами 8Observer8 20.02.2026 Содержание блога Box2D позволяет легко создать главного героя, который не проходит сквозь стены и перемещается с заданным трением о препятствия, которые можно располагать под углом, как верхнее. . .	Конвертировать закладки radiotray-ng в m3u-плейлист damix 19.02.2026 Это можно сделать скриптом для PowerShell. Использование . \СonvertRadiotrayToM3U. ps1 <path_to_bookmarks. json> Рядом с файлом bookmarks. json появится файл bookmarks. m3u с результатом. # Check if. . .	Семь CDC на одном интерфейсе: 5 U[S]ARTов, 1 CAN и 1 SSI Eddy_Em 18.02.2026 Постепенно допиливаю свою "многоинтерфейсную плату". Выглядит вот так: https:/ / www. cyberforum. ru/ blog_attachment. php?attachmentid=11617&stc=1&d=1771445347 Основана на STM32F303RBT6. На борту пять. . .	Камера Toupcam IUA500KMA Eddy_Em 12.02.2026 Т. к. у всяких "хикроботов" слишком уж мелкий пиксель, для подсмотра в ESPriF они вообще плохо годятся: уже 14 величину можно рассмотреть еле-еле лишь на экспозициях под 3 секунды (а то и больше),. . .
И ясному Солнцу zbw 12.02.2026 И ясному Солнцу, и светлой Луне. В мире покоя нет и люди не могут жить в тишине. А жить им немного лет.	«Знание-Сила» zbw 12.02.2026 «Знание-Сила» «Время-Деньги» «Деньги -Пуля»	SDL3 для Web (WebAssembly): Подключение Box2D v3, физика и отрисовка коллайдеров 8Observer8 12.02.2026 Содержание блога Box2D - это библиотека для 2D физики для анимаций и игр. С её помощью можно определять были ли коллизии между конкретными объектами и вызывать обработчики событий столкновения. . . .	SDL3 для Web (WebAssembly): Загрузка PNG с прозрачным фоном с помощью SDL_LoadPNG (без SDL3_image) 8Observer8 11.02.2026 Содержание блога Библиотека SDL3 содержит встроенные инструменты для базовой работы с изображениями - без использования библиотеки SDL3_image. Пошагово создадим проект для загрузки изображения. . .

volodin661 6688 / 2279 / 348 Регистрация: 10.12.2013 Сообщений: 7,890
	27.12.2024, 19:58
	встроенные команды интерпретатора ничем не отличаются от исполняемых файлов, если речь идёт о порядке исполнения. есть какие-то исторические предпочтения по порядку исполнения, базирующиеся на именах расширений ( завсегда сначала .COM, потом .EXE) вне зависимости от их расположения в PATHEXT. но это не точно. память может и подводит. эксперимент проводить не буду. Добавлено через 56 минут --- 0

volodin661 6688 / 2279 / 348 Регистрация: 10.12.2013 Сообщений: 7,890
	30.12.2024, 16:34
	siberian-man, да ? может и так, проверить не смогу, виндуса под руками нет. и мотивации нет. эх. 0

типа WHICH .)

Решение