ICQ Bot и игнорирование событие onDisconnect

Public Class Form1
    Public WithEvents icq As New vbicq4.vbicq4  'создаем объект движка
    'делегирование события ошибки 
    Delegate Sub ErrDelegate(ByVal d As String)
    'делегирование события приема сообщения 
    Delegate Sub MsgDelegate(ByVal u As String, ByVal m As String)
    'делегирование события соединения 
    Delegate Sub OnConDelegate()
 
    'Константы
    Const BuffSize = 100    'размер очереди отправки
    Const SendTimeout = 1500 'таймаут между отправками (1.5 сек)
    Const PingTimeout = 10000 'Таймаут проерки на вылет (10 сек)
    'кодировка файлов бота
    Dim cp As System.Text.Encoding = System.Text.Encoding.GetEncoding(1251)
 
    Dim buffer As New List(Of String)   'очередь рассылки
    Dim StopTime As DateTime = Now   'им проверяем себя на вылет
 
    'Кнопка "Подключить"
    Private Sub Button1_Click(ByVal sender As System.Object, _
                              ByVal e As System.EventArgs) Handles Button1.Click
        icq.UIN = TextBox1.Text         'задаем uin
        icq.pass = TextBox2.Text        'задаем пароль
        icq.connect()                   'подключаемся
        TextBox3.Text = "Подключаемся..." & vbCrLf
        'включим таймер отправки
        StopTime = Now.AddSeconds(5)     'даем 5 секунд на логин
        Timer1.Interval = SendTimeout    'отправляем не чаще чем 1.5 сек, иначе вылетим
        Timer1.Enabled = True       'включаем таймер
    End Sub
 
    'Кнопка "Отключить"
    Private Sub Button2_Click(ByVal sender As System.Object, _
                              ByVal e As System.EventArgs) Handles Button2.Click
        Timer1.Enabled = False    'отключаем отпарвку
        icq.DisConnect()          'Разъединяемся
    End Sub
 
 
    'Если зашли в асю
    Private Sub icq_onConnect() Handles icq.onConnect
        'Проверяем на ошибку доступа из разных потоков:
        If InvokeRequired Then
            Me.BeginInvoke(New OnConDelegate(AddressOf icq_onConnect))
            Exit Sub
        End If
        'Напишем что мы в сети
        TextBox3.Text &= "В сети!" & vbCrLf
    End Sub
 
    'Если нас выкинуло:
    Private Sub icq_onDisconnect() Handles icq.onDisconnect
        'Проверяем на ошибку доступа из разных потоков:
        If InvokeRequired Then
            Me.BeginInvoke(New OnConDelegate(AddressOf icq_onDisconnect))
            Exit Sub
        End If
        'Напишем что мы в сети
        TextBox3.Text &= "Вылетели" & vbCrLf
    End Sub
 
    'если произошла ошибка:
    Private Sub icq_onError(ByVal Description As String) Handles icq.onError
        'Проверяем на ошибку доступа из разных потоков:
        If InvokeRequired Then
            Me.BeginInvoke(New ErrDelegate(AddressOf icq_onError), Description)
            Exit Sub
        End If
        'Выводим текст ошибки
        TextBox3.Text &= "Ошибка: " & Description & vbCrLf
 
        'Проверим, не за частый ли логин нас выкинуло:
        If InStr("Cлишком часто", Description) Then
            'если да - сбавим обороты:
            StopTime = Now.AddMinutes(15) 'ждем 15 минуток
            TextBox3.Text &= "Слишком часто ломились в сеть. Ждём 15 минут" & vbCrLf
        End If
    End Sub
 
    'Если пришло сообщение:
    Private Sub icq_onMessage(ByVal uin As String, _
                              ByVal message As String) Handles icq.onMessage
        'Проверяем на ошибку доступа из разных потоков:
        If InvokeRequired Then
            Me.BeginInvoke(New MsgDelegate(AddressOf icq_onMessage), _
                           New Object() {uin, message})
            Exit Sub
        End If
        'Печатаем сообщение:
        TextBox3.Text &= uin & ": " & message & vbCrLf
 
        'обрабатываем запрос:
        'если очередь больше допустипого то выходим
        If buffer.Count > BuffSize Then Exit Sub
        'иначе - обрабатываем запрос:
        ' если прислали !Help
        If LCase(Strings.Left(message, 5)) = "!help" Then
            'добавим в очередь ответ
            buffer.Add(uin & ":" & IO.File.ReadAllText("help.txt", cp))
            Exit Sub    'Выходим
        End If
        'Если хотят знать погоду:
        If LCase(Strings.Left(message, 7)) = "!pogoda" Then
            'добавим в очередь ответ
            buffer.Add(uin & ":" & IO.File.ReadAllText("pogoda.txt", cp))
            Exit Sub    'Выходим
        End If
 
        'если до сих пор не вышли - значит команда не найдена:
        buffer.Add(uin & ":Команда " & message & " не найдена")
        Exit Sub    'Выходим
    End Sub
 
    'Тик таймера рассылки
    Private Sub Timer1_Tick(ByVal sender As System.Object, _
                            ByVal e As System.EventArgs) Handles Timer1.Tick
        'Сперва проверим не вылетели ли мы
        If icq.KeepAlive Then
            'если мы в сети то можно отправить сообщение
            'отправляем нулевой элемент очереди (если есть)
            Dim i As Integer
            If buffer.Count > 0 Then
                'вытащим uin и сообщение
                Dim uin As String = Split(buffer(i), ":")(0)
                Dim message As String = Split(buffer(i), ":")(1)
                icq.SendMessage(uin, message) 'отправим
                buffer.RemoveAt(0)  'удалим отправленное из очереди
                Exit Sub        'теперь можем выйти
            End If
        Else
            'если вылетели - может пора зайти снова?
            If StopTime < Now Then
                'сместим время след. проверки на величину таймаута
                StopTime = Now.AddMilliseconds(PingTimeout)
                icq.connect()     'попытаемся соединиться
            End If
        End If
    End Sub
End Class