Возможно ли в паскале (точнее, в Crt) сохранение всего видимого текста с консоли напрямую

unit menu_unit; // не ругайте код, я таки студент, да и код старый))
//-------------------------------------------------------------
interface
 
function menu(nazvanie: string; const p: array of string): integer;
//-------------------------------------------------------------
implementation
uses
   crt;
 
function menu(nazvanie: string; const p: array of string): integer;
var
   i, tek: integer;
   ch: char;
begin
   textbackground(black);
   textcolor(lightgray);
   tek := 0;
 
   repeat
   clrscr;
   writeln(nazvanie);
   for i := 0 to high(p) do
      if i = tek then
      begin
         textbackground(lightgray);
         textcolor(black);
         write(p[i]);
         clreol;
         textbackground(black);
         textcolor(lightgray);
         writeln;
      end
      else
         writeln(p[i]);
   writeln;
 
   ch := readkey;
   if ch <> #0 then
      continue;
   ch := readkey;
   if ch = #80 then
      tek := (tek + 1) mod length(p)
   else if ch = #72 then
      tek := (length(p) + tek - 1) mod length(p);
   until ch = #13;
 
   menu := tek;
end;
//-------------------------------------------------------------
begin end.

uses windows,crt;
var
  hStdout,hNewScreenBuffer:Handle;
  Security: TSecurityAttributes;
  srctReadRect,srctWriteRect:TSMALL_RECT;
  coordBufSize,coordBufCoord:TCOORD;
  chiBuffer:array of TCHAR_INFO;
  Info: TConsoleScreenBufferInfo;
  i,j:integer;
  a:array of string; //элементы меню
function menu(Items:array of string;x1,y1,x2,y2,color:integer):integer; //меню
var
  i,j,k:integer;
  c:char;
begin
  cursoroff;
  window(1,1,80,25);
  textbackground(Color);
  textcolor(White);
  for i:=1 to x2-x1+1 do begin
    gotoxy(x1-1+i,y1-1);write('-');
    gotoxy(x1-1+i,y2+1);write('-');
  end;
  for i:=1 to y2-y1+1 do begin
    gotoxy(x1-1,y1-1+i);write('|');
    gotoxy(x2+1,y2-i+1);write('|');
  end;
  gotoxy(x1-1,y1-1);write('+');
  gotoxy(x1-1,y2+1);write('+');
  gotoxy(x2+1,y1-1);write('+');
  gotoxy(x2+1,y2+1);write('+');
  window(x1,y1,x2,y2);
  clrscr;
  i:=0;
  k:=x2-x1;
  repeat
    for j:=low(Items) to High(Items) do begin
      if j=i then begin
        textbackground(LightBlue);
        textcolor(LightRed);
      end else begin
        textbackground(color);
        textcolor(White);
       end;
       gotoxy(k div 2-length(Items[j]) div 2,1+j);
     write(Items[j]);
    end;
    c:=readkey;
    if c=#0 then begin
      c:=readkey;
      case ord(c) of
        72: if i>low(Items)  then i:=i-1 else i:=high(Items);
        80: if i<High(Items) then i:=i+1 else i:=low(Items);
      end;
    end;
  until c=#13;
  cursoron;
  menu:=i;
end;
 
procedure MScreen(B:boolean);//если true - записываем экран, false - восстанавливает 
//списано с MSDN  [url]https://msdn.microsoft.com/ru-ru/library/windows/desktop/ms685032(v=vs.85).aspx[/url]
begin
  FillChar(Security, SizeOf(Security), 0);
  hStdout:=GetStdHandle(STD_OUTPUT_HANDLE);
  GetConsoleScreenBufferInfo(hStdout, @Info);
  hNewScreenBuffer:=CreateConsoleScreenBuffer(
    GENERIC_READ or
    GENERIC_WRITE,
    FILE_SHARE_READ or
    FILE_SHARE_WRITE,
    Security,
    CONSOLE_TEXTMODE_BUFFER,
    nil);
    if (hStdout=INVALID_HANDLE_VALUE) or
       (hNewScreenBuffer=INVALID_HANDLE_VALUE) then
       begin
         writeln('CreateConsoleScreenBuffer failed - ',GetLastError);
         halt(1);
       end;
     if (not SetConsoleActiveScreenBuffer(hNewScreenBuffer)) then
     begin
       writeln('SetConsoleActiveScreenBuffer failed - ', GetLastError);
        halt(1);
     end;
   srctReadRect.Top:=0;    
   srctReadRect.Left:=0;
   srctReadRect.Bottom:=Info.dwSize.Y; 
   srctReadRect.Right:=Info.dwSize.X;
   srctWriteRect.Top:=0;    
   srctWriteRect.Left:=0;
   srctWriteRect.Bottom:=Info.dwSize.Y;
   srctWriteRect.Right:=Info.dwSize.X;
   coordBufSize.Y:=Info.dwSize.Y;
   coordBufSize.X:=Info.dwSize.X;
   coordBufCoord.X:=0;
   coordBufCoord.Y:=0;
   if b then begin
     setlength(chiBuffer,Info.dwSize.Y*Info.dwSize.X);
   if not ReadConsoleOutput(
     hStdout,
     @chiBuffer[0],
     coordBufSize,
     coordBufCoord,
     srctReadRect) then
     begin
       writeln('ReadConsoleOutput failed -',GetLastError);
       halt(1);
     end;
  end else
  if not  WriteConsoleOutput(
    hStdOut,
    @chiBuffer[0],
    coordBufSize,
    coordBufCoord,
    srctWriteRect) then
    begin
      writeln('WriteConsoleOutput failed - ',GetLastError);
      halt(1);
    end;
   if (not SetConsoleActiveScreenBuffer(hStdout)) then
     begin
       writeln('SetConsoleActiveScreenBuffer failed - ', GetLastError);
        halt(1);
     end;
end;
procedure musor; //просто генератор мусора на экране тут может быть какой-то текст
var
  i,j:integer;
begin
  randomize;
  for i:=1 to 25 do
  for j:=1 to 80 do begin
    textcolor(random(16));
    textbackground(random(16));
    gotoxy(j,i);
    write(chr(random(200)+32));
  end;
end;
begin
  musor;//заполняем мусором
  mscreen(true);//сохраняем копию в буфере
  repeat until keypressed;  //ждем нажатия на кнопку
  setlength(a,3);//три пункта меню
  a[0]:='Item 1';a[1]:='Item 2';a[2]:='Exit';//собственно они
  repeat until menu(a,30,10,50,15,green)=2; //меню
  mscreen(false); //восстанавливаем экран
 
end.

var
  screen: array [0..24,0..79] of record c: Char; a: Byte; end absolute $B800:0;