Помощь c CheckListBox. TDBCheckBox в TDBGrid.

procedure TForm1.CheckListBox1Click(Sender: TObject);
begin
  Memo1.Lines.Add(CheckListBox1.Items[CheckListBox1.ItemIndex]);
end;

uses
  StrUtils;
 
//Создание экземпляра формы.
procedure TForm1.FormCreate(Sender: TObject);
const
  Fn = 'Db\db-01.mdb';
var
  FileName : String;
begin
  //Полный путь к файлу базы данных. Этот файл располагается в папке "Db".
  //А папка "Db" расположена в той же папке, где лежит исполняемый файл программы.
  FileName := ExtractFilePath(ParamStr(0)) + Fn;
  //Проверяем существование файла.
  if not FileExists(FileName) then begin
    MessageBox(
      0
      ,'Файл с именем "' + Fn + '" не найден. Подключение к базе данных не настроено.'
      ,'Ошибка!'
      ,MB_OK + MB_ICONERROR + MB_APPLMODAL
    );
    Exit;
  end;
  //Добавляем в строку соединения сведения о пути к файлу базы данных.
  ADOTable1.ConnectionString :=
    ADOTable1.ConnectionString + ';Data Source=' + FileName;
end;
 
//Закрытие формы.
procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  if not (ADOTable1.Active and ADOTable1.Modified) then Exit;
 
  ADOTable1.Post;
  ADOTable1.Close;
end;
 
//Кнопка соединения/отключения с базой данных.
procedure TForm1.Button1Click(Sender: TObject);
var
  Btn : TButton;
begin
  Btn := Sender as TButton;
  ADOTable1.Active := not ADOTable1.Active;
  if ADOTable1.Active then
    Btn.Caption := 'Отключить'
  else
    Btn.Caption := 'Подключить';
  DBCheckBox1.Visible := False;
end;
 
//Прорисовка ячейки.
procedure TForm1.DBGrid1DrawColumnCell(Sender: TObject; const Rect: TRect;
  DataCol: Integer; Column: TColumn; State: TGridDrawState);
var
  Dbg : TDBGrid;
begin
  //Если на ячейке не установлен фокус ввода, то выходим.
  if not (gdFocused in State) then Exit;
 
  Dbg := Sender as TDBGrid;
  //Если ячейка принадлежит тому полю, с которым связан DBCheckBox1.
  if Column.FieldName = DBCheckBox1.DataField then begin
    //Вписываем DBCheckBox1 в область ячейки.
    DBCheckBox1.Left := Dbg.Left + Rect.Left + 2;
    DBCheckBox1.Top := Dbg.Top + Rect.Top + 2;
    DBCheckBox1.Height := Rect.Bottom - Rect.Top;
    DBCheckBox1.Width := Rect.Right - Rect.Left;
    //Выводим значение поля.
    DBCheckBox1.Caption := DBCheckBox1.Field.AsString;
    //Делаем DBCheckBox1 видимым.
    DBCheckBox1.Visible := True;
  end;
end;
 
//Уход фокуса ввода с ячейки.
procedure TForm1.DBGrid1ColExit(Sender: TObject);
var
  Dbg : TDBGrid;
begin
  Dbg := Sender as TDBGrid;
  if Dbg.SelectedField.FieldName = DBCheckBox1.DataField then
    DBCheckBox1.Visible := False; //Прячем DBCheckBox1.
end;
 
//Обработка нажатий клавиш в DBGrid1.
procedure TForm1.DBGrid1KeyDown(Sender: TObject; var Key: Word;
  Shift: TShiftState);
var
  Dbg : TDBGrid;
begin
  Dbg := Sender as TDBGrid;
  if Dbg.SelectedField.FieldName <> DBCheckBox1.DataField then Exit;
 
  //Если нажата клавиша, не связанная с навигацией, то передаём нажатие
  //в DBCheckBox1.
  case Key of
    VK_TAB, VK_UP, VK_DOWN, VK_LEFT, VK_RIGHT : ;
    else
      SendMessage(DBCheckBox1.Handle, WM_CHAR, Integer(Key), 0);
  end;
end;
 
//Щелчок на DBCheckBox1.
procedure TForm1.DBCheckBox1Click(Sender: TObject);
begin
  if SendMessage(DBCheckBox1.Handle, BM_GetCheck, 0, 0) = 0 then
    DBCheckBox1.Caption := 'Нет'
  else
    DBCheckBox1.Caption := 'Да';
  //Возвращаем фокус ввода на DBGrid1.
  DBGrid1.SetFocus;
end;

uses
  StrUtils;
 
//Создание экземпляра формы.
procedure TForm1.FormCreate(Sender: TObject);
const
  Fn = 'Db\db-01.mdb';
var
  FileName : String;
begin
  //Полный путь к файлу базы данных. Этот файл располагается в папке "Db".
  //А папка "Db" расположена в той же папке, где лежит исполняемый файл программы.
  FileName := ExtractFilePath(ParamStr(0)) + Fn;
  //Проверяем существование файла.
  if not FileExists(FileName) then begin
    MessageBox(
      0
      ,'Файл с именем "' + Fn + '" не найден. Подключение к базе данных не настроено.'
      ,'Ошибка!'
      ,MB_OK + MB_ICONERROR + MB_APPLMODAL
    );
    Exit;
  end;
  //Добавляем в строку соединения сведения о пути к файлу базы данных.
  ADOTable1.ConnectionString :=
    ADOTable1.ConnectionString + ';Data Source=' + FileName;
end;
 
//Закрытие формы.
procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  if not (ADOTable1.Active and ADOTable1.Modified) then Exit;
 
  ADOTable1.Post;
  ADOTable1.Close;
end;
 
//Кнопка соединения/отключения с базой данных.
procedure TForm1.Button1Click(Sender: TObject);
var
  Btn : TButton;
begin
  Btn := Sender as TButton;
  ADOTable1.Active := not ADOTable1.Active;
  if ADOTable1.Active then
    Btn.Caption := 'Отключить'
  else
    Btn.Caption := 'Подключить';
end;
 
//Кнопка "Скопировать в список".
procedure TForm1.Button2Click(Sender: TObject);
var
  Tbl : TADOTable;
  Chl : TCheckListBox;
  Bm : TBookmark;
  i : Integer;
begin
  Tbl := ADOTable1;
  Chl := CheckListBox1;
  Chl.Clear;
  if not Tbl.Active then Exit;
 
  //Ставим закладку в текущем месте набора данных.
  Bm := Tbl.GetBookmark;
  //Отключаем показ данных на время перебора записей.
  ADOTable1.DisableControls;
  //Копируем данные из набора данных в чеклист.
  Tbl.First;
  while not Tbl.Eof do begin
    //Добавляем в список пару: строка-объект, где под видом указателя на объект
    //передаём значение из поля "id".
    i := Chl.Items.AddObject(
      Tbl.FieldByName('family').AsString
        + ' ' + Tbl.FieldByName('name').AsString
        + ' ' + Tbl.FieldByName('fname').AsString
      ,TObject(Tbl.FieldByName('id').AsInteger)
    );
    Chl.Checked[i] := Tbl.FieldByName('check').AsBoolean;
    Tbl.Next;
  end;
  //Возвращаемся к закладке.
  Tbl.GotoBookmark(Bm);
  //Включаем показ данных.
  ADOTable1.EnableControls;
end;
 
//Кнопка "Скопировать в базу".
procedure TForm1.Button3Click(Sender: TObject);
var
  Tbl : TADOTable;
  Chl : TCheckListBox;
  Bm : TBookmark;
  i : Integer;
begin
  Tbl := ADOTable1;
  Chl := CheckListBox1;
  if not Tbl.Active then Exit;
 
  //Ставим закладку в текущем месте набора данных.
  Bm := Tbl.GetBookmark;
  //Отключаем показ данных на время перебора записей.
  ADOTable1.DisableControls;
  //Копируем данные списка в набор данных.
  Tbl.First;
  while not Tbl.Eof do begin
    i := Chl.Items.IndexOfObject( TObject(Tbl.FieldByName('id').AsInteger) );
    if i <> -1 then begin
      Tbl.Edit;
      Tbl.FieldByName('check').AsBoolean := Chl.Checked[i];
    end;
    Tbl.Next;
  end;
  //Возвращаемся к закладке.
  Tbl.GotoBookmark(Bm);
  //Включаем показ данных.
  ADOTable1.EnableControls;
end;