Реализация метода CopyToDataTable<T>, если универсальный тип T не является DataRow

Public Class ObjectShredder(Of T)
    ' Fields
    Private _fi As FieldInfo()
    Private _ordinalMap As Dictionary(Of String, Integer)
    Private _pi As PropertyInfo()
    Private _type As Type
 
    ' Constructor 
    Public Sub New()
        Me._type = GetType(T)
        Me._fi = Me._type.GetFields
        Me._pi = Me._type.GetProperties
        Me._ordinalMap = New Dictionary(Of String, Integer)
    End Sub
 
    Public Function ShredObject(ByVal table As DataTable, ByVal instance As T) As Object()
        Dim fi As FieldInfo() = Me._fi
        Dim pi As PropertyInfo() = Me._pi
        If (Not instance.GetType Is GetType(T)) Then
            ' If the instance is derived from T, extend the table schema
            ' and get the properties and fields.
            Me.ExtendTable(table, instance.GetType)
            fi = instance.GetType.GetFields
            pi = instance.GetType.GetProperties
        End If
 
        ' Add the property and field values of the instance to an array.
        Dim values As Object() = New Object(table.Columns.Count - 1) {}
        Dim f As FieldInfo
        For Each f In fi
            values(Me._ordinalMap.Item(f.Name)) = f.GetValue(instance)
        Next
        Dim p As PropertyInfo
        For Each p In pi
            values(Me._ordinalMap.Item(p.Name)) = p.GetValue(instance, Nothing)
        Next
 
        ' Return the property and field values of the instance.
        Return values
    End Function
 
 
    ' Summary:           Loads a DataTable from a sequence of objects.
    ' source parameter:  The sequence of objects to load into the DataTable.</param>
    ' table parameter:   The input table. The schema of the table must match that 
    '                    the type T.  If the table is null, a new table is created  
    '                    with a schema created from the public properties and fields 
    '                    of the type T.
    ' options parameter: Specifies how values from the source sequence will be applied to 
    '                    existing rows in the table.
    ' Returns:           A DataTable created from the source sequence.
 
    Public Function Shred(ByVal source As IEnumerable(Of T), ByVal table As DataTable, ByVal options As LoadOption?) As DataTable
 
        ' Load the table from the scalar sequence if T is a primitive type.
        If GetType(T).IsPrimitive Then
            Return Me.ShredPrimitive(source, table, options)
        End If
 
        ' Create a new table if the input table is null.
        If (table Is Nothing) Then
            table = New DataTable(GetType(T).Name)
        End If
 
        ' Initialize the ordinal map and extend the table schema based on type T.
        table = Me.ExtendTable(table, GetType(T))
 
        ' Enumerate the source sequence and load the object values into rows.
        table.BeginLoadData()
        Using e As IEnumerator(Of T) = source.GetEnumerator
            Do While e.MoveNext
                If options.HasValue Then
                    table.LoadDataRow(Me.ShredObject(table, e.Current), options.Value)
                Else
                    table.LoadDataRow(Me.ShredObject(table, e.Current), True)
                End If
            Loop
        End Using
        table.EndLoadData()
 
        ' Return the table.
        Return table
    End Function
 
 
    Public Function ShredPrimitive(ByVal source As IEnumerable(Of T), ByVal table As DataTable, ByVal options As LoadOption?) As DataTable
        ' Create a new table if the input table is null.
        If (table Is Nothing) Then
            table = New DataTable(GetType(T).Name)
        End If
        If Not table.Columns.Contains("Value") Then
            table.Columns.Add("Value", GetType(T))
        End If
 
        ' Enumerate the source sequence and load the scalar values into rows.
        table.BeginLoadData()
        Using e As IEnumerator(Of T) = source.GetEnumerator
            Dim values As Object() = New Object(table.Columns.Count - 1) {}
            Do While e.MoveNext
                values(table.Columns.Item("Value").Ordinal) = e.Current
                If options.HasValue Then
                    table.LoadDataRow(values, options.Value)
                Else
                    table.LoadDataRow(values, True)
                End If
            Loop
        End Using
        table.EndLoadData()
 
        ' Return the table.
        Return table
    End Function
 
    Public Function ExtendTable(ByVal table As DataTable, ByVal type As Type) As DataTable
        ' Extend the table schema if the input table was null or if the value 
        ' in the sequence is derived from type T.
        Dim f As FieldInfo
        Dim p As PropertyInfo
 
        For Each f In type.GetFields
            If Not Me._ordinalMap.ContainsKey(f.Name) Then
                Dim dc As DataColumn
 
                ' Add the field as a column in the table if it doesn't exist
                ' already.
                dc = IIf(table.Columns.Contains(f.Name), table.Columns.Item(f.Name), table.Columns.Add(f.Name, f.FieldType))
 
                ' Add the field to the ordinal map.
                Me._ordinalMap.Add(f.Name, dc.Ordinal)
            End If
 
        Next
 
        For Each p In type.GetProperties
            If Not Me._ordinalMap.ContainsKey(p.Name) Then
                ' Add the property as a column in the table if it doesn't exist
                ' already.
                Dim dc As DataColumn
                dc = IIf(table.Columns.Contains(p.Name), table.Columns.Item(p.Name), table.Columns.Add(p.Name, p.PropertyType))
 
                ' Add the property to the ordinal map.
                Me._ordinalMap.Add(p.Name, dc.Ordinal)
            End If
        Next
 
        ' Return the table.
        Return table
    End Function
 
End Class

Public Module CustomLINQtoDataSetMethods
    <Extension()> _
    Public Function CopyToDataTable(Of T)(ByVal source As IEnumerable(Of T)) As DataTable
        Return New ObjectShredder(Of T)().Shred(source, Nothing, Nothing)
    End Function
 
    <Extension()> _
    Public Function CopyToDataTable(Of T)(ByVal source As IEnumerable(Of T), ByVal table As DataTable, ByVal options As LoadOption?) As DataTable
        Return New ObjectShredder(Of T)().Shred(source, table, options)
    End Function
 
End Module

Dim query = _
    From order In orders.AsEnumerable() _
    Where order.Field(Of DateTime)("OrderDate") > New DateTime(2001, 8, 1) _
    Select order
 
' Create a table from the query.
Dim boundTable As DataTable = query.CopyToDataTable()

'=================================================================================================='
'                                      Поиск дублей по ITID                                                                                                             '
'=================================================================================================='
 
        Dim Itid_DBL = _
            From R1 In T1.AsEnumerable() _
            Join R2 In T2.AsEnumerable() On _
                R1.Field(Of String)("ITID") Equals _
                R2.Field(Of String)("ITID") _
                                Where (CLng(R1!ID) <> CLng(R2!ID)) And _
                  (((CInt(R1!YML) <= CInt(R2!YML)) And (CInt(R2!YML) <= CInt(IIf(CInt(R1!YMH) = 0, 9999, CInt(R1!YMH))))) Or _
                   ((CInt(R1!YML) <= CInt(IIf(CInt(R2!YMH) = 0, 9999, CInt(R2!YMH)))) And (CInt(IIf(CInt(R2!YMH) = 0, 9999, CInt(R2!YMH))) <= CInt(IIf(CInt(R1!YMH) = 0, 9999, CInt(R1!YMH))))) Or _
                   ((CInt(R2!YML) <= CInt(R1!YML)) And (CInt(R1!YML) <= CInt(IIf(CInt(R2!YMH) = 0, 9999, CInt(R2!YMH))))) Or _
                   ((CInt(R2!YML) <= CInt(IIf(CInt(R1!YMH) = 0, 9999, CInt(R1!YMH)))) And (CInt(IIf(CInt(R1!YMH) = 0, 9999, CInt(R1!YMH))) <= CInt(IIf(CInt(R2!YMH) = 0, 9999, CInt(R2!YMH)))))) _
            Select New With { _
                .ID1 = R1.Field(Of Long)("ID"), _
                .ID2 = R2.Field(Of Long)("ID"), _
                .ITID1 = R1.Field(Of String)("ITID"), _
                .ITID2 = R2.Field(Of String)("ITID"), _
                .YML1 = R1.Field(Of Decimal)("YML"), _
                .YML2 = R2.Field(Of Decimal)("YML"), _
                .YMH1 = R1.Field(Of Decimal)("YMH"), _
                .YMH2 = R2.Field(Of Decimal)("YMH")}
 
        Dim IDBL As New DataTable
        IDBL = Itid_DBL.CopyToDataTable()

Dim boundTable As DataTable = query.CopyToDataTable()

            Dim IDBL As New DataTable
 
            IDBL.Columns.Add("ID1", GetType(Long))
            IDBL.Columns.Add("ID2", GetType(Long))
            IDBL.Columns.Add("ITID1", GetType(String))
            IDBL.Columns.Add("ITID2", GetType(String))
            IDBL.Columns.Add("YML1", GetType(Decimal))
            IDBL.Columns.Add("YMH1", GetType(Decimal))
            IDBL.Columns.Add("YML2", GetType(Decimal))
            IDBL.Columns.Add("YMH2", GetType(Decimal))
 
For Each RR In Itid_DBL
      IDBL.Rows.Add(RR.ID1, RR.ID2, RR.ITID1, RR.ITID2, RR.YML1, RR.YMH1, RR.YML2, RR.YMH2)
Next