Для любителей, примитивная, но вполне рабочая змейка в исходниках

open System
 
type GameState = 
        | Running
        | Quit
 
type Game =
      { snake     : (int * int) list
        food      : (int * int) list
        walls     : (int * int) list
        togrow    : int
        direction : int * int }
 
let H, W, RND, SPEEDINTERVAL = 30, 80, System.Random(), 200
 
let newGame() = 
     { snake       = [(H/2, W/2)]
       direction   = (-1, 0)
       food        = [1..5] |> List.map (fun _ -> (RND.Next H, RND.Next W))
       togrow      = 0
       walls       = List.collect (fun i -> [(i, 0);(i, W-1)]) [0..H-1] 
                   @ List.collect (fun i -> [(0, i);(H-1, i)]) [0..W-1]
                   @ List.map (fun _ -> (RND.Next H, RND.Next W)) [1..15] }
 
let inittail xs togrow  = match togrow, List.rev xs with
                          | 0, h :: t  -> h,  List.rev t, 0
                          | n, h :: t  -> h,  xs, n - 1
                          | _, []      -> failwith "empty list"
let waitKeyPress ()     = System.Console.ReadKey (true) |> ignore
 
let draw txt color (y, x) = 
        Console.CursorLeft <- x 
        Console.CursorTop <- y 
        Console.ForegroundColor <- color
        Console.Write(txt : string)
let draw_snake = draw "O" ConsoleColor.Yellow 
let draw_wall  = draw "Ш" ConsoleColor.Red
let draw_food  = draw "*" ConsoleColor.Green
 
 
let (|HIT|_|) game coord = 
        if List.exists ((=)coord) game.walls
           || List.exists ((=)coord) game.snake then Some coord else None
let (|EAT|_|) game coord = 
        if List.exists ((=)coord) game.food then Some coord else None
 
 
let rec mainloop state = 
        if System.Console.KeyAvailable then
            match Char.ToLower <| System.Console.ReadKey(true).KeyChar with
            | 'w' -> mainloop { state with direction = (-1, 0) }
            | 's' -> mainloop { state with direction = (1, 0) }
            | 'a' -> mainloop { state with direction = (0, -1) }
            | 'd' -> mainloop { state with direction = (0, 1) }
            | 'p' -> GameState.Quit
            | _   -> mainloop state
        else 
        System.Threading.Thread.Sleep SPEEDINTERVAL
        let hh, hw = List.head state.snake
        match hh + fst state.direction, hw + snd state.direction with
        | HIT state head ->
                draw_snake head
                draw "    G A M E   O V E R    " ConsoleColor.Red (H/2, W/2 - 10)
                waitKeyPress()
                GameState.Running
        | EAT state head ->
                let newfood = Seq.initInfinite (fun i -> (RND.Next H, RND.Next W))
                              |> Seq.skipWhile (function HIT state _ | EAT state _ -> true | _ -> false )
                              |> Seq.head
                draw_snake head
                draw_food newfood
                mainloop { state with food = newfood :: List.filter ((<>)head) state.food
                                      snake = head :: state.snake
                                      togrow = 3 + state.togrow }
        | head -> 
                let old, body, newgrow = inittail state.snake state.togrow
                draw " " ConsoleColor.Yellow old
                draw_snake head
                mainloop { state with snake = head :: body
                                      togrow = newgrow }
 
    
let rec run_loop state  = 
        match state with 
        | Running     -> 
                Console.Clear()
                let state = newGame()
                state.food  |> Seq.iter draw_food
                state.walls |> Seq.iter draw_wall
                state.snake |> Seq.iter draw_snake
                waitKeyPress()
                mainloop state |> run_loop
        | Quit        -> ()
 
 
[<EntryPoint>]
let main argv = 
    Console.SetWindowSize(W + 1, H + 1)
    run_loop Running
    0

match System.Console.ReadKey(true).Key with
| ConsoleKey.W -> mainloop { state with direction = (-1, 0) }
| ConsoleKey.S -> mainloop { state with direction = (1, 0) }
| ConsoleKey.A -> mainloop { state with direction = (0, -1) }
| ConsoleKey.D -> mainloop { state with direction = (0, 1) }
| ConsoleKey.P -> GameState.Quit
| _   -> mainloop state