Функция с неопределенным количеством аргументов

function summ (a,b,... : integer) : integer;
begin
    result:=a+b+...;
end;

//Подсчёт суммы целочисленных аргументов.
function Sum(const aArr : array of Integer) : Integer;
var
  i : Integer;
begin
  Result := 0;
  for i := 0 to High(aArr) do
    Result := Result + aArr[i];
end;
 
//Пример вызова.
procedure TForm1.Button1Click(Sender: TObject);
var
  N : Integer;
begin
  N := Sum([1, 2, 3]);
  ShowMessage(IntToStr(N));
end;

type
  TData = record
    N : Integer;
    S : String;
  end;
 
{Функция подсчитывает сумму целочисленных аргументов и объединяет строковые
аргументы в одну строку.}
function Calc(const aArr : array of const) : TData;
var
  i : Integer;
begin
  Result.N := 0;
  Result.S := '';
  for i := 0 to High(aArr) do
    case aArr[i].VType of
      vtInteger    : Result.N := Result.N + aArr[i].VInteger;
      vtAnsiString : Result.S := Result.S + aArr[i].VPChar;
    end;
end;
 
//Пример вызова.
procedure TForm1.Button1Click(Sender: TObject);
var
  Data : TData;
begin
  Data := Calc([1, 2, 'ABCD', 3, 'EFGH', 4]);
  ShowMessage('Data.N = ' + IntToStr(Data.N) + #13#10'Data.S = ' + Data.S);
end;