Не получается получить данные из динамической библиотеки, написанной на FASM...

format PE GUI 4.0 DLL   ;Формат исполняемого файла DLL
entry hwEntry                  ;Инициализация DLL. Функция DllEntryPoint
include 'win32ax.inc'     ;Нужна для создания DLL.
 
  ;Этот макрос возвращает указатель на таблицу функций в fnTblPtr
   macro GetFnTblPtr envPtr, fnTblPtr
   {
    mov ebx, [envPtr]      ;envPtr адрес таблицы функций
    mov eax, [ebx]
    mov [fnTblPtr], eax
   }
 
  ;Этот макрос возвращает указатель на нужную функцию
   macro GetFnPtr fnTblPtr, index, fnPtr
   {
    mov eax, index          ;Номер функции
    mov ebx, 4                 ;Делитель
    mul ebx                      ;Умножает номер функции на 4 (размер функции 4 байта)
    mov ebx, [fnTblPtr]   ;Указатель на таблицу функций
    add ebx, eax              ;Добавляет к началу таблицы функций номер нужной
    mov eax, [ebx]
    mov [fnPtr], eax        ;FnPtr = адрес нужной функции
   }
 
section ".data" data readable writable
  Caption  db 'Native',0
  Message1 db 'Данные обнаруженны',0
  Message2 db 'Данные отсутствуют',0
 
section '.text' code readable executable
 
  proc hwEntry hinstDLL,fdwReason,lpvReserved
    mov eax, TRUE
    ret
  endp
 
 
proc Java_HelloJNI_sumAndAverage JNIEnv, jobject, jintArray
  local fnptr             :DWORD   ;Адрес нужной JNI функции
  local fntblptr        :DWORD   ;Указатель на таблицу функций
  local JavaMas     :DWORD   ;Полученный массив
  local LengthMas :DWORD   ;Полученная длина массива
  local OutMas       :DWORD   ;Массив для отправки в Java. Ни знаю какой должен быть размер в FASM.
 
  ;Вызовы макросов с передачей параметров
  GetFnTblPtr JNIEnv, fntblptr     ;Возвращает указатель на таблицу функций в fnTblPtr
  GetFnPtr fntblptr, 187, fnptr      ;187 - GetIntArrayElements
 
  ;GetIntArrayElements
   push 0                           ;3-isCopy
   push [jintArray]            ;2-Строковый объект Java
   push [JNIEnv]               ;1-Указатель интерфейса JNI
  call [fnptr]                       ;Вызов JNI функции GetIntArrayElements
   mov [JavaMas], eax    ;Сохраняет указатель на элементы массива (возвращает не 0)
 
 ;GetArrayLength
  GetFnPtr fntblptr, 171, fnptr    ;Макрос
   push [jintArray]                  ;Указатель на элементы массива
   push [JNIEnv]                     ;Указатель интерфейса JNI
  call [fnptr]                             ;Конвертирует массив, возвращает количество элементов массива
   mov [LengthMas], eax      ;Длина массива (возвращает 3)
 
 
;--- Проверка наличия данных в массиве ---
    cmp [JavaMas], 123    ;123 Первый элемент массива Java
     jne m0
    invoke MessageBox, 0, addr Message1, Caption, 0   ;Есть
    jmp m1
m0: invoke MessageBox, 0, addr Message2, Caption, 0   ;Нету
m1:
    ;При запуске java проекта выводится сообщение Message2 (123 нету)
;-------- Конец проверки ---------
 
;ReleaseIntArrayElements
  GetFnPtr fntblptr, 195, fnptr    ;Макрос
   push 0                     ;4-Mode
   push [JavaMas]     ;3-Указатель на массив элементов
   push [jintArray]      ;2-Объект массива Java
   push [JNIEnv]         ;1-Указатель интерфейса JNI
  call [fnptr]                 ;Нативный код больше не нуждается в доступе к elems (Возвращает не 0)
                                     ;При необходимости, эта функция копирует все изменения, внесённые elems в исходный массив.
 
;NewIntArray()
  GetFnPtr fntblptr,179, fnptr   ;Макрос
   push [LengthMas]      ;2-Длина массива
   push [JNIEnv]              ;1-Указатель интерфейса JNI
   call [fnptr]                     ;Возвращает массив Java
   mov [OutMas],eax
 
;SetIntArrayRegion
  GetFnPtr fntblptr, 211, fnptr   ;Макрос
   push [jintArray]        ;5-Исходный буфер
   push [LengthMas]   ;4-Число элементов, которые будут скопированы
   push 0                       ;3-Начальный индекс
   push [OutMas]         ;2-Массив Java
   push [JNIEnv]          ;1-Указатель интерфейса JNI
   call [fnptr]                 ;Копирует обратно область примитивного массива из буфера.   
 
 ;После вызова SetIntArrayRegion функции,  Java пишет:
  ;Exception in thread “Main” java.lang.NullPointerException
  ;          at HelloJNI.sumAndAverage(Native Method)
  ;          at HelloJNI.main(HelloJNI.java:12)
ret
endp
 
section '.idata' import data readable writeable
  library kernel, 'KERNEL32.DLL', user, 'USER32.DLL'
  import user, MessageBox, 'MessageBoxA'
 
section 'edata' export data readable
 export 'MasDll.DLL', \
  Java_HelloJNI_sumAndAverage,'Java_HelloJNI_sumAndAverage'             
 
section '.reloc' fixups data discardable

cmp [JavaMas], 123

mov eax,[JavaMas]
cmp dword[eax], 123

proc Java_HelloJNI_sumAndAverage __JNIEnv: DWORD, jobject, jintArray
  local elem rd 1
  local len  rd 1
 
  virtual at __JNIEnv
  _JNIEnv JNIEnv
  end virtual
 
  cominvk _JNIEnv,GetIntArrayElements,[jintArray],0
  mov     [elem],eax
  cominvk _JNIEnv,GetArrayLength,[jintArray]
  mov     [len],eax
  cominvk _JNIEnv,NewIntArray,eax
  push    eax
  cominvk _JNIEnv,SetIntArrayRegion,eax,0,[len],[elem]
  cominvk _JNIEnv,ReleaseIntArrayElements,[jintArray],[elem],2
  pop     eax
 
ret
  call [MessageBoxW] ;Без этого не создаётся таблица импорта и Java не хочет загружать DLL
endp