В каком участке кода задаётся шаг функции

uses Graph;
 
var
  tXMax, tYMax, OcX, OcY, Xroot: integer;
  Mx, My: real;
 
const
  D1 = 4.050156;
  D2 = 0.056044;
  A  = 0.422;
 
const
  XR = 10;
  XL = -10;
  YU = 10;
  YD = -10;
 
const
  YRoot: integer = 10;
 
procedure InitGr;
var
  GrDr, GrMd: integer;
begin
  GrDr := detect;
  InitGraph(GrDR, GrMd, '');
  tXMax := GetMaxX;
  tYMax := GetMaxY;
  Rectangle(0, 0, tXMax, tYmax);
  XRoot := tXmax - 100;
  SetColor(green);
end;
 
function F1(x, y: real): real;
begin
  F1 := cos(y - 0.2 * x * x) + 2 * x * y - 8 * x - 8 * y + d1;
end;
 
function F2(x, y: real): real;
begin
  F2 := (x - 3 * A) * (x * x + y * y) + 4 * a * a * a + d2;
end;
 
procedure Out_X_Y(X, Y, F: real);
var
  S: string[10];
begin
  Str(X:7:3, S);
  OutTextXY(XRoot, YRoot, 'X=' + S);
  YRoot := YRoot + 10;
  Str(Y:7:3, S);
  OutTextXY(XRoot, YRoot, 'Y=' + S);
  YRoot := YRoot + 14;
  Str(F:7:3, S);
  OutTextXY(XRoot, YRoot, 'F=' + S);
  YRoot := YRoot + 18;
end;
 
procedure ShowFunc1;
var
  tX, tY: integer;
  X, Y, FF: real;
begin
  for tX := 5 to (tXMax - 5) do
  begin
    X := (tX - 5) * Mx + XL;
    for tY := 5 to (tYmax - 5) do
    begin
      Y := (tY - 5) * My + YD;
      FF := F1(x, ((tY - 4) * My + YD));
      if (F1(X, Y) * FF < 0) then PutPixel(tX, tY, Cyan)
    end;
  end;
end;
 
procedure ShowFunc2;
var
  tX, tY: integer;
  X, Y, FF: real;
begin
  for tX := 5 to (tXMax - 5) do
  begin
    X := (tX - 5) * Mx + XL;
    for tY := 5 to (tYmax - 5) do
    begin
      Y := (tY - 5) * My + YD;
      FF := F2(x, ((tY - 4) * My + YD));
      if (F2(X, Y) * FF < 0) then begin
        if GetPixel(tX, tY) = Cyan then Out_X_Y(X, Y, F2(X, Y));
        PutPixel(tX, tY, red);
      end;
    end;
  end;
end;
 
procedure ShowOcX;
var
  X, dX: real;
  tX: integer;
  s: string[7];
begin
  OcX := Round(tYmax / 2);
  Line(5, OcX, tXMax - 5, OcX);
  OutTextXY(tXMax - 10, OcX - 3, '>');
  OutTextXY(tXMax - 12, OcX + 4, 'X');
  dX := (XR - XL) / 15;
  X := XL;
  while X < XR - dX / 2 do
  begin
    tX := Round((X - XL) / MX) + 5;
    Line(tX, OcX - 4, tX, Ocx + 4);
    Str(X:5:1, s);
    OutTextXY(tX - 15, OcX - 10, S);
    X := X + dx;
  end;
end;
 
procedure ShowOcY;
var
  Y, dY: real;
  tY: integer;
  s: string[7];
begin
  OcY := Round(tXmax / 2);
  Line(OcY, 5, OcY, tYMax - 5);
  OutTextXY(OcY - 3, 5, '^');
  OutTextXY(OcY + 4, 7, 'Y');
  dY := (YU - YD) / 15;
  Y := YU;
  while Y > YD + dy / 2 do
  begin
    tY := Round((YU - Y) / MY) + 5;
    Line(OcY - 4, tY, OcY + 4, tY);
    Str(Y:5:1, s);
    OutTextXY(OcY, tY - 10, S);
    Y := Y - dy;
  end;
end;
 
begin
  InitGr;
  Mx := (XR - XL) / (tXmax - 10);
  My := (YU - YD) / (tYmax - 10);
  ShowFunc1;
  ShowOcY;
  ShowOcX;
  ShowFunc2;
  Readln;
  CloseGraph;
end.

for tX := 5 to (tXMax - 5) do
for tY := 5 to (tYmax - 5) do