Сформировать двумерный массив и выполнить над ним преобразования

unit Zadanie135unit1;
 
{$H+}
 
interface
 
uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, Grids,
  StdCtrls, Menus;
 
type
 
  TArr = array of array of real;
 
  { TForm1 }
 
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Edit1: TEdit;
    Edit2: TEdit;
    Edit3: TEdit;
    Label1: TLabel;
    Label2: TLabel;
    Label3: TLabel;
    MainMenu1: TMainMenu;
    MenuItem1: TMenuItem;
    MenuItem2: TMenuItem;
    MenuItem3: TMenuItem;
    MenuItem4: TMenuItem;
    MenuItem5: TMenuItem;
    MenuItem6: TMenuItem;
    StringGrid1: TStringGrid;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure MenuItem1Click(Sender: TObject);
    procedure MenuItem2Click(Sender: TObject);
    procedure MenuItem3Click(Sender: TObject);
    procedure MenuItem4Click(Sender: TObject);
    procedure MenuItem5Click(Sender: TObject);
    procedure MenuItem6Click(Sender: TObject);
  private
    Row: integer;  // Переменная для хранения значения количества строк массива.
    Col: integer;  // Переменная для хранения значения количества столбцов массива.
    a: TArr; //   Переменная для хранения двумерного массива.
    SumRow: real; // Переменная для хранения значения суммы максимальных элементов.
  public
 
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.lfm}
 
{ TForm1 }
 
procedure ClearArr(var arr: TArr);
// Процедура, которая заполняет двумерный массив нулями.
var
  i,j: integer;
begin
  for i:= 1 to length(arr)-1 do
    for j:= 1 to length(arr[i])-1 do
      arr[i,j]:= 0;
end;
 
procedure ArrToStringGrid(arr:TArr);
// Процедура, которая выводит значения элементов массива в ячейки компонента StringGrid
var
  i,j: integer;
begin
  for i:= 1 to length(arr)-1 do
    for j:= 1 to length(arr[i])-1 do
      Form1.StringGrid1.Cells[j,i]:= FloatToStrF(arr[i,j], ffFixed, 4, 1);
 
end;
 
procedure RandomInArray(var arr: TArr);
// Процедура, которая заполняет двумерный массив случайными числами
// Числа действительные. Диапазон случайных чисел от -10.0 до 10.0
var
  i,j: integer;
begin
  for i:= 1 to length(arr)-1 do
    for j:= 1 to length(arr[i])-1 do
      arr[i,j]:= (random(201)-100)/10;
end;
 
procedure MinElement0MaxElement1(var arr: TArr);
// Процедура, которая находит минимальный элемент строки  массива и заменяет его нулями
// и находит максимальный элемент строки массива и заменяет его 1.
var
  i,j: integer;
  min,max: real;
  indmax: integer;
  indmin: integer;
begin
 
  for i:= 1 to length(arr)-1 do
    begin
      min:= 1.7e308;
      max:= -1.7e308;
      for j:= 1 to length(arr[i])-1 do
        begin
          if arr[i,j] > max then // Условие для поиска элемента с максимальным значением
            begin
              max:= arr[i,j];
              indmax:= j;
            end;
          if arr[i,j] < min then // Условие для поиска элемента с минимальным значением
            begin
              min:= arr[i,j];
              indmin:= j;
            end;
        end;
      arr[i,indmax]:= 1;  // Замена элемента с максимальным значением единицей.
      arr[i,indmin]:= 0;  // Замена элемента с минимальным значением нулем.
    end;
 
end;
 
procedure ColomnWithValue5(var arr: TArr);
//  Процедура, которая вставляет дополнительные столбцы
//  с пятерками, если найден первый элемент столбца делящийся на 5.
var
  i,j,k,d: integer;
begin
    for j := length(arr[1])-1 downto 1 do  // Перебор индексов элементов с от большего к меньшему.
      if round(arr[1,j]*10) mod 5 = 0 then  // Условие для поиска первого элемента столбца, делящегося на 5
          begin
          // Увеличение размера динамического массива на 1 столбец.
            SetLength(arr,length(arr),length(arr[1])+1);
            for d:= length(arr[1])-1 downto j do
              for k:= 1 to length(arr)-1 do
               arr[k,d+1]:= arr[k,d];          //  Передвижение элементов на 1 столбец вправо.
            for d:= 1 to length(arr)-1 do
                arr[d,j]:= 5;                   //  Вставка в массив столбца с пятерками.
          end;
 
end;
 
procedure SumArr(var arr: TArr; var sum: real);
// Процедура, которая суммирует все найденные максимальные элементы в строках.
var
i,j: integer;
  max: real;
  sum1: real;
begin
  sum1:= 0;
  for i:= 1 to length(arr)-1 do
    begin
      max:= -1.7e308;
      for j:= 1 to length(arr[i])-1 do
        if arr[i,j] > max then   // Условие для нахождения элемента с максимальным значением.
            max:= arr[i,j];
      sum1:= sum1 + max;     // Вычисление суммы максимальных элементов.
    end;
  sum:= sum1;
end;
 
procedure RowSort(var arr: TArr);
// Процедура, которая упорядочивает элементы в строках по возрастанию
var
  i,j,k: integer;
  tmp: real;
begin
  for i:= 1 to length(arr)-1 do
    for j := 1 to length(arr[i])-1 do
      for k := 1 to length(arr[i])-1 - j do
        if arr[i,k] > arr[i,k+1] then
          begin
            tmp := arr[i,k];
            arr[i,k] := arr[i,k+1];
            arr[i,k+1] := tmp;
          end;
end;
 
procedure TForm1.FormCreate(Sender: TObject);
begin
  Randomize;
  Row:= 5;
  Col:= 5;
  Edit1.Text:= intToStr(Row);
  Edit2.Text:= IntToStr(Col);
  SetLength(a,Row+1,Col+1);
  ClearArr(a);
  StringGrid1.RowCount:= length(a);
  StringGrid1.ColCount:= Length(a[1]);
  ArrToStringGrid(a);
  SumRow:= 0;
  Edit3.Text:= FloatToStrF(SumRow, ffFixed, 4, 1);
end;
 
 
procedure TForm1.Button1Click(Sender: TObject);
// Обработчик кнопки "Новый размер массива"
begin
  Row:= StrToInt(Edit1.Text);
  Col:= StrToInt(Edit2.Text);
  SetLength(a,Row+1,Col+1);
  StringGrid1.RowCount:= Row+1;
  StringGrid1.ColCount:= Col+1;
  ClearArr(a);
  ArrToStringGrid(a);
 
end;
 
procedure TForm1.Button2Click(Sender: TObject);
// Обработчик кнопки "Очистить"
begin
  ClearArr(a);
  ArrToStringGrid(a);
end;
 
procedure TForm1.MenuItem1Click(Sender: TObject);
begin
 
end;
 
procedure TForm1.MenuItem2Click(Sender: TObject);
// Обработчик пункта меню "Заполнить случайными числами"
begin
  RandomInArray(a);
  ArrToStringGrid(a);
end;
 
procedure TForm1.MenuItem3Click(Sender: TObject);
// Обработчик пункта меню "Заменить минимальный элемент нулем"
begin
  MinElement0MaxElement1(a);
  ArrToStringGrid(a);
end;
 
procedure TForm1.MenuItem4Click(Sender: TObject);
// Обработчик пункта меню "Вставить столбец с пятерками"
begin
  ColomnWithValue5(a);
  StringGrid1.RowCount:= length(a);
  StringGrid1.ColCount:= length(a[1]);
  Row:= StringGrid1.RowCount-1;
  Col:= StringGrid1.ColCount-1;
  Edit1.Text:= intToStr(Row);
  Edit2.Text:= IntToStr(Col);
  ArrToStringGrid(a);
end;
 
procedure TForm1.MenuItem5Click(Sender: TObject);
// Обработчик пункта меню "Найти сумму элементов i той строки"
begin
  SumArr(a,SumRow);
  Edit3.Text:= FloatToStrF(SumRow, ffFixed, 4, 1);
  ArrToStringGrid(a);
end;
 
procedure TForm1.MenuItem6Click(Sender: TObject);
// Обработчик пункта меню "Упорядочить строки по возрастанию"
begin
  RowSort(a);
  ArrToStringGrid(a);
end;
 
end.