Заново создать закладки в таблице word документа

//Добавление строк в таблицу MS Word на место строки с закладкой.
//Закладка во время обработки удаляется.
function SetBmRows(var aBms : Variant; const aBmName : String; aSg : TStringGrid) : Boolean;
var
  wdBm, wdRng, wdTbls, wdRows, wdRow, wdRowTmp : Variant;
  i, j, Cnt : Integer;
begin
  //Проверяем - существует ли закладка с заданным именем.
  Result := aBms.Exists(aBmName);
  //Если закладка не найдена - выходим.
  if not Result then Exit;
 
  //Ссылка на закладку.
  wdBm := aBms.Item(aBmName);
  //Ссылка на диапазон, связанный с закладкой.
  wdRng := wdBm.Range;
  //Ссылка на коллекцию таблиц.
  wdTbls := wdBm.Parent.Tables;
  //Удаление закладки.
  wdBm.Delete;
 
  //Определеляем, какой таблице принадлежит диапазон закладки.
  wdRow := Unassigned;
  for i := 1 to wdTbls.Count do begin
    if not wdRng.InRange(wdTbls.Item(i).Range) then Continue;
    wdRows := wdTbls.Item(i).Rows;
    //Определяем, какой строке принадлежит диапазон закладки.
    for j := 1 to wdRows.Count do begin
      if not wdRng.InRange(wdRows.Item(j).Range) then Continue;
      wdRow := wdRows.Item(j);
      Break;
    end;
    Break;
  end;
 
  //Добавление строк и заполнение ячеек данными.
  if not VarIsEmpty(wdRow) then begin
    //Запоминаем ссылку на строку с закладкой.
    wdRowTmp := wdRow;
//чет тут пытался я вставить заново-------------------------------------<<<<-
      aBms.Add(aBmName, wdRng);
    for i := aSg.RowCount - 1 downto 0 do begin
      //Добавляем строку сверху над текущей.
      wdRow := wdRows.Add(wdRow);
 
      Cnt := wdRow.Cells.Count;
      //Переписываем данные в ячейки.
      for j := 0 to aSg.ColCount - 1 do begin
 
        //Предусматриваем случай, когда в строке таблицы Word ячеек меньше,
        //чем количество столбцов в aSg.
        if j = Cnt then Break;
        wdRow.Cells.Item(j + 1).Range.Text := aSg.Cells[j, i];
      end;
 
    end;
    //Удаление строки с закладкой.
     wdRows.Item(wdRowTmp.Index).Delete;
 
  end;
 
end;
 
procedure TForm1.Button1Click(Sender: TObject);
var
  wdApp, wdDocs, wdDoc, wdBms : Variant;
  Od : TOpenDialog;
  Path : String;
begin
  Od := OpenDialog1;
  Path := ExtractFilePath(ParamStr(0));
  if Od.InitialDir = '' then Od.InitialDir := Path + 'Templates\';
  Od.Title := 'Выберите файл шаблона для создания нового документа';
  if not Od.Execute then Exit;
  if not FileExists(Od.FileName) then begin
    MessageBox(
      0
      ,'Файл с заданным не найден. Действие отменено.'
      ,'Внимание!'
      ,MB_YESNO + MB_ICONEXCLAMATION + MB_APPLMODAL
    );
    Exit;
  end;
  try
    wdApp := CreateOleObject('Word.Application');
  except
    ShowMessage('Не удалось запустить MS Word. Действие отменено.');
    Exit;
  end;
 
  //Делаем видимым окно MS Word.
  wdApp.Visible := True;
  //Ссылка на коллекцию документов.
  wdDocs := wdApp.Documents;
  //Создаём документ на основе шаблона.
  wdDoc := wdDocs.Add(Template:=Od.FileName);
  //Подключаемся к коллекции закладок.
  wdBms := wdDoc.Bookmarks;
  //Отключение перерисовки окна MS Word. - Для ускорения работы.
  wdApp.ScreenUpdating := False;
  try
    //Ищем закладки с нужными именами и изменяем их содержимое, в соответствие
    //с данными, введёнными на форме.
    SetBmRows(wdBms, 'ROWS1', StringGrid1);
  finally
    //Включение перерисовки окна MS Word.
    wdApp.ScreenUpdating := True;
  end;
end;