Написать функцию,которая сохраняет дубликаты эл-ов списка в список.Пример описан ниже

(defun collect-doubles (list &optional (func #'equal))
  (let ((table (make-hash-table :test func)))
    (loop for (a . b) on list if (find a b :test func)
       do (setf (gethash a table) t))
    (loop for e being the hash-keys in table collect e)))

(defun f (xs)
  (let (result)
    (let ((table (make-hash-table)))
      (dolist (x xs result)
        (when (= 2 (incf (gethash x table 0)))
          (push x result))))))

(defun task (lst &optional (r nil))
  (cond ((null lst) (reverse r))
        ((and (member (car lst) (cdr lst)) (not (member (car lst) r))) (task (cdr lst) (cons (car lst) r)))
        (t (task (cdr lst) r))))
 
==> task
 
(task '(1 2 3 1 2 3 5))
 
==> (1 2 3)

(defun task (lst)
  (let* ((ll (length lst))
         (lsts (setof lst))
         (pair (mapcar #'(lambda (x) (list (- ll (length (remove x lst))) x)) lsts)))
      (mapcar 'cadr (remove-if-not #'(lambda (x) (= 2 (car x))) pair))))
 
==> task
 
(task '(1 2 3 1 2 3 5))
 
==> (1 2 3)

(defun more-than-one (w &optional (v (remove-duplicates w)))
  (cond ((null v) nil)
        ((= (count (car v) w) 1) (more-than-one w (cdr v)))
        ((cons (car v) (more-than-one w (cdr v))))))
 
> (more-than-one '(1 2 3 1 2 3 5))
(1 2 3)
> (more-than-one '(6 1 2 7 1 2 5))
(1 2)

(defun more-than-one (w &optional (v (remove-duplicates w)))
  (when v (if (= (count (car v) w) 1)
              (more-than-one w (cdr v))
              (cons (car v) (more-than-one w (cdr v))))))
 
> (more-than-one '(6 1 2 7 1 2 5))
(1 2)
> (more-than-one '(1 2 3 1 2 3 5))
(1 2 3)

(defun more-than-one (w &optional (v (remove-duplicates w)))
  (loop for a in v when (> (count a w) 1) collect a))
 
> (more-than-one '(1 2 3 1 2 3 5))
(1 2 3)
> (more-than-one '(6 1 2 7 1 2 5))
(1 2)

(defun more-than-one (w &optional (v (remove-duplicates w)))
  (remove-if #'(lambda (a) (= (count a w) 1)) v))
 
> (more-than-one '(6 1 2 7 1 2 5))
(1 2)
> (more-than-one '(1 2 3 1 2 3 5))
(1 2 3)

(defun more-than-one (w &optional (v (remove-duplicates w)) ac)
  (cond ((null v) (nreverse ac))
        ((= (count (car v) w) 1) (more-than-one w (cdr v) ac))
        ((more-than-one w (cdr v) (cons (car v) ac)))))
 
> (more-than-one '(6 1 2 7 1 2 5))
(1 2)
> (more-than-one '(1 2 3 1 2 3 5))
(1 2 3)

(defun more-than-one (w &optional (v (remove-duplicates w)) ac)
  (if v
      (more-than-one w (cdr v) (if (= (count (car v) w) 1)
                                   ac
                                   (cons (car v) ac)))
      (nreverse ac)))
 
> (more-than-one '(1 2 3 1 2 3 5))
(1 2 3)
> (more-than-one '(6 1 2 7 1 2 5))
(1 2)