Для любителей, примитивная, но вполне рабочая змейка в исходниках - 2

open System
open System.Collections.Generic
 
type Io = System.Console
 
let H, W, RND, SPEEDINTERVAL = 30, 80, System.Random(), 200 
 
type GameMsg =
        | NewGame 
        | CloseApp
        | MoveToW
        | MoveToS
        | MoveToA
        | MoveToD
        | Tick
        | Crash
        | QueryClosed of AsyncReplyChannel<bool>
     
type SpritePos = { Y : int; X : int }
type SpriteAux = char 
 
let dodraw txt color { Y = y; X = x } = 
        Io.CursorLeft <- x 
        Io.CursorTop  <- y 
        Io.ForegroundColor <- color
        Io.Write(txt : string)
 
let game =
        MailboxProcessor<GameMsg>.Start(fun inbox ->
            let wallsNfood  = Dictionary<SpritePos, SpriteAux>()
            let snake       = LinkedList<SpritePos>()
            let toGrow      = ref 0
            let direction   = ref { Y = -1; X = 0 }
 
            let isFilled k       = wallsNfood.ContainsKey k
            let toWallsNfood k v = if not <| isFilled k then wallsNfood.Add(k, v)
            let rec getFoodPos() =
                    let pos = { Y = RND.Next H; X = RND.Next W }
                    if snake.Contains pos || isFilled pos then getFoodPos() else pos
 
            let start () = 
                Io.Clear()
                wallsNfood.Clear()
                snake.Clear()
                direction := { Y = -1; X = 0 }
                toGrow    := 7
                
                let walls = List.collect (fun i -> [i, 0; i, W-1]) [0..H-1] 
                          @ List.collect (fun i -> [0, i; H-1, i]) [0..W-1]
                          @ List.map (fun _ -> RND.Next H, RND.Next W) [1..15]
                for y,x as e in walls do 
                        toWallsNfood { Y = y; X = x } 'Ш' 
                        dodraw "Ш" ConsoleColor.Red  { Y = y; X = x }
                
                let food  = seq { for i in 1..5 -> getFoodPos() }
                for e in food do 
                        toWallsNfood e '*'
                        dodraw "*" ConsoleColor.Green e
 
                snake.AddFirst { Y = H/2; X = W/2 } |> ignore
                for e in snake do dodraw "O" ConsoleColor.Yellow e
 
 
            let move() = 
                let head, dir = snake.First.Value, !direction
                let head = { Y = head.Y + dir.Y; X = head.X + dir.X }
                match wallsNfood.TryGetValue head with
                | true, 'Ш'     ->  inbox.Post Crash
                | true, '*'     ->  let e = getFoodPos()
                                    toWallsNfood e '*'
                                    dodraw "*" ConsoleColor.Green e
                                    wallsNfood.Remove head |> ignore
                                    toGrow := 5
                | _ when snake.Contains head ->  inbox.Post Crash
                | _ -> ()
                snake.AddFirst head |> ignore
                dodraw "O" ConsoleColor.Yellow head
 
                if !toGrow > 0 
                    then toGrow := !toGrow - 1
                    else let last = snake.Last.Value
                         dodraw " " ConsoleColor.Yellow last
                         snake.RemoveLast()
 
 
            let rec loop() = async {
                let! msg = inbox.Receive()
                match msg with
                | CloseApp          -> return! closed()
                | Crash             -> dodraw "    G A M E   O V E R    " ConsoleColor.Red { Y = H/2; X = W/2 - 10 }
                                       return! over()
                | _ ->
                match msg with
                | NewGame           -> start()
                | MoveToW           -> direction := { Y = -1; X = 0  }
                | MoveToS           -> direction := { Y =  1; X = 0  }
                | MoveToA           -> direction := { Y = 0 ; X = -1 }
                | MoveToD           -> direction := { Y = 0 ; X =  1 }
                | Tick              -> move()
                | QueryClosed repl  -> repl.Reply false
                | _                 -> ()
                return! loop()
                }
 
            and over() = async {
                let! msg = inbox.Receive()
                match msg with
                | CloseApp      -> return! closed()
                | NewGame           -> inbox.Post NewGame
                                       return! loop()
                | QueryClosed repl  -> repl.Reply false
                                       return! over()
                | _                 -> return! over()
                }
 
            and closed() = async {
                let! msg = inbox.Receive()
                match msg with
                | QueryClosed repl  -> repl.Reply true 
                | _                 -> ()
                return! closed()
                }
            loop()
        )
 
let input =
        MailboxProcessor<char>.Start(fun inbox ->
            let rec loop() = async {
                let pressed = Io.ReadKey true
                match pressed.Key with
                | ConsoleKey.UpArrow    | ConsoleKey.W  -> game.Post MoveToW 
                | ConsoleKey.DownArrow  | ConsoleKey.S  -> game.Post MoveToS 
                | ConsoleKey.LeftArrow  | ConsoleKey.A  -> game.Post MoveToA 
                | ConsoleKey.RightArrow | ConsoleKey.D  -> game.Post MoveToD 
                | ConsoleKey.Escape     | ConsoleKey.Q  -> game.Post CloseApp
                | ConsoleKey.Spacebar   | ConsoleKey.N  -> game.Post NewGame 
                | _                                     -> ()
                return! loop()
                }
            loop()
        )
 
let tick =
        MailboxProcessor<char>.Start(fun inbox ->
            let rec loop() = async {
                System.Threading.Thread.Sleep SPEEDINTERVAL
                Tick |> game.Post
                return! loop()
                }
            loop()
        )
 
[<EntryPoint>][<STAThread>]
let main argv = 
    let rec loop () = 
        System.Threading.Thread.Sleep 1000
        if game.PostAndReply QueryClosed then () else loop ()
    Io.SetWindowSize(W + 1, H + 1)
    game.Post NewGame
    loop ()
    0