Геометрическая задачка

uses crt;
 
type point = record{точки}
           x, y: real;
        end;
     okr = record{окружности}
         x, y, r: real;
        end;
        
const nmax = 20;
 
function Peres(a, b: point; c: okr): boolean;{пересекаются или нет}
var
    s, ab, h: real;
begin
    s:= abs(a.x * (b.y - c.y) + b.x * (c.y - a.y) + c.x * (a.y - b.y)); {удвоенная площадь треугольника вершины которого центр окружности и 2 точки}
    ab:= sqrt(sqr(a.x - b.x) + sqr(a.y - b.y)); {сторона, противоположная центру окружности}
    h:= s / ab; {высота на нее = расстояние от центра до прямой}
    Peres:= h < c.r;{если оно меньше радиуса, пересекаются}
end;
 
var a: array[1..nmax] of point;
    b: array[1..nmax] of okr;
    n, m, i, j, k, p, mx, imx, jmx: integer;
begin
    clrscr;
    randomize;
    
    repeat
        write('Количество точек до ', nmax, ' n = ');
        readln(n);
    until n in [1..nmax];
    
    repeat
        write('Количество окружностей до ', nmax, ' m = ');
        readln(m);
    until m in [1..nmax];
    
    for i:=1 to n do
    begin
        a[i].x:= -10 + random * 21;
        a[i].y:= -10 + random * 21;
    end;
     
    for i:=1 to m do
    begin
        b[i].x:= -5 + 11 * random;
        b[i].y:= -5 + 11 * random;
        b[i].r:= 5 * random;
    end;
     
    writeln('Координаты точек:');
    write('X:');
    
    for i:= 1 to n do
        write(a[i].x:6:2);
    
    writeln;
    write('Y:');
    
    for i:=1 to n do
        write(a[i].y:6:2);
    
    writeln;
    writeln;
    writeln('Параметры окружностей:');
    write('X:');
    
    for i:= 1 to m do
        write(b[i].x:6:2);
    
    writeln;
    write('Y:');
    
    for i:= 1 to m do
        write(b[i].y:6:2);
    
    writeln;
    write('R:');
    
    for i:= 1 to m do
        write(b[i].r:6:2);
    
    writeln;
    writeln;
    
    mx:= 0;
    imx:= 0;
    jmx:= 0;
    
    for i:= 1 to n - 1 do
        for j:= i + 1 to n do
        begin
            k:= 0;
            for p:= 1 to m do
                if Peres(a[i], a[j], b[p]) then
                    k:= k + 1;
            
            if k > mx then
                begin
                    mx:= k;
                    imx:= i;
                    jmx:= j;
                end;
        end;
    
    if mx = 0 then
        write('Нет пересекающихся прямых и окружностей')
    else
        begin
            writeln('Максимальное число пересечений прямой с окружностями=', mx);
            write('Эта прямая проходит через точки (', a[imx].x:0:2, ';', a[imx].y:0:2, ') и (', a[jmx].x:0:2, ';', a[jmx].y:0:2, ')');
        end;
    readln
end.