перевод с Delphi

{МНК со степенным базисом}
procedure TForm1.MNK1Click(Sender: TObject);
type matrix=array[0..100,0..100] of real;
     vector=array [0..100] of real; {Нумеруем точки с нуля}
var n,m,k,i:integer;
    x,f,c:vector;
    a:matrix;
    x0,x9,h,x1:real;
    t:cardinal;
 
procedure InputData(n:integer; var x,f:vector); {Ввод исходных данных}
var i:integer;
begin
 for i:=0 to n do begin
  x[i]:=StrToFloat(StringGrid1.Cells[0,i+1]);
  f[i]:=StrToFloat(StringGrid1.Cells[1,i+1]);
 end;
end;
 
function ex (a:real; n:integer):real;
 {Показательная функция для формирования матрицы Грама}
var i:integer;
    e:real;
begin
 e:=1;
 for i:=1 to n do e:=e*a;
 ex:=e;
end;
 
procedure Gram (n,m:integer; var x,f:vector; var a:matrix);
{Формирование матрицы Грама A по векторам данных X,F}
var i,j:integer;
    p,q,r,s:real;
begin
 for j:=0 to m do begin
  s:=0; r:=0; q:=0;
  for i:=0 to n do begin
   p:=ex(x[i],j);
   s:=s+p;
   r:=r+p*f[i];
   q:=q+p*ex(x[i],m);
  end;
  a[0,j]:=s;
  a[j,m]:=q;
  a[j,m+1]:=r;
 end;
 {Надо формировать только 1-ю строку и 2 последних столбца матрицы Грама,
  остальные элементы легко получить циклическим копированием:}
 for i:=1 to m do
 for j:=0 to m-1 do a[i,j]:=a[i-1,j+1];
end;
 
procedure Gauss(n:integer; var a:matrix; var x:vector);
{Решение СЛАУ методом Гаусса}
{a - расширенная матрица системы, x - вектор результата}
var i,j,k,l,k1,n1:integer;
    r,s:real;
begin
 {Прямой ход:}
 n1:=n+1;
 for k:=0 to n do begin
  k1:=k+1;
  s:=a[k,k];
  for j:=k1 to n1 do a[k,j]:=a[k,j]/s;
  for i:=k1 to n do begin
   r:=a[i,k];
   for j:=k1 to n1 do a[i,j]:=a[i,j]-a[k,j]*r;
  end;
 end;
 {Обратный ход:}
 for i:=n downto 0 do begin
  s:=a[i,n1];
  for j:=i+1 to n do s:=s-a[i,j]*x[j];
  x[i]:=s;
 end;
end;
 
function fi (m:integer; var c:vector; x1:real):real;
{Аппроксимирующая функция по найденным коэффициентам МНК}
{m - степень полинома, c - вектор коэффициентов,
 x1 - точка, в которой ищем значение}
var i:integer; p:real;
begin
 p:=c[m];
 for i:=m-1 downto 0 do p:=c[i]+x1*p;
 fi:=p;
end;
 
begin
 n:=StrToInt(Nl.Text);
 n:=n-1; {нумерация будет с нуля!}
 m:=StrToInt(M1.Text);
 InputData (n,x,f); {вводим данные}
 t:=gettickcount;
 Gram (n,m,x,f,a); {считаем матрицу Грама}
 Gauss (m,a,c); {решаем систему линейных уравнений}
 x0:=StrToFloat(Xn.Text);
 x9:=StrToFloat(Xk.Text);
 h:=StrToFloat(Hl.Text);
 k:=round((x9-x0)/h+1);
 x1:=x0;
 StringGrid2.RowCount:=k+1;
 for i:=1 to k do begin
  StringGrid2.Cells[0,i]:=FloatToStr(x1);
  StringGrid2.Cells[1,i]:=FloatToStr(fi(m,c,x1));
  x1:=x1+h;
 end;
 t:=gettickcount-t;
 Time1.Text:=FloatToStr(t);
end;