Внутренности кода на Ассемблере (оконное приложение)

format PE GUI 4.0                                                ; 32-разрЯдное оконное приложение WINDOWS EXE
entry start                                                      ; точка входа
 
include 'include\win32a.inc'
 
ID_CAPTION = 101                                                 ; идентификаторы текстовых полей ввода и кнопок
ID_MESSAGE = 102
ID_OK = 103
ID_CANCEL = 104
 
section '.text' code readable executable                         ; секциЯ кода
 
  start:
        invoke GetModuleHandle,0                                     ; получить уникальный идентификатор активного программного модулЯ
        invoke DialogBoxParam,eax,0,HWND_DESKTOP,DialogProc,0        ; запустить цикл обработки сообщений для сктивного программного модулЯ
        or eax,eax                                                   ; если диалог вернул 1 то...
        jz exit
        invoke MessageBox,HWND_DESKTOP,message,caption,0             ; ...вывести сообщение
  exit:
        invoke ExitProcess,0                                         ; завершить выполнение программы
 
proc DialogProc hwnddlg,msg,wparam,lparam                        ; оконнаЯ функциЯ обработки сообщений
        push ebx esi edi
        cmp     [msg],WM_INITDIALOG                                      ; сообщение предшествующее оторажению окна
        je      .wminitdialog
        cmp     [msg],WM_COMMAND                                         ; сообщение отправлЯемое при нажатии на кнопки, меню и т.п.
        je      .wmcommand
        cmp     [msg],WM_CLOSE                                           ; сообщение отправлЯемое перед закрытием окна
        je      .wmclose
        xor     eax,eax                                                  ; если сообщение не обработано возвращаем 0
        jmp     .finish
  .wminitdialog:
        jmp     .processed
  .wmcommand:
        cmp     [wparam],BN_CLICKED shl 16 + ID_CANCEL                   ; если нажата кнопка CANCEL
        je      .wmclose
        cmp     [wparam],BN_CLICKED shl 16 + ID_OK                       ; если нажата кнопка OK
        jne     .processed
        invoke GetDlgItemText,[hwnddlg],ID_CAPTION,caption,40h       ; получение текста заголовка
        invoke GetDlgItemText,[hwnddlg],ID_MESSAGE,message,100h      ; получение текста сообщениЯ
        invoke EndDialog,[hwnddlg],1                                 ; закрыть окно и вернуть вызвавшей программе 1
        jmp     .processed
  .wmclose:
        invoke EndDialog,[hwnddlg],0                                 ; закрыть окно и вернуть вызвавшей программе 0
  .processed:
        mov     eax,1                                                    ; если сообщение обработано возвращаем 1
  .finish:
        pop     edi esi ebx
        ret
endp
 
section '.bss' readable writeable                                ; секциЯ данных
 
  caption rb 40h                                                 ; строки длЯ хранениЯ заголовка и сообщения
  message rb 100h
 
section '.idata' import data readable writeable                  ; секциЯ импортируемых функций
 
  library kernel,'KERNEL32.DLL',\
          user,'USER32.DLL'
 
  import kernel,\
         GetModuleHandle,'GetModuleHandleA',\
         ExitProcess,'ExitProcess'
 
  import user,\
         DialogBoxParam,'DialogBoxParamA',\
         GetDlgItemText,'GetDlgItemTextA',\
         MessageBox,'MessageBoxA',\
         EndDialog,'EndDialog'
 
section '.rsrc' resource data readable                           ; секциЯ объЯвлениЯ ресурсов
 
  directory RT_DIALOG,dialogs
 
  resource dialogs,0,LANG_ENGLISH+SUBLANG_DEFAULT,demonstration
 
  dialog demonstration,'Lab6 example',70,70,190,105,WS_CAPTION+WS_POPUP+WS_SYSMENU+DS_MODALFRAME
    dialogitem 'STATIC','&Caption:',-1,10,10,70,8,WS_VISIBLE
    dialogitem 'EDIT','',ID_CAPTION,10,20,170,13,WS_VISIBLE+WS_BORDER+WS_TABSTOP
    dialogitem 'STATIC','&Message:',-1,10,40,70,8,WS_VISIBLE
    dialogitem 'EDIT','',ID_MESSAGE,10,50,170,13,WS_VISIBLE+WS_BORDER+WS_TABSTOP+ES_AUTOHSCROLL
    dialogitem 'BUTTON','OK',ID_OK,85,80,45,15,WS_VISIBLE+WS_TABSTOP+BS_DEFPUSHBUTTON
    dialogitem 'BUTTON','C&ancel',ID_CANCEL,135,80,45,15,WS_VISIBLE+WS_TABSTOP+BS_PUSHBUTTON
  enddialog

 cmp     [wparam],BN_CLICKED shl 16 + ID_CANCEL

caption rb 40h
message rb 100h

 cmp     [wparam],BN_CLICKED shl 16 + ID_CANCEL

caption rb 40h
message rb 100h