Компилирование для arm7 в Linux

#include "AT91SAM7X256_inc.h"
#include "exits.h"

.equ _exit, 0x20
.global _exit

.equ ARM_MODE_USR, 0x10
.equ ARM_MODE_FIQ, 0x11
.equ ARM_MODE_IRQ, 0x12
.equ ARM_MODE_SVC, 0x13
.equ ARM_MODE_ABT, 0x17
.equ ARM_MODE_UND, 0x1b
.equ ARM_MODE_SYS, 0x1f
.equ I_BIT, 0x80
.equ F_BIT, 0x40

.section .init
.org 0
.global main
ldr pc, =_start
mov r0, #EX_UNEXP_SWI
ldr pc, =_exit

.global _start
.func _start
_start:
/* NOTE: stacks is set by bootloader, and AIC is reset too. */
.global hardware_init
ldr r0, =hardware_init
mov lr, pc
bx r0
msr CPSR_c, #ARM_MODE_SVC /* enable interrupts */

/* копирование содержимого секции .data из ПЗУ в ОЗУ: _etext --> _data.._edata */
.global __data_load__
.global __data_start__
.global __data_end__
copy_data:
ldr r0, =__data_load__
ldr r1, =__data_start__
ldr r2, =__data_end__
copy_data1:
cmp r1, r2
ldrlo r3, [r0], #4
strlo r3, [r1], #4
blo copy_data1

/* заполнение секции .bss нулём */
.global __bss_start__
.global __bss_end__
zero_bss:
ldr r0, =__bss_start__
ldr r1, =__bss_end__
mov r2, #0
zero_bss1:
cmp r0, r1
strlo r2, [r0], #4
blo zero_bss1

/* вызов конструкторов C++ */
.global __ctors_start__
.global __ctors_end__
call_ctors:
ldr r0, =__ctors_start__
ldr r1, =__ctors_end__
b call_ctors2
call_ctors1:
ldr r2, [r0], #4
stmfd sp!, {r0-r1} /* сохр. r0-r1 на стеке */
mov lr, pc
bx r2
ldmia sp!, {r0-r1}
call_ctors2:
cmp r0, r1
blo call_ctors1

/* вызов функции main() */
.global main
mov r0, #0 /* int argc, char *argv[] */
mov r1, r0
mov r2, r0 /* ? */
mov fp, r0
mov r7, r0 /* ? */
ldr r4, =main
mov lr, #-4 /* возврат из main() по адресу 0 */
bx r4

.size _start, .-_start
.endfunc

.section .text
.global di
.global ei
.func di
di: msr CPSR_c, #ARM_MODE_SVC|I_BIT
mov pc, lr
.endfunc
.func ei
ei: msr CPSR_c, #ARM_MODE_SVC
mov pc, lr
.endfunc

.end