Указатель и очередь

type plinkone=^tlinkone;
      tlinkone=record
      data:real;
      adress:plinkone;
 Procedure AddONELinkedQueue1(var head,tail:plinkone;value:real);//2 adress 1 connectivity
 var temp:plinkone;
 begin
   new(temp);
   temp^.data:=value;
   temp^.adress:=nil;
   if head=nil then
   begin
     head:=temp;
     tail:=head;
   end
   else
   begin
     tail^.adress:=temp;
     tail:=temp;
   end;
 end;

program Project1;
 
type
  {Тип основных данных.}
  TData = Integer;
  {Тип указателя на элемент очереди.}
  TPElem = ^TElem;
  {Тип элемента очереди.}
  TElem = record
    Data : TData;   {Основные данные.}
    PNext : TPElem; {Указатель на следующий элемент очереди.}
  end;
  {Тип, определяющий очередь.}
  TQueue = record
    PFirst, PLast : TPElem; {Указатели на первый и на последний элементы очереди.}
  end;
 
{Начальная инициализация очереди. Внимание! Эту процедуру можно выполнять
только в отношении пустой очереди. Иначе будут утечки памяти.
Если очередь непустая, то следует применить вызов QFree().}
procedure Init(var aQ : TQueue);
begin
  aQ.PFirst := nil;
  aQ.PLast := nil;
end;
 
{Добавление элемента в конец очереди.}
procedure Push(var aQ : TQueue; const aData : TData);
var
  P : TPElem;
begin
  New(P);           {Выделение памяти для элемента.}
  P^.Data := aData; {Записываем основные данные.}
  P^.PNext := nil;  {Т. к., элемент добавляется в конец очереди, то указатель на следующий элемент = NIL.}
  if aQ.PFirst = nil then {Если очередь пустая, то новый элемент становится первым элементом очереди.}
    aQ.PFirst := P
  else                    {Если очередь непустая, то новый элемент прикрепляем к последнему элементу очереди.}
    aQ.PLast^.PNext := P;
  aQ.PLast := P; {Добавленный элемент становится последним элементом очереди.}
end;
 
{Изъятие элемента из начала очереди. Если очередь непустая, то
из начала очереди извлекается элемент и его значение возвращается
через параметр aData. В этом случае функция возвращает True.
Если очередь пустая, то операция отменяется и функция возвращает False.}
function Pop(var aQ : TQueue; var aData : TData) : Boolean;
var
  P : TPElem;
begin
  Result := False;
  P := aQ.PFirst;
  if P <> nil then
  begin
    aData := P^.Data;       {Читаем данные первого элемента очереди.}
    aQ.PFirst := P^.PNext;  {Первым элементом очереди становится тот элемент, который раньше был вторым.}
    if aQ.PFirst = nil then {Если очередь оказалась пустой, то инициализируем её.}
      Init(aQ);
    Dispose(P);             {Освобождаем память, занятую для элемента.}
    Result := True;
  end;
end;
 
{Освобождение памяти, выделенной для элементов очереди (очистка очереди).}
procedure QFree(var aQ : TQueue);
var
  Data : TData;
begin
  while Pop(aQ, Data) do;
end;
 
{Распечатка очереди в направлении: начало - конец.}
procedure QWriteln(const aQ : TQueue);
var
  P : TPElem;
begin
  P := aQ.PFirst;
  if P <> nil then
  repeat
    if P <> aQ.PFirst then {Если это не первый элемент очереди, то ставим перед ним запятую.}
      Write(', ');
    Write(P^.Data); {Распечатка основных данных элемента.}
    P := P^.PNext;  {Указатель на следующий элемент.}
  until P = nil
  else
    Write('Очередь пуста.');
  Writeln;
end;
 
const
  M = 15; {Количество элементов, которые мы добавим в очередь.}
var
  Q1, Q2, Q3 : TQueue;
  Data : TData;
  i : Integer;
  S : String;
begin
  {Начальная инициализация очередей.}
  Init(Q1);
  Init(Q2);
  Init(Q3);
 
  repeat
    {Добавление элементов в первую очередь.}
    Randomize;
    for i := 1 to M do
      Push(Q1, -9 + Random(19)); {Целые числа из диапазона -9..9.}
 
    {Распечатка очередей.}
    Writeln('--------------------');
    Writeln('Начальное состояние очередей:');
    Writeln('Первая очередь (начало - конец):');
    QWriteln(Q1);
    Writeln('Вторая очередь (начало - конец):');
    QWriteln(Q2);
    Writeln('Третья очередь (начало - конец):');
    QWriteln(Q3);
 
    {Теперь будем последовательно извлекать элементы из начала первой очереди.
    И те из них, которые являются неотрицательными, запишем во вторую очередь,
    а все остальные (т. е., отрицательные) - в третью очередь.}
    while Pop(Q1, Data) do
      if Data >= 0 then
        Push(Q2, Data)
      else
        Push(Q3, Data);
 
    {Распечатка очередей.}
    Writeln('-----');
    Writeln('Состояние очередей после обработки:');
    Writeln('Первая очередь (начало - конец):');
    QWriteln(Q1);
    Writeln('Вторая очередь (начало - конец):');
    QWriteln(Q2);
    Writeln('Третья очередь (начало - конец):');
    QWriteln(Q3);
 
    {Освобождение памяти, выделенной для элементов очередей.}
    QFree(Q1);
    QFree(Q2);
    QFree(Q3);
    Writeln('-----');
    Writeln('Память, выделенная для очередей, освобождена.');
 
    Writeln('Повторить - Enter, выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.