Анализ Текста

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;
 
type
  TForm1 = class(TForm)
    Memo1: TMemo;
    Button1: TButton;
    OpenDialog1: TOpenDialog;
    Memo2: TMemo;
    Label1: TLabel;
    Label2: TLabel;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
 
type
  TArrStat = array[AnsiChar] of Integer;
 
//Функция возвращает размер файла в байтах и выполняет подсчёт в этом файле
//количества присутствий каждого однобайтного символа (AnsiChar).
//Собранные сведения записываются в массив aArr.
function Calc(const aFileName : String; var aArr : TArrStat) : Integer;
const
  BuffSize = 100000; //Размер буфера в байтах.
var
  F : File;
  S : AnsiString; //Буфер.
  Ch : AnsiChar;
  i, Cnt : Integer;
begin
  //Связываем файловую переменную с именем файла.
  AssignFile(F, aFileName);
  //Открываем файл в режиме чтение/запись с наименьшим размером блока в 1 байт.
  Reset(F, 1);
  Result := FileSize(F);
  //Обнуление массива статистики.
  for Ch := #0 to #255 do aArr[Ch] := 0;
  //Размещаем буфер в памяти (выделяем память для строки).
  SetLength(S, BuffSize);
  //Продолжаем цикл чтения, пока не обнаружен конец файла.
  while not Eof(F) do begin
    //Пытаемся прочитать из файла в буфер (в строку S) BuffSize наименьших блоков.
    //Размер наименьшего блока у нас равен 1 байт. Такой же размер имеет один
    //символ AnsiChar. Т. е., мы пытаемся прочитать BuffSize символов AnsiChar
    //в строку S.
    //Cnt - это реальное количество прочитанных символов. Cnt может быть равен
    //или меньше, чем BuffSize. Например, в данном случае, если от текущей позиции
    //до конца файла располагается 10 символов, то при вызове BlockRead() в строку
    //S будет прочитано 10 символов, и значение Cnt станет равным 10.
    BlockRead(F, S[1], BuffSize, Cnt);
 
    //Собираем статистику по прочитанным символам.
    for i := 1 to Cnt do
    if (s[i]<>#9)and(s[i]<>#13)and(s[i]<>#10)
    then
    Inc(aArr[S[i]]);
  end;
  //Закрываем файл.
  CloseFile(F);
end;
 
procedure TForm1.Button1Click(Sender: TObject);
var
  Arr : TArrStat;
  Size : Integer;
  Ch : AnsiChar;
  Od : TOpenDialog;
 
begin
 
  Od := OpenDialog1; //OpenDialog1 уже должен быть на форме.
  if Od.InitialDir = '' then
    Od.InitialDir := ExtractFilePath( ParamStr(0) );
  if not Od.Execute then Exit;
  if not FileExists(Od.FileName) then begin
    MessageBox(0, 'Файл с заданным именем не найден. Действие отменено.'
      ,'Файл не найден', MB_OK + MB_ICONEXCLAMATION + MB_APPLMODAL);
    Exit;
  end;
 
 Memo2.Lines.LoadFromFile(Od.FileName) ;
 
 
  //Сбор статистики.
  Size := Calc(Od.FileName, Arr);
  //Распечатка результатов в Мемо.
 
 
  Memo1.Lines.Add('------------------------------');
  Memo1.Lines.Add('Файл: ' + Od.FileName);
  Memo1.Lines.Add('Размер файла: ' + IntToStr(Size));
  Memo1.Lines.Add('#<Код>: <Частота> / <Количество присутствий>');
 
  for Ch := #0 to #255 do
  if Arr[Ch]<>0 then
  Memo1.Lines.Add('#' + IntToStr(Byte(Ch))
      + ':'#9 + FormatFloat('0.000000000000', Arr[Ch] / Size)
      + ' / ' + IntToStr(Arr[Ch])+#9+'('+Ch+')');
 
end;
 
end.