Составить блок-схему для программы Сапер

unit Minesf;
 
interface
 
uses
  SysUtils, Windows, Messages, Classes, Graphics,
  Controls, Forms, Dialogs, Grids, StdCtrls, Menus, ExtCtrls, ImgList;
 
const NItems = 10;
const NMines = 12;
 
type
  TForm1 = class(TForm)
    DrawGrid1: TDrawGrid;
    Panel1: TPanel;
    LabelShots: TLabel;
    MainMenu1: TMainMenu;
    File1: TMenuItem;
    NewGame1: TMenuItem;
    N1: TMenuItem;
    Exit1: TMenuItem;
    Help1: TMenuItem;
    About1: TMenuItem;
    ImageList: TImageList;
    procedure FormCreate(Sender: TObject);
    procedure DrawGrid1MouseDown(Sender: TObject; Button: TMouseButton;
      Shift: TShiftState; X, Y: Integer);
    procedure DrawGrid1DrawCell(Sender: TObject; Col, Row: Integer;
      Rect: TRect; State: TGridDrawState);
    procedure FormDestroy(Sender: TObject);
    procedure About1Click(Sender: TObject);
    procedure NewGame1Click(Sender: TObject);
    procedure Exit1Click(Sender: TObject);
  private
    Playing: Boolean;
    Bmp: TBitmap;
    LastBmp: Char;
    Shots,
    MinesFound: Integer;
 
    Display: array [0 .. NItems - 1, 0 .. NItems -1] of Boolean;
 
    Map: array [0 .. NItems - 1, 0 .. NItems -1] of Char;
 
    procedure ComputeMines (X, Y: Integer);
 
    procedure FloodZeros (X, Y: Integer);
 
  public
 
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.DFM}
 
uses MMSystem;
 
procedure TForm1.FormCreate(Sender: TObject);
var
  I, J, X, Y, MinesToPlace: Integer;
  TempBmp:TBitmap;
begin
  If Imagelist.Count<=0 then
  begin
    TempBmp:=TBitmap.Create;
    TempBmp.LoadFromFile('def.bmp');
    Imagelist.Clear;
    Imagelist.Add(TempBmp,TempBmp);
    TempBmp.Free;
  end;
  Randomize;
  Playing := True;
  Shots := 0;
  MinesFound := 0;
  Bmp := TBitmap.Create;
  LastBmp := ' ';
 
  for I := 0 to NItems - 1 do
    for J := 0 to NItems - 1 do
    begin
      Map [I, J] := ' ';
      Display [I, J] := False;
    end;
 
  MinesToPlace := NMines;
  while MinesToPlace > 0 do
  begin
    X := Random (NItems);
    Y := Random (NItems);
    if Map [X, Y] <> 'M' then
    begin
      Map [X, Y] := 'M';
      Dec (MinesToPlace);
    end;
  end;
 
  for I := 0 to NItems - 1 do
    for J := 0 to NItems - 1 do
      if not (Map [I, J] = 'M') then
        ComputeMines (I, J);
end;
 
procedure TForm1.ComputeMines (X, Y: Integer);
var
  Col, Row: Integer;
  Total : Char;
begin
  Total := '0';
  for Col := X - 1 to X + 1 do
    for Row := Y -1 to Y + 1 do
      if (Col >= 0) and (Col < NItems) and
          (Row >= 0) and (Row < NItems) then
 
        if (Map [Col, Row] = 'M') or
            (Map [Col, Row] = 'K') then
          Inc (Total);
  Map [X, Y] := Total;
end;
 
procedure TForm1.FloodZeros (X, Y: Integer);
var
  Col, Row: Integer;
  MyRect: TRect;
begin
  if Map [X, Y] = '0' then
    for Col := X - 1 to X + 1 do
      for Row := Y -1 to Y + 1 do
        if (Col >= 0) and (Col < NItems) and
          (Row >= 0) and (Row < NItems) and
          not ( (Col = X) and (Row = Y) )then
        begin
 
          if (Map [Col, Row] = '0') and
              (Display [Col, Row] = False) then
          begin
 
            Display [Col, Row] := True;
            FloodZeros (Col, Row);
          end
          else
            Display [Col, Row] := True;
          MyRect := DrawGrid1.CellRect (Col, Row);
          InvalidateRect (DrawGrid1.Handle, @MyRect, False);
        end
end;
 
procedure TForm1.DrawGrid1MouseDown(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
var
  Col, Row: LongInt;
  MyRect: TRect;
begin
  if not Playing then Exit;
  DrawGrid1.MouseToCell (X, Y, Col, Row);
  if not Playing then
    SysUtils.Beep
  else if Button = mbLeft then
  begin
    Inc (Shots);
    LabelShots.Caption := 'Shots: ' + IntToStr (Shots);
 
    if (Map [Col, Row] = 'M') or (Map [Col, Row] = 'K') then
    begin
      PlaySound ('Boom.wav', 0, snd_async);
      Playing := False;
      ShowMessage(' Game Over');
    end
    else
    begin
      Display [Col, Row] := True;
      if Map [Col, Row] = '0' then
        FloodZeros (Col, Row);
    end;
  end
  else
  begin
    case Map [Col, Row] of
 
      'M': begin
        Map [Col, Row] := 'K';
        Display [Col, Row] := True;
        Inc (MinesFound);
        if MinesFound = NMines then
        begin
          MessageDlg ('You have won. Congratulations!',
            mtInformation, [mbOK], 0);
          Playing := False;
          DrawGrid1.Repaint;
        end
      end;
 
      'K': begin
        Map [Col, Row] := 'M';
        Display [Col, Row] := False;
        Dec (MinesFound);
      end;
      '0'..'8': begin
        Map [Col, Row] := 'W';
        Display [Col, Row] := True;
      end;
 
      'W': begin
        ComputeMines (Col, Row);
        Display [Col, Row] := False;
      end;
    end;
  end;
  MyRect := DrawGrid1.CellRect (Col, Row);
  InvalidateRect (DrawGrid1.Handle, @MyRect, False);
end;
 
procedure TForm1.DrawGrid1DrawCell(Sender: TObject; Col, Row: Integer; Rect: TRect; State: TGridDrawState);
 
  procedure MyDraw(ACode:Char);
  var dx:integer;
  begin
    Case ACode of
    '0': dx:=0;
    '1': dx:=1;
    '2': dx:=2;
    '3': dx:=3;
    '4': dx:=4;
    '5': dx:=5;
    '6': dx:=6;
    '7': dx:=7;
    '8': dx:=8;
    'M': dx:=9;
    'K': dx:=10;
    'W': dx:=10;
    'U': dx:=11;
    end;
  Imagelist.Draw(DrawGrid1.Canvas,Rect.Left, Rect.Top,dx);
  end;
 
var Code: Char;
begin
  Code := Map [Col, Row];
 
  if Display [Col, Row] then
  begin
    if not (Code = LastBmp) then LastBmp := Code;
    MyDraw(Code);
  end
  else
  begin
    if not (LastBmp = 'U') then LastBmp := 'U';
    MyDraw(LastBmp);
  end;
 
  if (not Playing) and (Code = 'M') then
  begin
    if not (Code = LastBmp) then LastBmp := Code;
    MyDraw(Code);
  end;
end;
 
procedure TForm1.FormDestroy(Sender: TObject);
begin
  Bmp.Free;
end;
 
procedure TForm1.About1Click(Sender: TObject);
begin
  MessageDlg ('Мастер сапера в Delphi',
    mtInformation, [mbOK], 0);
end;
 
procedure TForm1.NewGame1Click(Sender: TObject);
begin
  FormCreate (self);
  DrawGrid1.Repaint;
end;
 
procedure TForm1.Exit1Click(Sender: TObject);
begin
  Close;
end;
 
end.