Прошу помощи в отрисовке потомка TEdit

unit ADEdit;
 
interface
 
uses
  System.SysUtils, System.Classes, Vcl.Controls, Vcl.StdCtrls, Graphics,
  Messages, Dialogs, Forms, Windows, UITypes;
 
type
  TADEdit = class(TEdit)
  private
    procedure WMNCCalcSize(var Message: TWMNCCalcSize); message WM_NCCALCSIZE;
    procedure WMEraseBkgnd(var Message: TWMEraseBkgnd); message WM_ERASEBKGND;
    function TextExtent(AStr: String): TSize;
  protected
 
  public
    constructor Create(AOwner: TComponent); override;
  published
 
  end;
 
procedure Register;
 
implementation
 
procedure Register;
begin
  RegisterComponents('Altium', [TADEdit]);
end;
 
constructor TADEdit.Create(AOwner: TComponent);
begin
  inherited;
  BorderStyle := bsNone;
  Color := $002E2E2E;
  Height := 21;
  Width := 57;
  Font.Size := 8;
  Font.Color := $00E6E6E6;
  Text := '2.30mm';
end;
 
procedure TADEdit.WMEraseBkgnd(var Message: TWMEraseBkgnd);
var DC: HDC;
begin
   inherited;
   DC := GetWindowDC(Handle);
   FillRgn(DC, CreateRoundRectRgn(0, 0, Width+1, Height+1, 10, 10), Brush.Handle);
   Message.Result := 1;
end;
 
procedure TADEdit.WMNCCalcSize(var Message: TWMNCCalcSize);
var P: PNCCalcSizeParams;
    S: TSize;
begin
  inherited;
  P := Message.CalcSize_Params;
  S := TextExtent('A');
  P.rgrc[0].Top := P.rgrc[0].Top + (Height - S.cy) shr 1;
  P.rgrc[0].Left := P.rgrc[0].Left + 8;
  P.rgrc[0].Right := P.rgrc[0].Right - 2;
  P.rgrc[0].Bottom := P.rgrc[0].Top + S.cy;
end;
 
function TADEdit.TextExtent(AStr: String): TSize;
var DC: HDC;
    SaveFont: HFONT;
begin
  DC := GetDC(0);
  SaveFont := SelectObject(DC, Font.Handle);
  GetTextExtentPoint32(DC, PChar(AStr), Length(AStr), Result);
  SelectObject(DC, SaveFont);
  ReleaseDC(0, DC);
end;
 
end.

procedure TADEdit.WMEraseBkgnd(var Message: TWMEraseBkgnd);
var
  DC: HDC;
  rgn: HRGN;
  r: TRect;
begin
  inherited;
  DC := GetWindowDC(Handle);
  r.Left := 0;
  r.Top := 0;
  r.Right := Width;
  r.Bottom := Height;
  FillRect(DC, r, Parent.Brush.Handle);
 
  rgn := CreateRoundRectRgn(0, 0, Width+1, Height+1, 10, 10);
  FillRgn(DC, rgn, Brush.Handle);
  DeleteObject(rgn);
 
  ReleaseDC(Handle, DC);
  Message.Result := 1;
end;

unit ADEdit;
 
interface
 
uses
  System.SysUtils, System.Classes, Vcl.Controls, Vcl.StdCtrls, Graphics,
  Messages, Dialogs, Forms, Windows, UITypes;
 
type
  TADEdit = class(TEdit)
  private
    FRGN: HRGN;
    procedure WMNCCalcSize(var Message: TWMNCCalcSize); message WM_NCCALCSIZE;
    procedure WMSize(var Message: TWMSize); message WM_SIZE;
    procedure WMEraseBkgnd(var Message: TWMEraseBkgnd); message WM_ERASEBKGND;
    function TextExtent(AStr: String): TSize;
  protected
 
  public
    constructor Create(AOwner: TComponent); override;
  published
 
  end;
 
procedure Register;
 
implementation
 
procedure Register;
begin
  RegisterComponents('Altium', [TADEdit]);
end;
 
constructor TADEdit.Create(AOwner: TComponent);
begin
  inherited;
  BorderStyle := bsNone;
  Color := $002E2E2E;
  Height := 21;
  Width := 57;
  Font.Size := 8;
  Font.Color := $00E6E6E6;
  Text := '2.30mm';
  FRGN := 0;
end;
 
procedure TADEdit.WMEraseBkgnd(var Message: TWMEraseBkgnd);
var DC: HDC;
begin
  inherited;
  DC := GetWindowDC(Handle);
  FillRect(DC, Rect(0, 0, Width, Height), Brush.Handle);
  ReleaseDC(Handle, DC);
  Message.Result := 1;
end;
 
procedure TADEdit.WMNCCalcSize(var Message: TWMNCCalcSize);
var P: PNCCalcSizeParams;
    S: TSize;
begin
  inherited;
  P := Message.CalcSize_Params;
  S := TextExtent('A');
  P.rgrc[0].Top := P.rgrc[0].Top + (Height - S.cy) shr 1;
  P.rgrc[0].Left := P.rgrc[0].Left + 8;
  P.rgrc[0].Right := P.rgrc[0].Right - 2;
  P.rgrc[0].Bottom := P.rgrc[0].Top + S.cy;
end;
 
procedure TADEdit.WMSize(var Message: TWMSize);
begin
  SetWindowRGN(Handle, 0, false);
  DeleteObject(FRGN);
  FRGN := CreateRoundRectRgn(0, 0, Width+1, Height+1, 10, 10);
  SetWindowRGN(Handle, FRGN, false);
  inherited;
end;
 
function TADEdit.TextExtent(AStr: String): TSize;
var DC: HDC;
    SaveFont: HFONT;
begin
  DC := GetDC(0);
  SaveFont := SelectObject(DC, Font.Handle);
  GetTextExtentPoint32(DC, PChar(AStr), Length(AStr), Result);
  SelectObject(DC, SaveFont);
  ReleaseDC(0, DC);
end;
 
end.