ребята можете объяснить где как добавлять

unit AutoUpdateImpl;
 
interface
 
uses IdHTTP, SysUtils;
 
type
 
  EAutoUpdate = class(exception);
  EAutoUpdateMissing = class(EAutoUpdate);
  EAutoUpdateInvalidUpdateInfoDocument = Class(EAutoUpdate);
 
  TFileVersionInfo = record
    FileVersion: array[0..1] of cardinal;
    ProductVersion: array[0..1] of cardinal;
  end;
 
function GetFileVersion(FileName: string; var FileInfo: TFileVersionInfo): Boolean;
 
function AutoUpdate_CheckEXE(EXEFileName, VersionInfoURL: String; Var UpdateURL, NewVersionInfo: String; Var CurrentVersion, Latestversion: TFileVersionInfo): Boolean; overload;
function AutoUpdate_CheckEXE(EXEFileName, VersionInfoURL: String; Var UpdateURL, NewVersionInfo: String; Var CurrentVersion, Latestversion: TFileVersionInfo; ProxyServer, ProxyUsername, ProxyPassword: string; ProxyPort: Integer): Boolean; overload;
procedure AutoUpdate_WriteEXEVersionInfoFile(EXEFileName, TargetFileName, UpdateURL, NewVersionInfo, NewVersionInfoURL: string);
 
 
implementation
{$IFDEF MSWINDOWS}
uses classes, Windows, Forms;
{$ELSE}
uses classes, QForms, SysUtils;
{$ENDIF}
 
resourcestring
   STR_EX_VERSION_INFO_MISSING = 'Cannot extract version informations from "%s"';
   STR_EX_INVALID_VERSION_INFO_STRING = 'The version info string "%s" could not be parsed';
   STR_CANNOT_GET_NEW_VERSION_DOCUMENT = 'Cannot get the information page for the new version at URL "%s".'#13#10'Exception %s: "%s"';
 
const
  STR_LATEST_VERSION       = 'LatestVersion';
  STR_UPDATE_URL           = 'UpdateURL';
  STR_NEW_VERSION_INFO     = 'NewVersionInfo';
  STR_NEW_VRESION_INFO_URL = 'NewVersionInfoURL';
 
function VersionInfoToStr(VersionInfo: TFileversionInfo): string;
begin
  result := Format( '%d.%d.%d.%d', [versionInfo.ProductVersion[0], versionInfo.ProductVersion[1], versionInfo.FileVersion[0], versionInfo.FileVersion[1]]);
end;
 
function StrToVersionInfoStr(Src: String): TFileversionInfo;
var
  StartPos, EndPos: Integer;
  SrcLength: Integer;
  AVersionInfoNumber, VersionInfoTarget: Integer;
begin
  try
    StartPos := 1;
    VersionInfoTarget := 0;
    SrcLength := Length(Src);
    for EndPos := 1 to Length(Src) do    // Iterate
    begin
      if (Src[EndPos] = '.') or (EndPos=SrcLength) then
      begin
        // get the data
        if (EndPos=SrcLength) then
          AVersionInfoNumber := StrToInt(Copy(Src, StartPos, EndPos - StartPos + 1))
        else
          AVersionInfoNumber := StrToInt(Copy(Src, StartPos, EndPos - StartPos));
        // Update the starting position
        StartPos := EndPos + 1;
        // Update the result
        case VersionInfoTarget of    //
          0:
            result.ProductVersion[0] := AVersionInfoNumber;
          1:
            result.ProductVersion[1] := AVersionInfoNumber;
          2:
            result.FileVersion[0] := AVersionInfoNumber;
          3:
            result.FileVersion[1] := AVersionInfoNumber;
        end;    // case
        inc(VersionInfoTarget);
        if VersionInfoTarget > 3 then
          Break;
      end;
    end;    // for
  except
    raise EAutoUpdateInvalidUpdateInfoDocument.createFmt(STR_EX_INVALID_VERSION_INFO_STRING, [Src]);
  end;
end;
 
procedure AutoUpdate_WriteEXEVersionInfoFile(EXEFileName, TargetFileName, UpdateURL, NewVersionInfo, NewVersionInfoURL: string);
var
  CurrentVersion: TFileVersionInfo;
  VersionInfoFile: TStringList;
begin
  // get current file version;
  if EXEFileName = '' then
    EXEFileName := Application.ExeName;
  if not GetFileVersion(Application.ExeName, CurrentVersion) then
    raise EAutoUpdateMissing.CreateFmt(STR_EX_VERSION_INFO_MISSING, [EXEFileName]);
  // Create the information
  VersionInfoFile := TStringList.Create;
  try
    VersionInfoFile.Values[STR_LATEST_VERSION]       := VersionInfoToStr(CurrentVersion);
    VersionInfoFile.Values[STR_UPDATE_URL]           := UpdateURL;
    if Trim(NewVersionInfo) <> '' then
      VersionInfoFile.Values[STR_NEW_VERSION_INFO]     := NewVersionInfo
    else
      VersionInfoFile.Values[STR_NEW_VRESION_INFO_URL] := NewVersionInfoURL;
    // Save the file
    VersionInfoFile.SaveToFile(TargetFileName);
  finally
    VersionInfoFile.Free;
  end;
 
 
end;
 
function AutoUpdate_CheckEXE(EXEFileName, VersionInfoURL: String; Var UpdateURL, NewVersionInfo: String; Var CurrentVersion, Latestversion: TFileVersionInfo): Boolean; overload;
begin
  result := AutoUpdate_CheckEXE(EXEFileName, VersionInfoURL, UpdateURL, NewVersionInfo, CurrentVersion, Latestversion, '','','', 0);
end;
 
function AutoUpdate_CheckEXE(EXEFileName, VersionInfoURL: String; Var UpdateURL, NewVersionInfo: String; Var CurrentVersion, Latestversion: TFileVersionInfo; ProxyServer, ProxyUsername, ProxyPassword: string; ProxyPort: Integer): Boolean; overload;
var
  NewVersionInfoURL: string;
  IdHTTP: TIdHTTP;
  Updatedata: TStringList;
  CurrentVersionStr: String;
begin
  // Get the version info string of the current EXE file
  if EXEFileName='' then
    EXEFileName := Application.ExeName;
  if not GetFileVersion(Application.ExeName, CurrentVersion) then
    raise EAutoUpdateMissing.CreateFmt(STR_EX_VERSION_INFO_MISSING, [EXEFileName]);
 
  CurrentVersionStr := VersionInfoToStr(CurrentVersion);
 
  IdHTTP := TIdHTTP.Create(nil);
  try
    // handle the redirections
    IdHTTP.HandleRedirects := true;
    // Setup the proxy if there is one
    if ProxyServer <> '' then
    begin
      IdHTTP.ProxyParams.ProxyServer := ProxyServer;
      IdHTTP.ProxyParams.ProxyPort := ProxyPort;
      IdHTTP.ProxyParams.ProxyUsername := ProxyUsername;
      IdHTTP.ProxyParams.ProxyPassword := ProxyPassword;
    end;
    // Connect to the page
    Updatedata := TStringList.Create;
    try
      Updatedata.Text := IdHTTP.Get(VersionInfoURL);
      Latestversion   := StrToVersionInfoStr(Updatedata.values[STR_LATEST_VERSION]);
      // Compare the local and remote version information
      result := not AnsiSametext(VersionInfoToStr(Latestversion), CurrentVersionStr);
 
      UpdateURL       := Updatedata.Values[STR_UPDATE_URL];
 
      NewVersionInfo  := Updatedata.Values[STR_NEW_VERSION_INFO];
      if trim(NewVersionInfo)='' then
      begin
        NewVersionInfoURL := Updatedata.Values[STR_NEW_VRESION_INFO_URL];
        if trim(NewVersionInfoURL) <> '' then
        begin
          try
            // statements to try
            NewVersionInfo := IdHTTP.Get(NewVersionInfoURL);
          except
            // Supress all exceptions here: if we cannot get the update info version page, it's no big deal
            on e: Exception do
              NewVersionInfo := Format(STR_CANNOT_GET_NEW_VERSION_DOCUMENT,[NewVersionInfoURL, e.classname, e.Message]);
          end;    // try/except
        end;
      end;
    finally
      Updatedata.Free;
    end;
  finally
    IdHTTP.Free;
  end;
end;
 
// Copyed from WindowsStuff.pas
function GetFileVersion(FileName: string; var FileInfo: TFileVersionInfo): Boolean;
{$IFDEF MSWINDOWS}
var
  Buffer: pointer;
  BufferSize: Cardinal;
  APVSFixedFileInfo: ^TVSFixedFileInfo;
  versionInfoSize: Cardinal;
begin
  result := false;
  BufferSize := GetFileVersionInfoSize(PChar(FileName), versionInfoSize); // Use versionInfoSize as dummy buffer
  if BufferSize > 0 then
  begin
    versionInfoSize := 0;
    Getmem(Buffer, BufferSize);
    try
      if GetFileVersionInfo(PChar(FileName),0, BufferSize, Buffer) then
      begin
        VerQueryValue(Buffer, '\', Pointer(APVSFixedFileInfo), versionInfoSize);
        if APVSFixedFileInfo^.dwSignature = $FEEF04BD then
        begin
          FileInfo.FileVersion[0] := APVSFixedFileInfo^.dwFileVersionMS;
          FileInfo.FileVersion[1] := APVSFixedFileInfo^.dwFileVersionLS;
          FileInfo.ProductVersion[0] := APVSFixedFileInfo^.dwProductVersionMS;
          FileInfo.ProductVersion[1] := APVSFixedFileInfo^.dwProductVersionLS;
          result := true;
        end;
      end
      else
      begin
        result := false;
      end;
    finally
      FreeMem(Buffer);
    end;
  end;
end;
{$ELSE}
begin
  Not implemented... write some code here if you know what to do... then
    
end;
{$ENDIF}
 
end.