Нужен исходный код функции sinh() и cosh() из библиотеки math.h

        include RULES.ASI
        include _MATH.INC
 
Header@
 
Data_Seg@
 
ExtSym@         _huge_dble, qword, cdecl
HUGE_VAL        equ     _huge_dble@
 
Data_EndS@
 
Code_Seg@
 
Func@   sinh, _EXPFUNC, _RTLENTRY, <double x>
Locals@ <double temp>
 
        Link@   ebx
 
        FLD1
        mov     ax, 7FFFh
        FCHS                    ; TOS = -1.0, used in FSCALE later
        mov     dx, x [6]
        and     ax, dx          ; select exponent and most signif. bits
 
        FLD     x.double
        cmp     ax, 4086h
        jnb     sinh_tooBig     ; exp (+-710.475) is the limit
 
        FABS
        cmp     ax, 3FD6h
        jb      sinh_small
 
sinh_justFits:
        f87     Exp
 
        FLD1
        FDIV    st, st(1)       ; Exp (-x)
        FSUBP   st(1), st
        FSCALE                  ; sinh (x) = (exp(x) - exp(-x)) / 2
 
sinh_end:
        fstp_st1                ; discard the -1
 
; change sign if original argument was negative
 
        test    dh, 80h
        jz      sinh_end2
        FCHS
sinh_end2:
        Unlink@ ebx
        Return@
 
sinh_tooBig:
        ja      sinh_over
        cmp     W0 (x [4]), 33CEh
        jb      sinh_justFits
 
sinh_over:
        FSTP    ST(0)                   ; discard ST and ST(1)
        FSTP    ST(0)
 
;       return  __matherr (OVERFLOW, "sinh", &x, NULL,
;                                                (_DX & 0x8000) ? - HUGE_VAL : HUGE_VAL);
 
        FLD     HUGE_VAL.double
        test    dh, 80H
        jz      sinh_temp
        FCHS
sinh_temp:
        FSTP    temp.double
 
        matherr OVERFLOW, sinh, x, NULL, temp
        jmp     sinh_end2
 
sinh_small:
        cmp     ax, 3DE0h
        jb      sinh_end                ; x tiny, return x
 
        FLDL2E
        FMUL
        F2XM1
; TOS = y = exp(x) - 1
        FLD1
        FADD    st(0),st(1)
; stack = 1+y,y,-1
        FDIVR   st(0),st(1)
        FADD
        FSCALE
        jmp     sinh_end;
 
EndFunc@ sinh
 
Code_EndS@
        end

        include RULES.ASI
        include _MATH.INC
 
Header@
 
Data_Seg@
 
ExtSym@         _huge_dble, qword, cdecl
HUGE_VAL        equ     _huge_dble@
 
Data_EndS@
Code_Seg@
Func@   cosh, _EXPFUNC, _RTLENTRY, <double x>
 
        Link@   ebx
 
        FLD1
        mov     ax, 7FFFh
        FCHS                    ; TOS = -1.0
        and     ax, x [6]       ; select exponent and most signif. bits
 
        FLD     DOUBLE (x)
        cmp     ax, 4086h
        jnb     cosh_tooBig     ; exp (+-710.475) considered too large
        cmp     ax, 3F20h
        jb      cosh_tiny
cosh_justFits:
 
        f87     Exp
 
        FLD1
        FDIV    st, st(1)       ; Exp (-x)
        FADDP   st(1), st
        FSCALE                  ; cosh (x) = (exp(x) + exp(-x)) / 2
        fstp_st1
 
cosh_end:
        Unlink@ ebx
        Return@
 
cosh_tooBig:
        ja      cosh_over
        cmp     W0 (x [4]), 033CEh
        jb      cosh_justFits
 
cosh_over:
 
        FSTP    ST(0)                   ; pop two items off the stack
        FSTP    ST(0)
 
;       return __matherr (OVERFLOW, "cosh", &x, NULL, HUGE_VAL);
 
        matherr OVERFLOW, cosh, x, NULL, HUGE_VAL
        jmp     short   cosh_end
 
;  cosh is more accurately calculated by the polynomial
;
;        (1 + x^2/2)
;
;  when x is tiny (|x| < 2^-13).
 
cosh_tiny:
        FMUL    ST(0), ST(0)
        FSCALE                  ; divide by 2
        FSUBRP  ST(1), ST(0)    ; +1 == - (-1)
        jmp     short   cosh_end
 
EndFunc@ cosh
Code_EndS@
        end