деки в делфи

type
  //Тип сновных данных.
  TData = Integer;
  //Тип указателя на элемент дека.
  TPElem = ^TElem;
  //Тип элемента дека.
  TElem = record
    Data : TData;
    PNext, PPrev : TPElem; //Указатели на следующий и предыдущий элементы.
  end;
  //Тип дека.
  TDeck = record
    PFirst, PLast : TPElem; //Указатели на первый и последний элементы дека.
  end;
 
//Добавление элемента в начало дека.
procedure PushF(var aDeck : TDeck; var aPElem : TPElem);
begin
  if aPElem = nil then Exit;
 
  aPElem.PPrev := nil;
  aPElem.PNext := aDeck.PFirst;
  if aDeck.PFirst <> nil then aDeck.PFirst^.PPrev := aPElem;
  aDeck.PFirst := aPElem;
  if aDeck.PLast = nil then aDeck.PLast := aPElem;
end;
 
//Добавление элемента в конец дека.
procedure PushL(var aDeck : TDeck; var aPElem : TPElem);
begin
  if aPElem = nil then Exit;
 
  aPElem.PNext := nil;
  aPElem.PPrev := aDeck.PLast;
  if aDeck.PLast <> nil then aDeck.PLast^.PNext := aPElem;
  aDeck.PLast := aPElem;
  if aDeck.PFirst = nil then aDeck.PFirst := aPElem;
end;
 
//Изъятие элемента из начала дека.
function PopF(var aDeck : TDeck; var aPElem : TPElem) : Boolean;
begin
  Result := False;
  if aDeck.PFirst = nil then Exit;
 
  aPElem := aDeck.PFirst;
  aDeck.PFirst := aPElem^.PNext;
  if aDeck.PFirst <> nil then aDeck.PFirst^.PPrev := nil;
  if aDeck.PLast = aPElem then aDeck.PLast := nil;
  Result := True;
end;
 
//Изъятие элемента из конца дека.
function PopL(var aDeck : TDeck; var aPElem : TPElem) : Boolean;
begin
  Result := False;
  if aDeck.PFirst = nil then Exit;
 
  aPElem := aDeck.PLast;
  aDeck.PLast := aPElem^.PPrev;
  if aDeck.PLast <> nil then aDeck.PLast^.PNext := nil;
  if aDeck.PFirst = aPElem then aDeck.PFirst := nil;
  Result := True;
end;
 
//Удаление дека из памяти.
procedure DeckFree(var aDeck : TDeck);
var
  PDel : TPElem;
begin
  while PopF(aDeck, PDel) do Dispose(PDel);
end;
 
//Распечатка дека в направлении начало - конец.
function DeckPrint(var aDeck : TDeck) : String;
var
  D : TDeck;
  PElem : TPElem;
  i : Integer;
begin
  Result := '';
  D.PFirst := nil;
  D.PLast := nil;
  i := 0;
  while PopF(aDeck, PElem) do begin
    PushL(D, PElem);
    Inc(i);
    if i > 1 then Result := Result + ', ';
    Result := Result + IntToStr(PElem^.Data);
  end;
  aDeck := D;
  if Result = '' then Result := 'Дек пуст.';
end;
 
procedure TForm1.Button1Click(Sender: TObject);
const
  //Основа для установки размера деков.
  M = 10;
var
  D1, D2, D3 : TDeck;
  PElem, PElem1, PElem2 : TPElem;
  F1, F2 : Boolean;
  i, j : Integer;
begin
  Memo1.Lines.Add('--------------------------------------------------');
  //Начальная инициализация деков.
  D1.PFirst := nil;
  D1.PLast := nil;
  D2 := D1;
  D3 := D1;
 
  //Записываем в первые 2 дека элементы по возрастанию значений в направлении
  //начало - конец.
  Randomize;
  //В первый дек записываем чётные значения.
  j := 0;
  for i := 1 to 5 + Random(M) do begin
    New(PElem);
    PElem^.Data := j;
    PushL(D1, PElem);
    Inc(j, 2);
  end;
  //Во второй дек записываем нечётные значения.
  j := 1;
  for i := 1 to 5 + Random(M) do begin
    New(PElem);
    PElem^.Data := j;
    PushL(D2, PElem);
    Inc(j, 2);
  end;
  //Распечатка первых двух деков.
  Memo1.Lines.Add('Первый дек:');
  Memo1.Lines.Add(DeckPrint(D1));
  Memo1.Lines.Add('Второй дек:');
  Memo1.Lines.Add(DeckPrint(D2));
 
  //Решение задачи.
  F1 := PopL(D1, PElem1);
  F2 := PopL(D2, PElem2);
  //Выполняем работу пока в деке D1 и (или) D2 есть элементы.
  while F1 or F2 do begin
    //Если из конца дека D1 взят элемент и в этот момент оказалось:
    //- Что в деке D2 нет элементов.
    //- Или значение элемента, взятого из конца дека D2 оказалось меньше значения
    //элемента, взятого из конца дека D1.
    //- Тогда записываем элемент, взятый из конца дека D1 в конец дека D3.
    //А затем изымаем следующий элемент из конца дека D1.
    while F1 and ( not F2 or (PElem2^.Data < PElem1^.Data) ) do begin
      PushL(D3, PElem1);
      F1 := PopL(D1, PElem1);
    end;
    //Аналогично в отношении второго дека.
    while F2 and ( not F1 or (PElem1^.Data < PElem2^.Data) ) do begin
      PushL(D3, PElem2);
      F2 := PopL(D2, PElem2);
    end;
  end;
 
  //Ответ.
  Memo1.Lines.Add('Третий дек:');
  Memo1.Lines.Add(DeckPrint(D3));
 
  //Удаление деков из памяти.
  DeckFree(D1);
  DeckFree(D2);
  DeckFree(D3);
  Memo1.Lines.Add('Деки удалены из памяти.');
end;