Необходим совет по парсингу HTML

//Загрузка HTML документа из строковой переменной.
function LoadHTMLContent(aWb : TWebBrowser; const aStr : String) : Variant;
begin
  Result := aWb.OleObject.document;
  //Если объект документа оказался не созданным, то создаём его.
  if TVarData(Result).VDispatch = nil then begin
    //Создаём новый документ с пустым содержанием.
    aWb.Navigate('about:blank');
    Result := aWb.OleObject.document;
  end;
  //Загружаем в документ нужный HTML код из Memo1.
  Result.open('text/html', 'replace');
  Result.write(aStr);
  Result.close;
end;
 
//Создание нового документа в TWebBrowser.
procedure TForm1.Button1Click(Sender: TObject);
begin
  LoadHTMLContent(WebBrowser1, Memo1.Text);
end;
 
//Поиск элементов с заданными параметрами.
procedure TForm1.Button2Click(Sender: TObject);
var
  Doc, Arr, Elem : Variant;
  STag, SClass : String;
  i : Integer;
begin
  //Ссылка на документ.
  Doc := WebBrowser1.OleObject.document;
  if TVarData(Doc).VDispatch = nil then begin
    ShowMessage('Документ не задан. Действие отменено.');
    Exit;
  end;
 
  //Параметры поиска.
 
  //Тег.
  STag := Edit1.Text;
  if STag = '' then begin
    ShowMessage('Тег не задан. Действие отменено.');
    Exit;
  end;
  //Имя класса.
  SClass := Edit2.Text;
  if SClass = '' then begin
    ShowMessage('Тег не задан. Действие отменено.');
    Exit;
  end;
 
  //Решение задачи.
 
  Memo2.Clear;
  //Получаем список всех элементов с заданным тегом.
  Arr := Doc.getElementsByTagName(STag);
  //Перебираем элементы этого списка и выбираем те, которые имеют
  //имя класса, совпадающего с заданным.
  for i := 0 to Arr.length - 1 do begin
    //Ссылка на очередной элемент.
    Elem := Arr.item(i);
    //Если имя класса совпадает с заданным, то распечатываем
    //сведения об этом элементе.
    if Elem.className = SClass then begin
      Memo2.Lines.Add(
        'Тег: "' + Elem.tagName + '"'
        + ', класс: "' + Elem.className + '"'
        + ', текст: "' + Elem.innerHTML + '"'
      );
    end;
  end;
end;