Написать функцию, которая удаляет из списка элементы

(defun drop (e w)
  (cond ((null w) nil)
        ((equal (car w) e) (drop e (cdr w)))
        ((listp (car w)) (cons (drop e (car w)) (drop e (cdr w))))
        ((cons (car w) (drop e (cdr w))))))
 
> (drop 'a '(a b a (b a c x) x b))
(B (B C X) X B)

(defun drop (e w &aux (a (car w)) (d (cdr w)))
  (cond ((null w) nil)
        ((equal a e) (drop e d))
        ((listp a) (cons (drop e a) (drop e d)))
        ((cons a (drop e d)))))
 
> (drop 'a '(a b a (b a c x) x b))
(B (B C X) X B)

(defun drop (e w &aux (a (car w)) (d (cdr w)))
  (when w (if (equal a e) (drop e d)
              (cons (if (listp a) (drop e a) a)
                    (drop e d)))))
 
> (drop 'a '(a b a (b a c x) x b))
(B (B C X) X B)

(defun drop (e w)
  (loop for a in w unless (equal a e)
        collect (if (listp a) (drop e a) a)))
 
> (drop 'a '(a b a (b a c x) x b))
(B (B C X) X B)

(defun drop (e w)
  (loop for a in w unless (equal a e)
        collect (if (atom a) a (drop e a))))
 
> (drop 'a '(a b a (b a c x) x b))
(B (B C X) X B)

(defun task (el lst)
  (let ((lst1 (remove-if (lambda (x) (equal el x)) lst)))
    (mapcar (lambda (x) (if (atom x) x (task el x))) lst1)))
 
==> TASK
(task 'h '(a s d h (((d f h) e h) q)))
 
 
==> (A S D (((D F) E) Q))