Добавление документа Word в ListBox

  public
    { Public declarations }
    ListPath : string; // Вот так, например

procedure TForm1.FormCreate(Sender: TObject);
begin
   ListPath := ExtractFilePath(Application.ExeName) + 'doc.txt';
   ListBox1.Items.LoadFromFile(ListPath); // Везде работай с ее содержимым, а не с явно заданным именем
end;

procedure TFPrikaz.Button6Click(Sender: TObject);
begin
with OpenDialog1 do
      if Execute then
      begin
        sListBox1.Items.Add(FileName)
      end;
end;

sListBox1.Items.Add(ExtractFileName(FileName));

unit Unit3;
 
interface
 
uses
   Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
   Dialogs, StdCtrls;
 
type
  // Класс - перехватчик. Описывается перед классом формы, и имеет
  // то же имя, что и VCL-евский класс TlistBox, поэтому при
  // добавлении на форму TListBox-а у него уже будут
  // методы (можно дописать и свойства, и поля, все что угодно),
  // присутствующие в новом классе. О том, что это за методы - ниже
  TListBox = class(StdCtrls.TListBox)
     procedure Clear; override;
     procedure SaveToFile(const fn : string);
     procedure LoadFromFile(const fn : string);
  end;
 
  TForm3 = class(TForm)
    btnAdd: TButton;
    ListBox1: TListBox;
    btnShow: TButton;
    OpenDialog1: TOpenDialog;
    procedure btnAddClick(Sender: TObject);
    procedure btnShowClick(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
  private
    { Private declarations }
    ListPath : string;
  public
    { Public declarations }
  end;
 
var
  Form3: TForm3;
 
implementation
 
{$R *.dfm}
 
// Это доп. класс, для удобства использования свойства
// Objects. Потому что элемент, добавляемый в это свойство,
// должен быть наследником класса TObject
type
   tsObject = class // все КЛАССЫ - потомки TObject
      FullPath : string;
      constructor Create(s : string);
   end;
 
{ tsObject }
constructor tsObject.Create(s: string);
begin
   FullPath := s;
end;
 
// Добавляем новый файл в листбокс
procedure TForm3.btnAddClick(Sender: TObject);
var s : string;
begin
   if OpenDialog1.Execute then
   begin
      s := OpenDialog1.FileName;
      ListBox1.Items.AddObject(ExtractFileName(s), TObject(tsObject.Create(s)));
   end;
end;
 
// Показываем, что на самом деле хранится в выбранном
// поле листбокса. По аналогиии можно сделать и запуск этого
// файла, и удаление
procedure TForm3.btnShowClick(Sender: TObject);
begin
   ShowMessage(tsObject(ListBox1.Items.Objects[ListBox1.ItemIndex]).FullPath);
end;
 
// При уничтожении формы сохраняем всю информацию в файл
// (заметь, используется добавленный к ListBox-у метод SaveToFile,
// а не стандартный Items.SaveToFile, потому что второй запишет
// опять же только имена, без путей) и очищаем ListBox (если этого
// не сделать - будет утечка памяти, потому что к его содержимому
// добавлялись объекты, которые сами по себе не удалятся, это надо
// сделать программисту)
procedure TForm3.FormClose(Sender: TObject; var Action: TCloseAction);
begin
   ListBox1.SaveToFile(ListPath);
   ListBox1.Clear;
end;
 
// При старте - составляем имя txt-файла, с которым будем работать,
// и читаем из него в ListBox, используя добавленный метод LoadFromFile,
// вместо Items.LoadFromFile
procedure TForm3.FormCreate(Sender: TObject);
begin
   ListPath := ExtractFilePath(Application.ExeName) + 'doc.txt';
   ListBox1.LoadFromFile(ListPath);
end;
 
 
{ TListBox }
// Теперь - о том, что делается в добавленных методах
 
// 1. Этот метод перекрывает стандартный Clear. Потому что
// нам теперь при очистке нужно не только сделать все то, что
// делалось раньше, но и удалить все добавленные Object-ы
procedure TListBox.Clear;
var i : integer;
begin
   // Вот мы их удаляем
   for i := 0 to Count - 1 do
      Items.Objects[i].Free;
   // А потом вызываем стандартный Clear
   inherited;
end;
 
// 2. Для чтения данных мы должны сделать нечто другое.
// Если просто прочесть содержимое файла в Items, то ListBox
// опять будет содержать полные пути. Поэтому:
procedure TListBox.LoadFromFile(const fn: string);
var
   i : integer;
   sL : TStringList;
begin
   // Читаем файл во временный TStringList
   sL := TStringList.Create;
   try
      sL.LoadFromFile(fn);
      // и каждый его элемент записываем в ListBox. Имя - в Items,
      // а полный путь - в Objects
      for i := 0 to sL.Count - 1 do
      begin
         Items.AddObject(ExtractFileName(sL[i]), TObject(tsObject.Create(sL[i])));
      end;
   finally
      FreeAndNil(sL); // Все, временный список больше не нужен
   end;
end;
 
// 3. При записи из ListBox-а в нужно сделать то же самое, что
// и при чтении. Записывать не содержимое Items, а содержимое
// Objects
procedure TListBox.SaveToFile(const fn: string);
var
   i : integer;
   sL : TStringList;
begin
   sL := TStringList.Create;
   try
      for i := 0 to Count - 1 do
         sL.Add(tsObject(Items.Objects[i]).FullPath);
      sL.SaveToFile(fn);
   finally
      FreeAndNil(sL);
   end;
end;
 
end.