Считать с базы данных поля

---Сессия пользователя
CREATE TABLE [dbo].[Session] (
    [SessionId]      UNIQUEIDENTIFIER DEFAULT (newid()) NOT NULL,
    [CreateDate]     DATETIME         DEFAULT (getutcdate()) NOT NULL,
    [UpdateDate]     DATETIME         DEFAULT (getutcdate()) NOT NULL,
    [SessionStateId] NVARCHAR (16)    DEFAULT ('Created') NOT NULL,
-- SessionState Статус сессии. Возможные значения 
-- Created - Создана, - возможно вобще не нужно
-- Active - Активна, возможно использование для вызова методов, просмотра страниц
-- Closed - Закрыта пользователем
-- Expired - Истек срок жизни
    [UserId]        BIGINT           NULL,
    [ExpireDate]    DATETIME         DEFAULT (dateadd(minute,(60),getutcdate())) NOT NULL,
    PRIMARY KEY CLUSTERED ([SessionId] ASC)
);
GO

SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
IF OBJECT_ID('[dbo].[__Template]') IS NOT NULL
    DROP PROCEDURE [dbo].[__Template]
GO
CREATE PROCEDURE [dbo].[__Template]-- __Template название вашей хранимки
AS
BEGIN
    SET NOCOUNT ON;
 
    DECLARE @ProcID CHAR(36) = NEWID();
 
    DECLARE @TranCount Int = @@TranCount;
 
    IF (@TranCount = 0)
        BEGIN TRANSACTION;
    ELSE
        SAVE TRANSACTION @ProcID;
 
    BEGIN TRY
        -- TODO: Procedure body comes here
        
        
        
        -- Завершаем транзакцию
        IF (@@TranCount > @TranCount)
            COMMIT TRANSACTION;
    END TRY
    BEGIN CATCH
        IF (@@TranCount > 0)
        BEGIN
            IF (@@TranCount = @TranCount AND XACT_STATE() <> -1)
                ROLLBACK TRANSACTION @ProcID;
            ELSE IF (@@TranCount > @TranCount)
                ROLLBACK TRANSACTION;
        END
        EXEC ReThrowException;
        RETURN;
    END CATCH
END
GO

CREATE PROCEDURE [dbo].[ThrowException] 
    @Code NVarChar(50),             -- Код исключения (см. таблицу Exception)
    @Param0 Sql_Variant = NULL,     -- Параметры, используемые
    @Param1 Sql_Variant = NULL,     -- в сообщении об ошибке
    @Param2 Sql_Variant = NULL,
    @Param3 Sql_Variant = NULL
AS
BEGIN
    SET NOCOUNT ON;
 
    -- Ищем код исключения
 
    DECLARE @Message NVarChar(2048);
    DECLARE @State   Int;
 
    SELECT  @Message = [Message],
            @State   = [State]
    FROM    Exception
    WHERE   Code = @Code;
 
    IF @@RowCount <> 1
    BEGIN
        EXEC ThrowException 'EXCEPTION_CODE_NOT_FOUND', @Code;
        RETURN;
    END
    
    -- Возбуждаем исключение
 
    DECLARE @NVCParam0 NVarChar(128); SET @NVCParam0 = RTrim(Cast(@Param0 as NVarChar(128)));
    DECLARE @NVCParam1 NVarChar(128); SET @NVCParam1 = RTrim(Cast(@Param1 as NVarChar(128)));
    DECLARE @NVCParam2 NVarChar(128); SET @NVCParam2 = RTrim(Cast(@Param2 as NVarChar(128)));
    DECLARE @NVCParam3 NVarChar(128); SET @NVCParam3 = RTrim(Cast(@Param3 as NVarChar(128)));
 
    RaisError(@Message, 18, @State, @NVCParam0, @NVCParam1, @NVCParam2, @NVCParam3);
    RETURN;
END
GO

ALTER PROCEDURE [dbo].[ReThrowException] 
AS
BEGIN
    DECLARE @Number    Int;
    DECLARE @Severity  Int;
    DECLARE @State     Int;
    DECLARE @Message   NVarChar(4000);
    DECLARE @Procedure NVarChar(126);
    DECLARE @Line      Int;
    
    SELECT  @Number    = ERROR_NUMBER(),
            @Severity  = ERROR_SEVERITY(),
            @State     = ERROR_STATE(),
            @Message   = ERROR_MESSAGE(),
            @Procedure = ERROR_PROCEDURE(),
            @Line      = ERROR_LINE();
 
    IF @Number = 50000
    BEGIN
        RaisError(@Message, @Severity, @State);
        RETURN;
    END
    ELSE
    BEGIN
        IF (Len(@Procedure) > 0) SET @Message = @Message + ' in «' + @Procedure + '»';
        IF (@Line > 0) SET @Message = @Message + ', line ' + Cast(@Line AS NVarChar(32));
        RaisError(@Message, @Severity, 127); -- SERVER_ERROR
        RETURN;
    END
END
GO

--- Таблица содержащаая в себе коды исклчений и их описание
CREATE TABLE [dbo].[Exception](
     [Code]        NVARCHAR(64)   NOT NULL, 
     [Message]     NVARCHAR(2048) NOT NULL,
     [State]       INT            NOT NULL,
     PRIMARY KEY CLUSTERED ([Code] ASC)
);
GO